Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: BPSOSQF

BPSOSQF.m

Go to the documentation of this file. 
  1. BPSOSQF ;BHAM ISC/FCS/DRS/FLS - Insurer asleep - status 31 ;06/01/2004
  1.  ;;1.0;E CLAIMS MGMT ENGINE;**1,5,7,10**;JUN 2004;Build 27
  1.  ;;Per VHA Directive 2004-038, this routine should not be modified.
  1.  Q
  1.  ;
  1.  ; Check for insurer asleep claims
  1.  ;
  1. STATUS31 ;EP - BPSOSQ2
  1.  ; Loop through claims at 31%
  1.  ; Reset to 30% if:
  1.  ;   a) This is a prober and it is time to retry
  1.  ;   b) The insurer is awake
  1.  N IEN59,GRPLAN
  1.  ;
  1.  ; Make sure we can get the lock
  1.  I '$$LOCK59^BPSOSQ2(31) Q
  1.  ;
  1.  ; Loop through transactions that are 31%
  1.  S IEN59=""
  1.  F  S IEN59=$O(^BPST("AD",31,IEN59)) Q:'IEN59  D
  1.  . ;
  1.  . ; Get the Group Plan for the transaction
  1.  . S GRPLAN=+$$GETPLN59^BPSUTIL2(IEN59)
  1.  . I GRPLAN=0 D LOG^BPSOSL(IEN59,$T(+0)_"-No Group Plan was found") Q
  1.  . ;
  1.  . ; If this is the prober and it is time to retry, reset the status
  1.  . I $$PROBER(GRPLAN)=IEN59,$$RETRY(GRPLAN) D RESET(IEN59,"-Prober Transaction") Q
  1.  . ;
  1.  . ; If the plan is no longer asleep, reset the status
  1.  . I '$$ISASLEEP(GRPLAN) D RESET(IEN59,"-Payer is awake")
  1.  ;
  1.  D UNLOCK59^BPSOSQ2(31)
  1.  Q
  1.  ;
  1. RESET(IEN59,MSG) ;
  1.  ; Procedure to set status to 30% and log a message
  1.  ; Input:
  1.  ;   IEN59 - BPS Transaction IEN59
  1.  ;   PROBER - Flag indicating whether this is a prober
  1.  I '$G(IEN59) Q
  1.  ; Clear pointer to Asleep Payer
  1.  N DIE,DA,DR,DTOUT
  1.  S DIE=9002313.59,DA=IEN59,DR="801///@" D ^DIE
  1.  ; Set status to 30%
  1.  D SETSTAT^BPSOSU(IEN59,30)
  1.  ; Log message
  1.  D LOG^BPSOSL(IEN59,$T(+0)_"-Retrying Asleep Claim"_$G(MSG))
  1.  Q
  1.  ;
  1. ISASLEEP(GRPLAN) ;
  1.  ; Function to check if Payer is asleep.
  1.  ; Input:
  1.  ;   GRPLAN = GROUP INSURANCE PLAN file IEN
  1.  ; Returns:
  1.  ;   1 = Yes, payer is asleep
  1.  ;   0 = No, payer is not asleep
  1.  I '$G(GRPLAN) Q 0
  1.  N BPAIEN,BPSSITE
  1.  ;
  1.  ; If the plan is not in the Insurer Asleep file, asleep is off
  1.  S BPAIEN=$O(^BPS(9002313.15,"B",GRPLAN,0))
  1.  Q:'BPAIEN 0
  1.  ;
  1.  ; If the plan is set to ignore, asleep is off
  1.  I $$IGNORE(GRPLAN) Q 0
  1.  ;
  1.  ; Check is the site parameters have disabled sleep
  1.  S BPSSITE=$G(^BPS(9002313.99,1,0))
  1.  I '$P(BPSSITE,"^",5)!('$P(BPSSITE,"^",6)) Q 0
  1.  ;
  1.  Q 1
  1.  ;
  1. IGNORE(GRPLAN) ;
  1.  ; Function to check if IGNORE ASLEEP flag set for Plan
  1.  ; Input:
  1.  ;   GRPLAN = Group Insurance Plan file IEN
  1.  ; Returns:
  1.  ;   1 = Ignore
  1.  ;   0 = Don't Ignore
  1.  I '$G(GRPLAN) Q 0
  1.  N BPAIEN
  1.  S BPAIEN=$O(^BPS(9002313.15,"B",GRPLAN,0))
  1.  Q:'BPAIEN 0
  1.  Q $S($P($G(^BPS(9002313.15,BPAIEN,0)),U,3)=1:1,1:0)
  1.  ;
  1. PROBER(GRPLAN) ;
  1.  ; Function to return the PROBER CLAIM for an insurer
  1.  ; Input:
  1.  ;   GRPLAN = Group Insurance Plan file IEN
  1.  ; Returns:
  1.  ;   PROBER CLAIM - Pointer to BPS TRANSACTION file
  1.  I '$G(GRPLAN) Q ""
  1.  N BPAIEN
  1.  S BPAIEN=$O(^BPS(9002313.15,"B",GRPLAN,0))
  1.  Q:'BPAIEN ""
  1.  Q $P($G(^BPS(9002313.15,BPAIEN,0)),U,4)
  1.  ;
  1. RETRY(GRPLAN) ;
  1.  ; Function to return a flag indicating whether it is time to rerun the prober
  1.  ; Input:
  1.  ;   GRPLAN = Group Insurance Plan file IEN
  1.  ; Returns:
  1.  ;   RETRY = Flag indicating it is time to retry the prober
  1.  I '$G(GRPLAN) Q 0
  1.  N BPAIEN,RETRY
  1.  S BPAIEN=$O(^BPS(9002313.15,"B",GRPLAN,0))
  1.  Q:'BPAIEN 0
  1.  S RETRY=$$GET1^DIQ(9002313.15,BPAIEN_",",.05,"I")
  1.  I RETRY'>$$NOW^XLFDT Q 1
  1.  Q 0