Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: BPSRPT7

BPSRPT7.m

Go to the documentation of this file. 
  1. BPSRPT7 ;BHAM ISC/BEE - ECME REPORTS ;14-FEB-05
  1.  ;;1.0;E CLAIMS MGMT ENGINE;**1,3,5,7,8,10,11,19,20,23,24,28**;JUN 2004;Build 22
  1.  ;;Per VA Directive 6402, this routine should not be modified.
  1.  ;
  1.  Q
  1.  ;
  1.  ;Routine to Display the Reports (Continued)
  1.  ;
  1.  ; The following sub-routines were moved to BPSRPT7A:
  1.  ;   PTBDT,PGTOT6,PGTOT,ITOT,BILLED
  1.  ; 
  1.  ;Get Close Reason
  1.  ;
  1.  ; Input Variable -> BP59 = ptr to BPS TRANSACTIONS
  1.  ; Returned Value -> Claim Close Reason
  1.  ;
  1. CLRSN(BP59) N BP02,CIEN,CL
  1.  S CL=""
  1.  S BP02=+$P($G(^BPST(BP59,0)),U,4)
  1.  S CIEN=+$P($G(^BPSC(BP02,900)),U,4)
  1.  I CIEN'=0 S CL=$$GETCLR^BPSRPT6(CIEN)
  1.  Q CIEN_"^"_CL
  1.  ;
  1.  ;Get Reversal Reason
  1.  ;
  1.  ; Input Variable -> BP59 = ptr to BPS TRANSACTIONS
  1.  ; Returned Value -> Claim Reversal Reason
  1.  ;
  1. RVSRSN(BP59) Q $P($G(^BPST(BP59,4)),U,4)
  1.  ;
  1.  ;Return the Transaction Type - SUBMIT or REVERSAL
  1.  ;
  1. TTYPE(BPRX,BPREF,BPSEQ) N BPSTATUS,TTYPE
  1.  S TTYPE="SUBMIT"
  1.  S BPSTATUS=$$STATUS^BPSRPT6(BPRX,BPREF,$G(BPSEQ))
  1.  I BPSTATUS["REVERSAL" S TTYPE="REVERSAL"
  1.  Q TTYPE
  1.  ;
  1.  ;Return the payer response
  1.  ;
  1. RESPONSE(BPRX,BPREF,BPSEQ) Q $P($$STATUS^BPSRPT6(BPRX,BPREF,$G(BPSEQ)),U)
  1.  ;
  1.  ;Print Report Subtotals
  1.  ;
  1. TOTALS(BPRTYPE,BPDIV,BPTBIL,BPTINS,BPTCOLL,BPTDPAY,BPCNT,BPELTM,BPRICE) ;
  1.  I (BPRTYPE=1)!(BPRTYPE=4) D  Q
  1.  .W !!,?83,"----------",?105,"----------",?122,"----------"
  1.  .W !,"SUBTOTALS for DIV:",$E($$BPDIV(BPDIV),1,52),?83,$J(BPTBIL,10,2),?105,$J(BPTINS,10,2),?122,$J(BPTCOLL,10,2)
  1.  .W !,"COUNT",?83,$J(BPCNT,10),?105,$J(BPCNT,10),?122,$J(BPCNT,10)
  1.  .W:BPCNT !,"MEAN",?83,$J(BPTBIL/BPCNT,10,2),?105,$J(BPTINS/BPCNT,10,2),?122,$J(BPTCOLL/BPCNT,10,2)
  1.  I BPRTYPE=3 D  Q
  1.  .W !!,?100,"----------",?122,"----------"
  1.  .W !,"SUBTOTALS for DIV:",$E($$BPDIV(BPDIV),1,52),?100,$J(BPTBIL,10,2),?122,$J(BPTINS,10,2)
  1.  .W !,"COUNT",?100,$J(BPCNT,10),?122,$J(BPCNT,10)
  1.  .W:BPCNT !,"MEAN",?100,$J(BPTBIL/BPCNT,10,2),?122,$J(BPTINS/BPCNT,10,2)
  1.  I BPRTYPE=2 D  Q
  1.  .W !!,?41,"----------"
  1.  .W !,"SUBTOTALS for DIV:",$E($$BPDIV(BPDIV),1,22),?41,$J(BPTBIL,10,2)
  1.  .W !,"COUNT",?41,$J(BPCNT,10)
  1.  .W:BPCNT !,"MEAN",?41,$J(BPTBIL/BPCNT,10,2)
  1.  I (BPRTYPE=5) D  Q
  1.  .W !!,"SUBTOTALS for DIV: ",$E($$BPDIV(BPDIV),1,43),?65,"---------------"
  1.  .W !,"TOTAL CLAIMS",?65,$J(BPCNT,15)
  1.  .W !,"AVERAGE ELAPSED TIME PER CLAIM",?65,$J($S(BPCNT=0:"0",1:(BPELTM\BPCNT)),15)
  1.  I (BPRTYPE=7) D  Q
  1.  .W !!,"SUBTOTALS for DIV:",$E($$BPDIV(BPDIV),1,43)
  1.  .N BPBILR
  1.  .S BPBILR="" F  S BPBILR=$O(BPCNT(BPBILR)) Q:BPBILR=""  D  Q:BPQ
  1.  ..S NP=$$CHKP^BPSRPT5(1) Q:BPQ
  1.  ..W !,?3,BPBILR,?65,$J($G(BPCNT(BPBILR)),5)
  1.  .Q:$G(BPQ)
  1.  .W !,?65,"-----"
  1.  .W !,"CLOSED CLAIMS SUBTOTAL",?65,$J(BPCNT,5)
  1.  I BPRTYPE=8 D  Q
  1.  .W !!,?78,"----------",?100,"----------",?122,"----------"
  1.  .W !,"SUBTOTALS for DIV:",$E($$BPDIV(BPDIV),1,52),?78,$J(BPTBIL,10,2),?100,$J(BPTINS,10,2),?122,$J(BPTCOLL,10,2)
  1.  .W !,?4,$J($P(BPRICE,U,3),10,2),?23,$J($P(BPRICE,U,4),10,2),?38,$J($P(BPRICE,U,5),10,2),?56,$J($P(BPRICE,U,6),10,2),?81,$J($P(BPRICE,U,7),10,2),?96,$J($P(BPRICE,U,2),10,2),?111,$J($P(BPRICE,U),10,2)
  1.  .W !,"COUNT",?78,$J(BPCNT,10),?100,$J(BPCNT,10),?122,$J(BPCNT,10)
  1.  .W !,?4,$J(BPCNT,10),?23,$J(BPCNT,10),?38,$J(BPCNT,10),?56,$J(BPCNT,10),?81,$J(BPCNT,10),?96,$J(BPCNT,10),?111,$J(BPCNT,10)
  1.  .W:BPCNT !,"MEAN",?78,$J(BPTBIL/BPCNT,10,2),?100,$J(BPTINS/BPCNT,10,2),?122,$J(BPTCOLL/BPCNT,10,2)
  1.  .W !,?4,$J($P(BPRICE,U,3)/BPCNT,10,2),?23,$J($P(BPRICE,U,4)/BPCNT,10,2),?38,$J($P(BPRICE,U,5)/BPCNT,10,2),?56,$J($P(BPRICE,U,6)/BPCNT,10,2),?81,$J($P(BPRICE,U,7)/BPCNT,10,2),?96,$J($P(BPRICE,U,2)/BPCNT,10,2),?111,$J($P(BPRICE,U)/BPCNT,10,2)
  1.  ;
  1.  I BPRTYPE=9 D  Q
  1.  .W !!,?84,"----------"
  1.  .W !,"SUBTOTALS for DIV:",$E($$BPDIV(BPDIV),1,52),?84,$J(BPTBIL,10,2)
  1.  .W !,"COUNT",?84,$J(BPCNT,10)
  1.  .W:BPCNT !,"MEAN",?84,$J(BPTBIL/BPCNT,10,2)
  1.  ;
  1.  I BPRTYPE=10 D  Q
  1.  .W !!,?77,"----------",?90,$J("----------",13),?106,"----------",?118,$J("----------",12)
  1.  .W !,"SUBTOTALS for DIV:",$E($$BPDIV(BPDIV),1,52),?77,$J(BPTBIL,10,2),?90,$J(BPTINS,13,2),?106,$J(BPTCOLL,10,2),?118,$J(BPTDPAY,12,2)
  1.  .W !,"COUNT",?77,$J(BPCNT,10),?90,$J(BPCNT,13),?106,$J(BPCNT,10),?118,$J(BPCNT,12)
  1.  .W:BPCNT !,"MEAN",?77,$J(BPTBIL/BPCNT,10,2),?90,$J(BPTINS/BPCNT,13,2),?106,$J(BPTCOLL/BPCNT,10,2),?118,$J(BPTDPAY/BPCNT,12,2)
  1.  Q
  1.  ;
  1.  ;Print Report Header
  1.  ; Input variables (passed in) - BPRTYPE -> number of report
  1.  ;                             - BPRPTNAM -> report name
  1.  ;                             - BPPAGE -> report page number
  1.  ; Input variables (defined in BPSRPT0) - BPPHARM,BPSUMDET,BPNOW,BPMWC,BPRTBCK,BPINSINF
  1.  ;                                        BPREJCD,BPCCRSN,BPAUTREV,BPACREJ,BPQSTDRG
  1.  ;                                        BPDRUG,BPDRGCL,BPRESC,BPOPCL,BPRLNRL,
  1.  ;                                        BPSORT,BPBEGDT,BPENDDT
  1.  ; Output variable - BPSDATA -> Reset to 0 to show no actual data has been printed
  1.  ;                           on the screen
  1.  ;                   BPPAGE -> First set in BPSRPT0, report page number
  1.  ;                   BPBLINE -> Controls whether to print a blank line
  1.  ;                   
  1. HDR(BPRTYPE,BPRPTNAM,BPPAGE) ;
  1.  ;Display Excel Header
  1.  I BPEXCEL D HDR^BPSRPT8A(BPRTYPE) Q
  1.  ;
  1.  ; Define BPPDATA - Tells whether data has been displayed for a screen
  1.  S BPSDATA=0
  1.  S BPBLINE=""
  1.  S BPPAGE=$G(BPPAGE)+1
  1.  W @IOF
  1.  W "ECME "_BPRPTNAM_" "_$S(BPSUMDET=1:"SUMMARY",1:"DETAIL")_" REPORT"
  1.  I (",2,10,")'[(","_BPRTYPE_",") D
  1.  . W ?89,"Print Date: "_$G(BPNOW)_"  Page:",$J(BPPAGE,3)
  1.  . W !,"DIVISION(S): ",$$GETDIVS^BPSRPT4(72,.BPPHARM)
  1.  . W ?86,"Fill Locations: "_$S(BPMWC="A":"C,M,W",1:BPMWC)
  1.  ;
  1.  I (",2,")[BPRTYPE D
  1.  . W ?87,"Print Date: "_$G(BPNOW)_"  Page:",$J(BPPAGE,3)
  1.  . W !,"DIVISION(S): ",$$GETDIVS^BPSRPT4(72,.BPPHARM)
  1.  . W ?84,"Fill Locations: "_$S(BPMWC="A":"C,M,W",1:BPMWC)
  1.  ;
  1.  I (",1,2,3,4,7,")[BPRTYPE D
  1.  . W ?110,"Fill Type: "
  1.  . I BPRTBCK=1 W "RT,BB,P2,RS" Q
  1.  . F I=1:1:$L(BPRTBCK,",") W:I'=1 "," S RTBCKX=$P(BPRTBCK,",",I) W $S(RTBCKX=2:"RT",RTBCKX=3:"BB",RTBCKX=4:"P2",RTBCKX=5:"RS",1:"")
  1.  ;
  1.  I (",1,2,3,4,7,9,")[BPRTYPE W !,"Insurance: "_$S(BPINSINF=0:"ALL",1:"SELECTED")
  1.  ;
  1.  I (",5,6,8,")[BPRTYPE D
  1.  . W ?110,"Fill type: "_$S(BPRTBCK=2:"RT",BPRTBCK=3:"BB",BPRTBCK=4:"P2",BPRTBCK=5:"RS",1:"RT,BB,P2,RS")
  1.  . W !,"Insurance: "_$S(BPINSINF=0:"ALL",1:$$BPINS(BPINSINF))
  1.  ;
  1.  I (",7,")[BPRTYPE W ?44,"Close Reason: ",$S(BPCCRSN'=0:"SELECTED",1:"ALL")
  1.  I (",4,")[BPRTYPE D
  1.  . W ?44,$J($S(BPAUTREV=0:"ALL",1:"AUTO"),4)," Reversals"
  1.  . W ?60,$J($S(BPACREJ=1:"REJECTED",BPACREJ=2:"ACCEPTED",1:"ALL"),8)," Returned Status"
  1.  ;
  1.  I (",5,6,8,")[BPRTYPE W ?87,"Drugs/Classes: "_$S(BPQSTDRG=2:$$DRGNAM^BPSRPT6(BPDRUG,30),BPQSTDRG=3:$E(BPDRGCL,1,30),1:"ALL")
  1.  I (",1,2,3,4,7,9,")[BPRTYPE  W ?87,"Drugs/Classes: "_$S(BPQSTDRG'=1:"SELECTED",1:"ALL")
  1.  ;
  1.  I (",2,")[BPRTYPE D
  1.  . W !,"Reject Code: ",$S(BPREJCD'=0:"SELECTED",1:"ALL")
  1.  . W ?87,"Eligibility: " D
  1.  . . I BPELIG1=0 W "CVA,TRI,VET" Q
  1.  . . S (ABVELIG,LIST,N)="" F  S N=$O(BPELIG1(N)) Q:N=""  D
  1.  . . . S ABVELIG=$S(N="C":"CVA",N="T":"TRI",N="V":"VET",1:""),LIST=LIST_$G(ABVELIG)_","
  1.  . . W $E(LIST,1,$L(LIST)-1)
  1.  . W ?113,"Open/Closed: ",$S(BPOPCL=1:"CLOSED",BPOPCL=2:"OPEN",1:"ALL")
  1.  . W !,"Prescriber: ",$S(BPRESC'=0:"SELECTED",1:"ALL")
  1.  . W ?91,"Patient: ",$S(BPQSTPAT'=0:"SELECTED",1:"ALL")
  1.  ;
  1.  I (",1,3,4,7,9,")[BPRTYPE D
  1.  . W !,"Eligibility: " D
  1.  . . I BPELIG1=0 W "CVA,TRI,VET" Q  ; ALL was selected
  1.  . . S (ABVELIG,LIST,N)="" F  S N=$O(BPELIG1(N)) Q:N=""  D
  1.  . . . S ABVELIG=$S(N="C":"CVA",N="T":"TRI",N="V":"VET",1:""),LIST=LIST_$G(ABVELIG)_","
  1.  . . W $E(LIST,1,$L(LIST)-1)
  1.  . W ?91,"Patient: ",$S(BPQSTPAT'=0:"SELECTED",1:"ALL")
  1.  ;
  1.  I (",9,")[BPRTYPE W !,"NON-BILLABLE STATUS: "_$S(BPNBSTS=0:"ALL",1:$$NBSTS(.BPNBSTS))
  1.  ;
  1.  I BPRTYPE=10 D
  1.  . W ?87,"Print Date: "_$G(BPNOW)_" Page:",$J(BPPAGE,3)
  1.  . W !,"DIVISION(S): ",$$GETDIVS^BPSRPT4(68,.BPPHARM)
  1.  . ; Fill Location, Fill Type and Drugs/Classes default to 'ALL', user not prompted
  1.  . W ?86,"Fill Locations: ALL"
  1.  . W ?110,"Fill Type: ALL"
  1.  . W !,"Insurance: "_$S(BPINSINF=0:"ALL",1:$$BPINS(BPINSINF))
  1.  . W ?87,"Drugs/Classes: ALL"
  1.  . W !,"Eligibility: " D
  1.  . . I BPELIG1=0 W "CVA,TRI,VET" Q
  1.  . . S (ABVELIG,LIST,N)="" F  S N=$O(BPELIG1(N)) Q:N=""  D
  1.  . . . S ABVELIG=$S(N="C":"CVA",N="T":"TRI",N="V":"VET",1:""),LIST=LIST_$G(ABVELIG)_","
  1.  . . W $E(LIST,1,$L(LIST)-1)
  1.  . W ?93,"Patient: ",$S(BPQSTPAT'=0:"SELECTED",1:"ALL")
  1.  . W !,"Status: "_$S(BPDUP=0:"ALL",1:BPDUP)
  1.  ;
  1.  W !,$S(BPRTYPE=5:"PRESCRIPTIONS",BPRLNRL=2:"RELEASED PRESCRIPTIONS",BPRLNRL=3:"PRESCRIPTIONS (NOT RELEASED)",1:"ALL PRESCRIPTIONS")
  1.  W " BY "_$S(BPRTYPE=7:"CLOSE",1:"TRANSACTION")_" DATE: "
  1.  W "From "_$$DATTIM^BPSRPT1(BPBEGDT)_" through "_$$DATTIM^BPSRPT1($P(BPENDDT,"."))
  1.  ;
  1.  I BPRTYPE=10 D
  1.  . W !!,"Status Codes: S= Duplicate of Approved, D= Duplicate of Paid, Q= Duplicate of Capture"
  1.  ;
  1.  D ULINE^BPSRPT5("=") Q:$G(BPQ)
  1.  D HEADLN1^BPSRPT4(BPRTYPE)
  1.  D HEADLN2^BPSRPT4(BPRTYPE)
  1.  D HEADLN3^BPSRPT4(BPRTYPE)
  1.  D ULINE^BPSRPT5("=")
  1.  ;
  1.  ;Print Division
  1.  I $G(BPDIV)]"" D
  1.  .W !,"DIVISION: ",$S(BPDIV=0:"BLANK",BPDIV="ALL DIVISIONS":"ALL DIVISIONS",$$DIVNAME^BPSSCRDS(BPDIV)]"":$$DIVNAME^BPSSCRDS(BPDIV),1:BPDIV)
  1.  .I BPRTYPE=5!(BPRTYPE=6)!(BPSUMDET=1)!(BPGRPLAN="") D ULINE^BPSRPT5("-")
  1.  ;
  1.  ;Print Insurance If Defined
  1.  I BPSUMDET=0,$G(BPGRPLAN)]"",$G(BPGRPLAN)'=0,$G(BPGRPLAN)'="~" D WRPLAN^BPSRPT5(BPGRPLAN)
  1.  Q
  1.  ;
  1.  ;Special Division Handling
  1.  ;
  1. BPDIV(BPDIV) Q $S(BPDIV=0:"BLANK",$$DIVNAME^BPSSCRDS(BPDIV)]"":$$DIVNAME^BPSSCRDS(BPDIV),1:BPDIV)
  1.  ;
  1.  ;Get selected insurance names based on user selection
  1.  ;If length is greater than 68 append "..."
  1.  ;Input: BPINSINF = Semi-colon separated list of file 36 IENs
  1.  ;Output: comma separated list of related file 36 names
  1. BPINS(BPINSINF) ;
  1.  N BPINS,BPINAME,RETV
  1.  S RETV=""
  1.  F I=2:1 S BPINS=$P($G(BPINSINF),";",I) Q:BPINS=""  D
  1.  . S BPINAME=$$INSNM^IBNCPDPI(BPINS) Q:BPINAME=""
  1.  . I RETV'="" S RETV=RETV_", "_BPINAME Q
  1.  . S RETV=BPINAME
  1.  I $L(RETV)>68 S RETV=$E(RETV,1,68)_"..."
  1.  Q RETV
  1.  ;
  1. ELIG(ELIG) ;
  1.  ; Display multiple eligibilities
  1.  ; Input:
  1.  ;   ELIG - Array of multiple eligibilities
  1.  ; Output
  1.  ;   Text of eligibilities
  1.  ;
  1.  I $D(ELIG)=0 Q ""
  1.  N N,LIST
  1.  S LIST=""
  1.  S N="" F  S N=$O(ELIG(N)) Q:N=""  D
  1.  . S LIST=LIST_$G(ELIG(N))_","
  1.  Q $E(LIST,1,$L(LIST)-1)
  1.  ;
  1. NBSTS(NBSTS) ;
  1.  ; Display multiple non-billable statuses
  1.  ; Input:
  1.  ;   NBSTS - Array of multiple non-billable statuses
  1.  ; Output
  1.  ;   Text of non-billable statuses
  1.  ;
  1.  I $D(NBSTS)=0 Q ""
  1.  N N,LIST
  1.  S LIST=""
  1.  S N="" F  S N=$O(NBSTS(N)) Q:N=""  D
  1.  . S LIST=LIST_$G(NBSTS(N))_","
  1.  Q $E(LIST,1,$L(LIST)-1)