Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: DGPMSTAT

DGPMSTAT.m

Go to the documentation of this file.
  1. DGPMSTAT ;ALB/JDS - DETERMINE INPATIENT STATUS - FORMERLY DGINPW ;01 JAN 1986
  1. ;;5.3;Registration;**36,246**;Aug 13, 1993
  1. ;
  1. ; Note: This used to be named 'DGINPW'
  1. ; ------
  1. ;
  1. EN ; -- call to return coresp adm and mvt data of pt as of a date
  1. ; input: DFN => patient file ifn
  1. ; DGT => date to check if pt was inpatient
  1. ; output: DGA1 => coresp adm mvt ifn of ^DGPM
  1. ; DG1 => ward ^ room-bed ^ mvt type(for xfrs only)
  1. ; DGXFR0 => Oth of last xfr mvt for admission
  1. ; -- init
  1. N MT,IAD,IMD,DGCA,DGDC ; Inverse Adm Date & Inverse Mvt Date
  1. S DG1=""
  1. ;
  1. ; -- scan adms for pt
  1. ; -- if still inpt or d/c > DGT date then continue to CA
  1. ;F IAD=9999999.9999998-DGT:0 S IAD=$O(^DGPM("ATID1",DFN,IAD)) Q:'IAD S DGA1=+$O(^(IAD,0)) I $D(^DGPM(DGA1,0)),$S('$D(^DGPM(+$P(^(0),"^",17),0)):1,1:^(0)>DGT) D CA Q:DG1
  1. F IAD=9999999.9999998-DGT:0 S IAD=$O(^DGPM("ATID1",DFN,IAD)) Q:'IAD S DGA1=+$O(^(IAD,0)),DGCA=$G(^DGPM(DGA1,0)),DGDC=$G(^DGPM(+$P(DGCA,U,17),0)) D Q:DG1!($P(DGCA,U,18)'=40)
  1. .I 'DGDC!(DGDC>DGT) D CA I $P(%,U,18)=43!($P(%,U,18)=45) S DG1="" Q
  1. K DGNO Q
  1. ;
  1. CA ; -- scan mvts for cor. adm that happened on or before DGT date
  1. ; -- if mvt is adm or xfr then set DG1
  1. ; -- if mvt is xfr then continue to XFR
  1. S %=""
  1. F IMD=9999999.9999998-DGT:0 S IMD=$O(^DGPM("APMV",DFN,DGA1,IMD)) Q:'IMD I $D(^DGPM(+$O(^(IMD,0)),0)) S %=^(0),MT=$P(%,"^",2) I MT=1!(MT=2) S DG1=$P(%,"^",6,7) D XFR:MT=2 Q:DG1
  1. CAQ Q
  1. ;
  1. XFR ; -- set DG1="" if XFR to asih(oth fac) --ELSE-- add MVT type to DG1
  1. S DGXFR0=%,DG1=$S($P(%,"^",18)=13:"",1:DG1_"^"_$P(%,"^",18))
  1. Q
  1. ;
  1. TREAT S DG2=0 D EN:'$D(DG1) Q:'DG1 S DG2=9999999 D TREAT1
  1. I +DG2=9999999 S DG2=0 Q
  1. S DG2=$S($D(^DIC(45.7,+DG2,0)):+$P(^(0),U,2),1:0)
  1. Q
  1. TREAT1 F DGID=0:0 S DGID=$O(^DGPM("ATS",DFN,DGA1,DGID)) Q:'DGID F DGS=0:0 S DGS=$O(^DGPM("ATS",DFN,DGA1,DGID,DGS)) Q:'DGS F DGDA=0:0 S DGDA=$O(^DGPM("ATS",DFN,DGA1,DGID,DGS,DGDA)) Q:'DGDA I ^DGPM(+DGDA,0) S DGX=^(0) D TR2
  1. Q
  1. TR2 I +DGX<(DGT+.1)&(+DGX<+DG2) S DG2=DGS
  1. Q
  1. DGT(X) ; FIGURE OUT WHICH TYPE OF DATE TO USE FOR DGWARDWHEN
  1. ; Input: X=Date in either FM format or regular date
  1. ; Output: Date in FM format
  1. N Y,%DT
  1. I '$D(X) S X=DT G DGTQ
  1. S %DT="T" D ^%DT S X=Y
  1. DGTQ Q X