Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: DGQPTQ6

DGQPTQ6.m

Go to the documentation of this file. 
  1. DGQPTQ6 ; SLC/PKS - Combination pt. list cont. ;6/5/01 12:38pm
  1.  ;;5.3;Registration;**447**;Aug 13, 1993
  1.  ;
  1.  ; Called by BUILD^DGQPT
  1.  ;
  1.  Q
  1.  ;
  1. COMBPTS(DGQLM,DGQCPTR,DGBDATE,DGEDATE) ; Build "Combination" pt. list.
  1.  ; SLC/PKS.
  1.  ;
  1.  ; NOTE: Any calls to this tag need to deal with DGQLM passed 
  1.  ;       variable appropriately.  Notice where it is evaluated 
  1.  ;       and make sure code specifies the setting of DGQLM (a 
  1.  ;       boolean variable) properly for the call.
  1.  ;
  1.  ; Variables used:
  1.  ; 
  1.  ;    MSG      = Holds error message, if any.
  1.  ;    DGBDATE  = PASSED: Beginning date for clinic appointments.
  1.  ;    DGEDATE  = PASSED: End date for clinic appointments.
  1.  ;    DGQCNT   = Counter for patients.
  1.  ;    DGQCPTR  = PASSED: Combination file [^OR(100.24,] pointer.
  1.  ;    DGQDUZ   = DUZ of current user.
  1.  ;    DGQERR   = Array for error msg(s) return from DB calls.
  1.  ;    DGQFILE  = Combo source entry file.
  1.  ;    DGQLM    = PASSED: Called from LM ("1") or GUI ("0")?
  1.  ;    DGQPDAT  = String holder for arrays and ^TMP file values.
  1.  ;    DGQPDOB  = Patient DOB.
  1.  ;    DGQPFMDT = Hold app't date/time in FM internal format.
  1.  ;    DGQPIEN  = Variable for patient IEN, ^TMP("DG",$J,"PTSCOMBO")
  1.  ;    DGQPMOR  = Appointment or Room/Bed information.
  1.  ;    DGQPNM   = Variable for patient name, ^TMP("DG",$J,"PTSCOMBO")
  1.  ;    DGQPSNM  = Source name display string holder.
  1.  ;    DGQPSSN  = Patient ID (first letter of last name, last 4 SSN).
  1.  ;    DGQPTMP  = Temporary string construction holder.
  1.  ;    DGQPTR   = Pointer to combo source entry.
  1.  ;    DGQRTN   = Holds return value from DB calls.
  1.  ;    DGQSPCH  = Holds return value from SELCHK^DGWPT.
  1.  ;    DGQSRC   = Variable to hold each combo source subscript.
  1.  ;    DGQSRCID = IEN of source.
  1.  ;    DGQTXT   = Variable to hold stored values.
  1.  ;    DGY      = Array used in sub-calls.
  1.  ;
  1.  ; (NOTE: LCNT,LIST,MSG,NUM,SORT new'd in calling routines for LM.)
  1.  ;
  1.  N DGQCNT,DGQDUZ,DGQERR,DGQFILE,DGQPCNT,DGQPDAT,DGQPDOB,DGQPFMDT,DGQPIEN,DGQPNM,DGQPMOR,DGQPSNM,DGQPSSN,DGQPTMP,DGQPTR,DGQRTN,DGQSPCH,DGQSRC,DGQSRCID,DGQTXT,DGY
  1.  ;
  1.  K ^TMP("DG",$J,"PATIENTS")                     ; Safety cleanup.
  1.  ;
  1.  ; Do preliminary settings, cleanup, look for an existing user record:
  1.  S MSG=""                                       ; Default.
  1.  I '$D(DUZ) D
  1.  .S MSG="No user DUZ info."
  1.  .I 'DGQLM D GUIABORT
  1.  .Q
  1.  S DGQDUZ=DUZ
  1.  K DGQERR
  1.  S DGQRTN=$$FIND1^DIC(100.24,"","QX",DGQDUZ,"","","DGQERR")
  1.  K DGQERR
  1.  D CLEAN^DILF ; Clean up after DB call.
  1.  ;
  1.  ; If no combination record, then punt:
  1.  I +DGQRTN<1 D
  1.  .S MSG="No combination entry."
  1.  .I 'DGQLM D GUIABORT
  1.  .Q
  1.  ;
  1.  I DGQLM D CLEAN^VALM10 ; VALM housekeeping.
  1.  ;
  1.  ; Order through the user's combination source entries:
  1.  I 'DGQLM S SORT="A" ; Required variable for PTSCOMBO^ORQPTQ5.
  1.  S DGQSRC=0
  1.  F  S DGQSRC=$O(^OR(100.24,DGQRTN,.01,DGQSRC)) Q:'DGQSRC  D
  1.  .K DGY                                         ; Clean up each time.
  1.  .S DGQTXT=""                                   ; Initialize.
  1.  .S DGQTXT=$G(^OR(100.24,DGQRTN,.01,DGQSRC,0))  ; Get record's value.
  1.  .;
  1.  .; In case of error, punt:
  1.  .I DGQTXT="" D
  1.  ..S MSG="Combination source entry error."
  1.  ..I 'DGQLM D GUIABORT                          ; GUI is different.
  1.  ..Q
  1.  .I DGQTXT="" Q
  1.  .S DGQPTR=$P(DGQTXT,";")                       ; Get pointer.
  1.  .S DGQFILE="^"_$P(DGQTXT,";",2)                ; Get file.
  1.  .;
  1.  .; Get info for each source entry and build DGY array accordingly.
  1.  .I DGQFILE="^DIC(42," D  Q                     ; Wards.
  1.  ..D WARDPTS^DGQPTQ2(.DGY,DGQPTR)
  1.  ..I $D(DGY) D PTSCOMBO^DGQPTQ5("W",DGQPTR)     ; Process DGY array.
  1.  .I DGQFILE="^VA(200," D  Q                     ; Providers.
  1.  ..D PROVPTS^DGQPTQ2(.DGY,DGQPTR)
  1.  ..I $D(DGY) D PTSCOMBO^DGQPTQ5("P",DGQPTR)     ; Process DGY array.
  1.  .I DGQFILE="^DIC(45.7," D  Q                   ; Specialties.
  1.  ..D SPECPTS^DGQPTQ2(.DGY,DGQPTR)
  1.  ..I $D(DGY) D PTSCOMBO^DGQPTQ5("S",DGQPTR)     ; Process DGY array.
  1.  .I DGQFILE="^OR(100.21," D  Q                  ; Team Lists
  1.  ..D TEAMPTS^DGQPTQ1(.DGY,DGQPTR)
  1.  ..I $D(DGY) D PTSCOMBO^DGQPTQ5("T",DGQPTR)     ; Process DGY array.
  1.  .I DGQFILE="^SC(" D  Q                         ; Clinics.
  1.  ..D CLINPTS^DGQPTQ2(.DGY,DGQPTR,DGBDATE,DGEDATE)
  1.  ..I $D(DGY) D PTSCOMBO^DGQPTQ5("C",DGQPTR)     ; Process DGY array.
  1.  ;
  1.  ; Order thru ^TMP file "B" node entries returned by previous calls:
  1.  S DGQCNT=0                                     ; Reset for final use.
  1.  I $D(^TMP("DG",$J,"PATIENTS")) D
  1.  .S DGQPDAT=""
  1.  .F  S DGQPDAT=$O(^TMP("DG",$J,"PATIENTS","B",DGQPDAT)) Q:DGQPDAT=""  D
  1.  ..;
  1.  ..; Clear variables each time through:
  1.  ..S (DGQTXT,DGQPFMDT,DGQPIEN,DGQPNM,DGQPSSN,DGQPDOB,DGQPSNM,DGQPMOR,DGQSRCID)=""
  1.  ..;
  1.  ..; Retrieve node's value:
  1.  ..S DGQTXT=$G(^TMP("DG",$J,"PATIENTS","B",DGQPDAT))
  1.  ..;
  1.  ..; Set indvidual variables:
  1.  ..S DGQPIEN=$P(DGQTXT,U)                       ; Patient DFN.
  1.  ..S DGQPNM=$P(DGQTXT,U,2)                      ; Patient name.
  1.  ..S DGQPSSN=$P(DGQTXT,U,3)                     ; Patient ID.
  1.  ..S DGQPDOB=$P(DGQTXT,U,4)                     ; Patient DOB.
  1.  ..S DGQPSNM=$P(DGQTXT,U,5)                     ; Source data.
  1.  ..S DGQPMOR=$P(DGQTXT,U,6)                     ; App't or R/B info.
  1.  ..S DGQSRCID=$P(DGQTXT,U,7)                    ; Source IEN.
  1.  ..S DGQPFMDT=$P(DGQTXT,U,8)                    ; App't FM date/time.
  1.  ..S DGQCNT=DGQCNT+1                            ; Increment counter.
  1.  ..;
  1.  ..; If a "sensitive" patient, reassign SSN, DOB data:
  1.  ..S DGQSPCH=$$SSN^DPTLK1(DGQPIEN)
  1.  ..I DGQSPCH["*" S DGQPSSN=""
  1.  ..S DGQPDOB=$$DOB^DPTLK1(DGQPIEN)
  1.  ..;
  1.  ..; Make some preliminary data settings:
  1.  ..S DGQPTMP=""
  1.  ..I DGQPSNM'="" S DGQPTMP=DGQPSNM_"  "
  1.  ..S DGQPTMP=DGQPTMP_DGQPMOR
  1.  ..;
  1.  ..; Write new ^TMP file "PATIENTS" nodes:
  1.  ..I DGQLM D                                    ; For LM.
  1.  ...S ^TMP("DG",$J,"PATIENTS","IDX",DGQCNT)=DGQPIEN_U_DGQPNM
  1.  ...S ^TMP("DG",$J,"PATIENTS",DGQCNT,0)=$$LJ^XLFSTR(DGQCNT,5)_$$LJ^XLFSTR(DGQPNM,31)_$$LJ^XLFSTR(DGQPSSN,10)_$$LJ^XLFSTR(DGQPDOB,15)_DGQPTMP_$$LJ^XLFSTR(DGQPDOB,15)_$$RJ^XLFSTR(DGQSRCID,8)_"  "_DGQPFMDT
  1.  ...D CNTRL^VALM10(DGQCNT,1,5,IOINHI,IOINORM)
  1.  ..;
  1.  ..I 'DGQLM D                                   ; For GUI.
  1.  ...S DGQTXT=DGQPIEN_U_DGQPNM_U_DGQPSNM_U_DGQPMOR_U_DGQPSSN_U_DGQPDOB_U_DGQSRCID_U_DGQPFMDT
  1.  ...S ^TMP("DG",$J,"PATIENTS",DGQCNT,0)=DGQTXT  ; Actual global write.
  1.  ;
  1.  ; Set counters for return, if applicable; do cleanup:
  1.  I DGQCNT S (LCNT,NUM)=DGQCNT
  1.  K DGY
  1.  ;
  1.  ; If no patients found, prepare user message:
  1.  I 'DGQCNT S MSG="No patients found."
  1.  ;
  1.  ; If an error message exists, dump any partial processing and quit:
  1.  I MSG'="" D  Q
  1.  .I 'DGQLM D GUIABORT
  1.  .I DGQLM K ^TMP("DG",$J,"PATIENTS")
  1.  ;
  1.  ; Next lines create #line^^#pts^context value entry:
  1.  I DGQLM D
  1.  .S ^TMP("DG",$J,"PATIENTS",0)=DGQCNT_U_DGQCNT_U_$G(LIST)
  1.  .S ^TMP("DG",$J,"PATIENTS","#")=$O(^ORD(101,"B","ORQPT SELECT PATIENT",0))_"^1:"_DGQCNT
  1.  ;
  1.  ; Standard clean-up for GUI:
  1.  I 'DGQLM D
  1.  .K LCNT,LIST,MSG,NUM,SORT
  1.  .K ^TMP("DG",$J,"PATIENTS","B")
  1.  ;
  1.  Q
  1.  ;
  1. GUIABORT ; Cleanup when aborting when called from GUI.
  1.  ;
  1.  K ^TMP("DG",$J,"PATIENTS")
  1.  S ^TMP("DG",$J,"PATIENTS",0)=""
  1.  K LCNT,LIST,MSG,NUM,SORT
  1.  ;
  1.  Q
  1.  ;