Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: DGBTR123

DGBTR123.m

Go to the documentation of this file. 
  1. DGBTR123 ;ALB/RFE - CLERK REPORT; 06/04/12
  1.  ;;1.0;Beneficiary Travel;**20**;November 11, 2011;Build 185
  1.  Q
  1. EN ;Entry point
  1.  N %,%Y,CCFEE,CLERK,CLERKALL,CLERKNAME,DATALINE,DFN,DGBTDIVN,DGBTEXC,DGBTQ,EQUAL,ENDDT,ENTRY,GRAND,I,LINEM,LINESP,LINEZERO,PAGE,PDT,PATZERO,POP
  1.  N PROMPT,REPTYPE,SQ1,SQ2,STARTDT,SUBS,TYPE,X,X2,X3,Y,ZTQUEUED
  1.  D CLEAN^DILF
  1.  S X2="2$",DGBTEXC=0
  1.  K DIR
  1.  S DIR("A")="START DATE: ",DIR(0)="DA^2991231:NOW:EX" D ^DIR K DIR
  1.  I ($D(DIRUT))!($D(DIROUT)) D CLEAN^DILF Q
  1.  S STARTDT=Y
  1.  S DIR("A")="END DATE: ",DIR(0)="DA^"_STARTDT_":NOW:EX" D ^DIR K DIR
  1.  I ($D(DIRUT))!($D(DIROUT)) D CLEAN^DILF Q
  1.  S ENDDT=Y
  1.  D
  1.  .I $$GET1^DIQ(43,1,11,"I") D  Q
  1.  ..S DGBTDIVN=$$YESNO^DGBTUTL("Do you wish to run this report for all divisions")
  1.  ..I DGBTDIVN S DGBTDIVN="ALL" Q
  1.  ..I (($D(DIRUT))!($D(DTOUT))!($D(DUOUT))) Q
  1.  ..K DIR S DIR(0)="P^40.8:EMZ" D ^DIR K DIR
  1.  ..I (($D(DIRUT))!($D(DTOUT))!($D(DUOUT))) Q
  1.  ..S DGBTDIVN=+Y
  1.  .S DGBTDIVN=$O(^DG(40.8,0))
  1.  I (($D(DIRUT))!($D(DTOUT))!($D(DUOUT))) D CLEAN^DILF Q
  1.  K DIR
  1.  S DIR(0)="S^M:MILEAGE;S:SPECIAL MODE",DIR("A")="Which claim type do you want to run?" D ^DIR K DIR
  1.  I (($D(DIRUT))!($D(DTOUT))!($D(DUOUT))) D CLEAN^DILF Q
  1.  S TYPE=Y
  1.  S CLERKALL=$$YESNO^DGBTUTL("Do you wish to run this report for all clerks")
  1.  I (($D(DIRUT))!($D(DTOUT))!($D(DUOUT))) D CLEAN^DILF Q
  1.  S CLERK=""
  1.  I 'CLERKALL D
  1.  .K DIR S DIR(0)="P^200:EMZ",DIR("A")="Select CLERK" D ^DIR K DIR
  1.  .I (($D(DIRUT))!($D(DTOUT))!($D(DUOUT))) Q
  1.  .S CLERK=$P(Y,U)
  1.  I (($D(DIRUT))!($D(DTOUT))!($D(DUOUT))) D CLEAN^DILF Q
  1.  K DIR
  1.  S DIR(0)="S^F:FULL;T:TOTAL",DIR("A")="Which claim type do you want to run?" D ^DIR K DIR
  1.  I (($D(DIRUT))!($D(DTOUT))!($D(DUOUT))) D CLEAN^DILF Q
  1.  S REPTYPE=Y
  1.  D SETPRT,QUIT
  1.  Q
  1. SETPRT ;
  1.  S DGBTEXC=$$SELEXCEL^DGBTUTL
  1.  I DGBTEXC="^" Q
  1.  S SUBS=DGBTEXC_U_STARTDT_U_ENDDT_U_DGBTDIVN_U_TYPE_U_REPTYPE_U_CLERKALL_U_CLERK
  1.  I 'DGBTEXC N COLWID S COLWID=132 D PRINTMSG^DGBTUTL
  1.  D DEVICE^DGBTUTL("Beneficiary Travel Clerk Report","MAIN^DGBTR123(SUBS)",DGBTEXC,132)
  1.  I $G(DGBTQ) Q
  1.  ;
  1.  I $D(IO("Q")) D:'$D(ZTQUEUED) ^%ZISC Q
  1.  D MAIN(SUBS)
  1.  D:'$D(ZTQUEUED) ^%ZISC
  1.  U IO
  1.  Q
  1. MAIN(SUBS) ;
  1.  K ^TMP("DGBTRPTC",$J)
  1.  S DGBTEXC=$P(SUBS,U)
  1.  S STARTDT=$P(SUBS,U,2)
  1.  S ENDDT=$P(SUBS,U,3)
  1.  S DGBTDIVN=$P(SUBS,U,4)
  1.  S TYPE=$P(SUBS,U,5)
  1.  S REPTYPE=$P(SUBS,U,6)
  1.  S CLERKALL=$P(SUBS,U,7)
  1.  S CLERK=$P(SUBS,U,8)
  1.  S CLERKNAME=$$GET1^DIQ(200,CLERK,.01)
  1.  D GETRECS
  1.  I '$D(^TMP("DGBTRPTC",$J)) W !,"No records found" D QUIT Q
  1.  D PRINT
  1.  Q
  1. GETRECS ;
  1.  I ((TYPE="M")&(REPTYPE="F")) F I="CLAIMS","TOT MILE","CC FEE","ECON","M&L","F&B","DED","PAY" S GRAND(I)=0
  1.  I ((TYPE="M")&(REPTYPE="T")) F I="MILE","CC FEE","ECON","M&L","F&B","DED","PAY" S GRAND(I)=0
  1.  I ((TYPE="S")&(REPTYPE="F")) F I="CLAIMS","MILE","BASE RATE","NSNL","WAIT TIME","EXTRA CREW","SPECIAL EQUIPMENT","INVOICE AMT" S GRAND(I)=0
  1.  I ((TYPE="S")&(REPTYPE="T")) F I="CLAIMS","MILE","BASE RATE","NSNL","WAIT TIME","EXTRA CREW","SPECIAL EQUIPMENT","INVOICE AMT" S GRAND(I)=0
  1.  S ENTRY=$O(^DGBT(392,"D",STARTDT),-1)
  1.  F  S ENTRY=$O(^DGBT(392,"D",ENTRY)) Q:ENTRY=""  Q:ENTRY>ENDDT  D
  1.  .S I=""
  1.  .F  S I=$O(^DGBT(392,"D",ENTRY,I)) Q:I=""  D GETLINE
  1.  Q
  1. GETLINE ;
  1.  S LINEZERO=$G(^DGBT(392,I,0)) Q:'$$CLERK
  1.  I $$GET1^DIQ(392,I,45.2,"I") Q  ;'="NO" Q
  1.  I '$$DIV Q
  1.  S DATALINE=""
  1.  S SQ1=$P(LINEZERO,"^",13)_"^"_$P(LINEZERO,"^",12)
  1.  I TYPE="M" D GLMILE
  1.  I TYPE="S" D GLSP
  1.  I DATALINE'="" S ^TMP("DGBTRPTC",$J,SQ1,SQ2)=DATALINE
  1.  Q
  1. DIV() ;
  1.  I DGBTDIVN="ALL" Q 1
  1.  Q $P(LINEZERO,U,11)=DGBTDIVN
  1. CLERK() ;
  1.  I CLERKALL Q 1
  1.  Q $P(LINEZERO,"^",12)=CLERK
  1. GLMILE ;
  1.  I $$GET1^DIQ(392,I,56,"I")'="M" Q
  1.  S LINEM=$G(^DGBT(392,I,"M"))
  1.  S CCFEE=$$GET1^DIQ(392,$P(LINEZERO,U),55)
  1.  I REPTYPE="F" D GLMILEF
  1.  I REPTYPE="T" D GLMILET
  1.  Q
  1. GLMILEF ; Mileage full
  1.  S SQ2=$O(^TMP("DGBTRPTC",$J,SQ1,""),-1)+1
  1.  S DFN=$P(LINEZERO,U,2) Q:DFN=""
  1.  S PATZERO=$G(^DPT(DFN,0))
  1.  S DATALINE=$P(PATZERO,U) ; Pat name
  1.  S GRAND("CLAIMS")=GRAND("CLAIMS")+1
  1.  S $P(DATALINE,U,2)=$P(PATZERO,U,9) ; Pat ID
  1.  S $P(DATALINE,U,3)=$$FMTE^XLFDT($P($P(LINEZERO,U),".")) ; Claim date/time
  1.  I DGBTEXC S $P(DATALINE,U,3)=$P($P(DATALINE,U,3),"@")
  1.  S $P(DATALINE,U,4)=$$GET1^DIQ(40.8,$P(LINEZERO,U,11),.01) ; Division
  1.  S $P(DATALINE,U,5)=$$GET1^DIQ(392.3,$P(LINEZERO,U,6),2) ; Account
  1.  S $P(DATALINE,U,6)=$S($P(LINEM,U)=1:"O",1:"R")
  1.  S $P(DATALINE,U,7)=$P(LINEM,U)*$P(LINEM,U,2) ; Total mileage
  1.  S GRAND("TOT MILE")=GRAND("TOT MILE")+($P(LINEM,U)*$P(LINEM,U,2))
  1.  S $P(DATALINE,U,8)=$$GET1^DIQ(392,$P(LINEZERO,U),44) ; Common carrier mode
  1.  S $P(DATALINE,U,9)=$$DLRAMT(CCFEE) ; Common carrier fee
  1.  S GRAND("CC FEE")=GRAND("CC FEE")+$$GET1^DIQ(392,$P(LINEZERO,U),55)
  1.  S $P(DATALINE,U,10)=$$DLRAMT($P(LINEZERO,U,8)) ; Most economical cost
  1.  S GRAND("ECON")=GRAND("ECON")+$P(LINEZERO,U,8)
  1.  S $P(DATALINE,U,11)=$$DLRAMT($P(LINEM,U,4)) ; Meals & lodging
  1.  S GRAND("M&L")=GRAND("M&L")+$P(LINEM,U,4)
  1.  S $P(DATALINE,U,12)=$$DLRAMT($P(LINEM,U,5)) ; Ferries & bridges
  1.  S GRAND("F&B")=GRAND("F&B")+$P(LINEM,U,5)
  1.  S $P(DATALINE,U,13)=$$DLRAMT($P(LINEZERO,U,9)) ; Deductible
  1.  S GRAND("DED")=GRAND("DED")+$P(LINEZERO,U,9)
  1.  S $P(DATALINE,U,14)=$$DLRAMT($P(LINEZERO,U,10)) ; Payable
  1.  S GRAND("PAY")=GRAND("PAY")+$P(LINEZERO,U,10)
  1.  S $P(DATALINE,U,15)=$TR($$GET1^DIQ(392,$P(LINEZERO,U),51),"^","") ; Remarks
  1.  Q
  1. GLMILET ; Mileage total
  1.  S $P(SQ1,"^",3)=$P(LINEZERO,U,11)
  1.  S $P(SQ1,"^",4)=$P(LINEZERO,U,6)
  1.  S SQ2=0
  1.  S DATALINE=$G(^TMP("DGBTRPTC",$J,SQ1,SQ2))
  1.  S $P(DATALINE,U)=($P(LINEM,U)*$P(LINEM,U,2))+$P(DATALINE,U) ; MILEAGE
  1.  S $P(DATALINE,U,2)=$$GET1^DIQ(392,I,55)+$P(DATALINE,U,2) ;COMMON CARRIER FEE
  1.  S GRAND("CC FEE")=GRAND("CC FEE")+CCFEE
  1.  S $P(DATALINE,U,3)=$P(LINEZERO,U,8)+$P(DATALINE,U,3) ; MOST ECONOMICAL COST
  1.  S GRAND("ECON")=GRAND("ECON")+$P(LINEZERO,U,8)
  1.  S $P(DATALINE,U,4)=$P(LINEM,U,4)+$P(DATALINE,U,4) ; MEALS & LODGING
  1.  S GRAND("M&L")=GRAND("M&L")+$P(LINEM,U,4)
  1.  S $P(DATALINE,U,5)=$P(LINEM,U,5)+$P(DATALINE,U,5) ; FERRIES & BRIDGES
  1.  S GRAND("F&B")=GRAND("F&B")+$P(LINEM,U,5)
  1.  S $P(DATALINE,U,6)=$P(LINEZERO,U,9)+$P(DATALINE,U,6) ; DEDUCTIBLE
  1.  S GRAND("DED")=GRAND("DED")+$P(LINEZERO,U,9)
  1.  S $P(DATALINE,U,7)=$P(LINEZERO,U,10)+$P(DATALINE,U,7) ; PAYABLE
  1.  S GRAND("PAY")=GRAND("PAY")+$P(LINEZERO,U,10)
  1.  Q
  1. GLSP ;
  1.  I $$GET1^DIQ(392,I,56,"I")'="S" Q
  1.  S LINESP=$G(^DGBT(392,I,"SP"))
  1.  I REPTYPE="F" D GLSPF
  1.  I REPTYPE="T" D GLSPT
  1.  Q
  1. GLSPF ; Special mode full
  1.  S SQ2=$O(^TMP("DGBTRPTC",$J,SQ1,""),-1)+1
  1.  S DFN=$P(LINEZERO,U,2) Q:DFN=""
  1.  S PATZERO=$G(^DPT(DFN,0))
  1.  S DATALINE=$P(PATZERO,U) ; Pat name
  1.  S GRAND("CLAIMS")=GRAND("CLAIMS")+1
  1.  S $P(DATALINE,U,2)=$P(PATZERO,U,9) ; Pat ID
  1.  S $P(DATALINE,U,3)=$$FMTE^XLFDT($P($P(LINEZERO,U),".")) ; Claim date/time
  1.  I DGBTEXC S $P(DATALINE,U,3)=$P($P(DATALINE,U,3),"@")
  1.  S $P(DATALINE,U,4)=$$GET1^DIQ(40.8,$P(LINEZERO,U,11),.01) ; Division
  1.  S $P(DATALINE,U,5)=$$GET1^DIQ(392.3,$P(LINEZERO,U,6),2) ; Account
  1.  S $P(DATALINE,U,6)=$P(LINESP,U,12) ; Mileage
  1.  S GRAND("MILE")=GRAND("MILE")+$P(LINESP,U,12)
  1.  S $P(DATALINE,U,7)=$$DLRAMT($P(LINESP,U,5)) ; Base rate fee
  1.  S GRAND("BASE RATE")=GRAND("BASE RATE")+$P(LINESP,U,5)
  1.  S $P(DATALINE,U,8)=$$DLRAMT($P(LINESP,U,7)) ; No show/no load fee
  1.  S GRAND("NSNL")=GRAND("NSNL")+$P(LINESP,U,7)
  1.  S $P(DATALINE,U,9)=$$DLRAMT($P(LINESP,U,8)) ; Wait time fee
  1.  S GRAND("WAIT TIME")=GRAND("WAIT TIME")+$P(LINESP,U,8)
  1.  S $P(DATALINE,U,10)=$$DLRAMT($P(LINESP,U,9)) ; Extra crew fee
  1.  S GRAND("EXTRA CREW")=GRAND("EXTRA CREW")+$P(LINESP,U,9)
  1.  S $P(DATALINE,U,11)=$$DLRAMT($P(LINESP,U,10)) ; Special equipment fee
  1.  S GRAND("SPECIAL EQUIPMENT")=GRAND("SPECIAL EQUIPMENT")+$P(LINESP,U,10)
  1.  S $P(DATALINE,U,12)=$$DLRAMT($P(LINESP,U,4)) ; Invoice
  1.  S GRAND("INVOICE AMT")=GRAND("INVOICE AMT")+$P(LINESP,U,4)
  1.  S $P(DATALINE,U,13)=$TR($P(LINESP,U,26),"^","") ; Remarks
  1.  Q
  1. GLSPT ; Special mode total
  1.  S $P(SQ1,"^",3)=$P(LINEZERO,U,11)
  1.  S $P(SQ1,"^",4)=$P(LINEZERO,U,6)
  1.  S SQ2=0
  1.  S DATALINE=$G(^TMP("DGBTRPTC",$J,SQ1,SQ2))
  1.  S $P(DATALINE,U)=1+$P(DATALINE,U) ; TOTAL CLAIMS
  1.  S GRAND("CLAIMS")=GRAND("CLAIMS")+1
  1.  S $P(DATALINE,U,2)=$P(LINESP,U,12)+$P(DATALINE,U,2) ; MILEAGE
  1.  S GRAND("MILE")=GRAND("MILE")+$P(LINESP,U,12)
  1.  S $P(DATALINE,U,3)=$P(LINESP,U,5)+$P(DATALINE,U,3) ; BASE RATE FEE
  1.  S GRAND("BASE RATE")=GRAND("BASE RATE")+$P(LINESP,U,5)
  1.  S $P(DATALINE,U,4)=$P(LINESP,U,7)+$P(DATALINE,U,4) ; NO LOAD/NO SHOW
  1.  S GRAND("NSNL")=GRAND("NSNL")+$P(LINESP,U,7)
  1.  S $P(DATALINE,U,5)=$P(LINESP,U,8)+$P(DATALINE,U,5) ; WAIT TIME
  1.  S GRAND("WAIT TIME")=GRAND("WAIT TIME")+$P(LINESP,U,8)
  1.  S $P(DATALINE,U,6)=$P(LINESP,U,9)+$P(DATALINE,U,6) ; EXTRA CREW
  1.  S GRAND("EXTRA CREW")=GRAND("EXTRA CREW")+$P(LINESP,U,9)
  1.  S $P(DATALINE,U,7)=$P(LINESP,U,10)+$P(DATALINE,U,7) ; SPECIAL EQUIPMENT
  1.  S GRAND("SPECIAL EQUIPMENT")=GRAND("SPECIAL EQUIPMENT")+$P(LINESP,U,10)
  1.  S $P(DATALINE,U,8)=$P(LINESP,U,4)+$P(DATALINE,U,8) ; TOTAL INVOICE AMOUNT
  1.  S GRAND("INVOICE AMT")=GRAND("INVOICE AMT")+$P(LINESP,U,4)
  1.  Q
  1. PRINT ;
  1.  U IO
  1.  S PAGE=0,$P(EQUAL,"=",133)=""
  1.  D NOW^%DTC S Y=% D DD^%DT S PDT=Y
  1.  I DGBTEXC D
  1.  .I (TYPE="M")&(REPTYPE="F") D
  1.  ..W "DATE ENTERED^PATIENT^PATIENT ID^CLERK^CLAIM DATE^DIVISION^ACCT^R/O^MILEAGE^CC MODE^CC FEE^MOST ECONOMIC^M & L^FERRIES & BRIDGES^DEDUCTIBLE^AMOUNT PAYABLE^REMARK"
  1.  .I (TYPE="M")&(REPTYPE="T") D
  1.  ..W "DATE ENTERED^CLERK^DIVISION^ACCT^MILEAGE^CC FEE^MOST ECONOMIC^M & L^FERRIES &BRIDGES^DEDUCTIBLE^AMOUNT PAYABLE"
  1.  .I (TYPE="S")&(REPTYPE="F") D
  1.  ..W "DATE ENTERED^PATIENT^PATIENT ID^CLERK^CLAIM DATE^DIVISION^ACCT^MILEAGE^BASE RATE^NO SHOW NO LOAD^WAIT TIME^EXTRA CREW^SPECIAL EQUIPMENT^INVOICE AMOUNT^REMARK"
  1.  .I (TYPE="S")&(REPTYPE="T") D
  1.  ..W "DATE ENTERED^CLERK^DIVISION^ACCT^# CLAIMS^MILEAGE^BASE RATE^NO SHOW NO LOAD^WAIT TIME^EXTRA CREW^SPECIAL EQUIPMENT^INVOICE AMOUNT"
  1.  I (TYPE="M")&(REPTYPE="F")&('DGBTEXC) D HDRMF^DGBTR3A
  1.  I (TYPE="M")&(REPTYPE="T")&('DGBTEXC) D HDRMT
  1.  I (TYPE="S")&(REPTYPE="F")&('DGBTEXC) D HDRSF
  1.  I (TYPE="S")&(REPTYPE="T")&('DGBTEXC) D HDRST
  1.  S (PROMPT,SQ1)=""
  1.  F  S SQ1=$O(^TMP("DGBTRPTC",$J,SQ1)) Q:SQ1=""  D  Q:PROMPT="^"
  1.  .S SQ2=""
  1.  .F  S SQ2=$O(^TMP("DGBTRPTC",$J,SQ1,SQ2)) Q:SQ2=""  D  Q:PROMPT="^"
  1.  ..S DATALINE=^TMP("DGBTRPTC",$J,SQ1,SQ2)
  1.  ..I DGBTEXC D PRTXL Q
  1.  ..I (TYPE="M")&(REPTYPE="F")&(($Y+4)>IOSL) D  Q:PROMPT="^"
  1.  ...D HDRMF^DGBTR3A
  1.  ..I (TYPE="M")&(REPTYPE="F") D
  1.  ...W !,$P(DATALINE,U),?32,$P(DATALINE,U,2),?43,$$GET1^DIQ(200,$P(SQ1,U,2),.01),?78,$P(DATALINE,U,3),?92,$$FMTE^XLFDT($P(SQ1,U))
  1.  ...W ?109,$P(DATALINE,U,5)
  1.  ...W !,?5,$P(DATALINE,U,4),?42,$P(DATALINE,U,6),?48,$P(DATALINE,U,7),?54,$P(DATALINE,U,8),?92,$P(DATALINE,U,9),?107,$P(DATALINE,U,10)
  1.  ...W ?119,$P(DATALINE,U,11)
  1.  ...W !,?5,$P(DATALINE,U,12),?17,$P(DATALINE,U,13),?25,$P(DATALINE,U,14),?38,$P(DATALINE,U,15)
  1.  ..I (TYPE="S")&(REPTYPE="F")&(($Y+4)>IOSL) D  Q:PROMPT="^"
  1.  ...D HDRSF
  1.  ..I (TYPE="S")&(REPTYPE="F") D
  1.  ...W !,$P(DATALINE,U),?32,$P(DATALINE,U,2),?43,$$GET1^DIQ(200,$P(SQ1,U,2),.01),?78,$P(DATALINE,U,3),?92,$$FMTE^XLFDT($P(SQ1,U))
  1.  ...W ?109,$P(DATALINE,U,5)
  1.  ...W !,?5,$P(DATALINE,U,4),?42,$P(DATALINE,U,6),?50,$P(DATALINE,U,7),?65,$P(DATALINE,U,8),?79,$P(DATALINE,U,9),?90,$P(DATALINE,U,10)
  1.  ...W ?102,$P(DATALINE,U,11),?116,$P(DATALINE,U,12)
  1.  ...W !,?5,$P(DATALINE,U,13)
  1.  ..I (TYPE="M")&(REPTYPE="T")&(($Y+3)>IOSL) D  Q:PROMPT="^"
  1.  ...D HDRMT
  1.  ..I (TYPE="M")&(REPTYPE="T") D
  1.  ...W !,$$GET1^DIQ(40.8,$P(SQ1,U,3),.01),?37,$$FMTE^XLFDT($P(SQ1,U)),?50,$$GET1^DIQ(392.3,$P(SQ1,U,4),2),?55,$P(DATALINE,U)
  1.  ...W ?63,$$DLRAMT($P(DATALINE,U,2)),?78,$$DLRAMT($P(DATALINE,U,3)),?90,$$DLRAMT($P(DATALINE,U,4)),?103,$$DLRAMT($P(DATALINE,U,5))
  1.  ...W !,?5,$$DLRAMT($P(DATALINE,U,6)),?18,$$DLRAMT($P(DATALINE,U,7)),?29,$$GET1^DIQ(200,$P(SQ1,U,2),.01)
  1.  ..I (TYPE="S")&(REPTYPE="T")&(($Y+3)>IOSL) D  Q:PROMPT="^"
  1.  ...D HDRST
  1.  ..I (TYPE="S")&(REPTYPE="T") D
  1.  ...W !,$$GET1^DIQ(40.8,$P(SQ1,U,3),.01),?37,$$FMTE^XLFDT($P(SQ1,U)),?50,$$GET1^DIQ(392.3,$P(SQ1,U,4),2),?55,$P(DATALINE,U,2)
  1.  ...W ?63,$P(DATALINE,U),?72,$$DLRAMT($P(DATALINE,U,3)),?87,$$DLRAMT($P(DATALINE,U,4)),?102,$$DLRAMT($P(DATALINE,U,5))
  1.  ...W ?117,$$DLRAMT($P(DATALINE,U,6))
  1.  ...W !,?5,$$DLRAMT($P(DATALINE,U,7)),?15,$$DLRAMT($P(DATALINE,U,8)),?25,$$GET1^DIQ(200,$P(SQ1,U,2),.01)
  1.  ..Q
  1.  I 'DGBTEXC D
  1.  .I ($Y+4)<IOSL W !!!
  1.  .I (REPTYPE="F"),(TYPE="M") D GRANDMF^DGBTR3A
  1.  .I (REPTYPE="T"),(TYPE="M") D GRANDMT^DGBTR3A
  1.  .I (REPTYPE="F"),(TYPE="S") D GRANDSF^DGBTR3A
  1.  .I (REPTYPE="T"),(TYPE="S") D GRANDST^DGBTR3A
  1.  I IOST["C-" S Y=$$PAUSE^DGBTUTL(DGBTEXC)
  1.  I IOST'["C-" W !,"REPORT HAS FINISHED"
  1.  Q
  1. PRTXL ;
  1.  I REPTYPE="F" D
  1.  .W !,$$FMTE^XLFDT($P(SQ1,U)),U,$P(DATALINE,U),U,$P(DATALINE,U,2),U,$$GET1^DIQ(200,$P(SQ1,U,2),.01) F I=3:1:$L(DATALINE,U) W U,$P(DATALINE,U,I)
  1.  I REPTYPE="T" D
  1.  .W !,$$FMTE^XLFDT($P(SQ1,U)),U,$$GET1^DIQ(200,$P(SQ1,U,2),.01),U,$$GET1^DIQ(40.8,$P(SQ1,U,3),.01),U,$$GET1^DIQ(392.3,$P(SQ1,U,4),2)
  1.  .I TYPE="M" D
  1.  ..W U,$P(DATALINE,U,1)
  1.  ..F I=2:1:$L(DATALINE,U) W U,$$DLRAMT($P(DATALINE,U,I))
  1.  .I TYPE="S" D
  1.  ..F I=1,2 W U,$P(DATALINE,U,I)
  1.  ..F I=3:1:$L(DATALINE,U) W U,$$DLRAMT($P(DATALINE,U,I))
  1.  Q
  1. DLRAMT(X) ;
  1.  D COMMA^%DTC I 'DGBTEXC Q $TR(X," ","")
  1.  Q $TR(X," ,$","")
  1. HDRMT ;
  1.  S PAGE=PAGE+1
  1.  W @IOF
  1.  W "BT CLERK REPORT      PRINT DATE: ",PDT,?(126-$L(PAGE)),"PAGE ",PAGE
  1.  W !,$$FMTE^XLFDT(STARTDT)," TO ",$$FMTE^XLFDT(ENDDT)
  1.  W !,"VERSION: TOTAL"
  1.  W !,"TYPE: MILEAGE"
  1.  W !,"DIVISION: ",$S(DGBTDIVN="ALL":"ALL",1:$$GET1^DIQ(40.8,DGBTDIVN,.01))
  1.  W !,"CLERK: ",$S(CLERKALL:"ALL",1:CLERKNAME)
  1.  W !,$E(EQUAL,1,117)
  1.  W !,"DIVISION",?37,"ENTERED",?50,"ACCT",?55,"MILEAGE",?63,"CC FEE",?78,"MOST ECON",?90,"M&L",?103,"F&B"
  1.  W !,?5,"DED",?18,"PAYABLE",?29,"CLERK"
  1.  W !,$E(EQUAL,1,117)
  1.  Q
  1. HDRSF ;
  1.  S PAGE=PAGE+1
  1.  W @IOF
  1.  W "BT CLERK REPORT      PRINT DATE: ",PDT,?(126-$L(PAGE)),"PAGE ",PAGE
  1.  W !,$$FMTE^XLFDT(STARTDT)," TO ",$$FMTE^XLFDT(ENDDT)
  1.  W !,"VERSION: FULL"
  1.  W !,"TYPE: SPECIAL MODE"
  1.  W !,"DIVISION: ",$S(DGBTDIVN="ALL":"ALL",1:$$GET1^DIQ(40.8,DGBTDIVN,.01))
  1.  W !,"CLERK: ",$S(CLERKALL:"ALL",1:CLERKNAME)
  1.  W !,$E(EQUAL,1,124)
  1.  W !,"PATIENT NAME",?32,"SSN",?43,"CLERK",?78,"CL DT",?92,"ENT DT",?109,"ACCT"
  1.  W !,?5,"DIVISION",?42,"MILEAGE",?50,"BASE RATE",?65,"NSNL",?79,"WAIT TIME",?90,"EX CREW",?102,"SPEC EQ",?116,"INV AMT"
  1.  W !,?5,"REMARKS"
  1.  W !,$E(EQUAL,1,124)
  1.  Q
  1. HDRST ;
  1.  S PAGE=PAGE+1
  1.  W @IOF
  1.  W "BT CLERK REPORT      PRINT DATE: ",PDT,?(126-$L(PAGE)),"PAGE ",PAGE
  1.  W !,$$FMTE^XLFDT(STARTDT)," TO ",$$FMTE^XLFDT(ENDDT)
  1.  W !,"VERSION: TOTAL"
  1.  W !,"TYPE: SPECIAL MODE"
  1.  W !,"DIVISION: ",$S(DGBTDIVN="ALL":"ALL",1:$$GET1^DIQ(40.8,DGBTDIVN,.01))
  1.  W !,"CLERK: ",$S(CLERKALL:"ALL",1:CLERKNAME)
  1.  W !,$E(EQUAL,1,127)
  1.  W !,"DIVISION",?37,"ENTERED",?50,"ACCT",?55,"MILEAGE",?63,"CLAIMS",?72,"BASE RATE",?87,"NSNL",?102,"WAIT TIME",?117,"EXTRA CREW"
  1.  W !,?5,"SPEC EQ",?15,"INV AMT",?25,"CLERK"
  1.  W !,$E(EQUAL,1,127)
  1.  Q
  1. QUIT ;
  1.  K ^TMP("DGBTRPTC",$J)
  1.  D CLEAN^DILF
  1.  Q