Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: DGRUGMFU

DGRUGMFU.m

Go to the documentation of this file. 
  1. DGRUGMFU ;ALB/GRR - CREATE MFU MESSAGE
  1.  ;;5.3;Registration;**190,349,381**;AUG 13, 1993
  1. EN(DGRSEGC,DGRSEGN,DGRFNUM,DGRFNAM,DGROLDN,DGRENM,DGCIEN) ;
  1.  K ^TMP($J,"DGRUGMFU")
  1.  ;;Input parameters:
  1.  ;;  DGRSEGC - Segment Code (Z36,LOC,STF)
  1.  ;;  DGRSEGN - Segment Name (LOCATION, STAFF)
  1.  ;;  DGRFNUM - File Number of master file
  1.  ;;  DGRFNAM - Master File Name (NEW PERSON)
  1.  ;;  DGROLDN - Value of name prior to change
  1.  ;;  DGRENM - Name field of changed entry
  1.  ;;  DGRCIEN - Internal Entry Number of changed entry
  1.  N DGREC,DGREDT,DGRROOM,DGRBED,DGRWARD,DGRWIEN
  1.  D INIT^HLFNC2("DGRU-RAI-MFU-SERVER",.HL) ;p-381 added
  1.  D NOW^%DTC S DGREDT=$$HLDATE^HLFNC(%) ;Current Date/Time
  1.  S DGREC="MFI"_HL("FS")_DGRSEGC_$E(HL("ECH"))_DGRSEGN_$E(HL("ECH"))_"HL7"_$E(HL("ECH"))_DGRFNUM_$E(HL("ECH"))_DGRFNAM_HL("FS")_HL("FS")_"UPD"_HL("FS")_DGREDT_HL("FS")_HL("FS")_"NE" ;Format MFI HL7 segment
  1.  S ^TMP($J,"DGRUGMFU",1)=DGREC ;Store MFI segment into global array
  1.  S DGREC="MFE"_HL("FS")_"MUP"_HL("FS")_HL("FS")_DGREDT_HL("FS")_DGCIEN_$E(HL("ECH"))_DGROLDN_$E(HL("ECH"))_"HL7" ;Format the MFE HL7 segment
  1.  S ^TMP($J,"DGRUGMFU",2)=DGREC ;Store MFE segment into array
  1.  I DGRSEGC="Z36" D  G EXIT ;If Z36 segment (Insurance), do following and exit
  1.  .S DGREC="Z36"_HL("FS")_DGCIEN_$E(HL("ECH"))_DGRENM ;Format Z36 segment
  1.  .S ^TMP($J,"DGRUGMFU",3)=DGREC ;Store Z36 segment into array
  1.  I DGRSEGC="STF" D  G EXIT ;If STF segment, do following and exit
  1.  .S DGREC="STF"_HL("FS")_DGCIEN_$E(HL("ECH"))_DGROLDN_$E(HL("ECH"))_DGRFNUM_HL("FS")_HL("FS")_$$HLNAME^HLFNC(DGRENM) ;Format the STF segment
  1.  .S $P(DGREC,HL("FS"),19)=$$GET1^DIQ(200,DGCIEN,8,"E") ;Set the Job title into sequence 18 (piece 19)
  1.  .S ^TMP($J,"DGRUGMFU",3)=DGREC ;Store STF segment into array
  1.  I DGRSEGC="LOC" D  G EXIT ;If LOC segment, do the following and exit
  1.  .I DGRFNUM=405.4 D  ;If the LOC is for Room-Bed change, do the following
  1.  ..S DGRROOM=$P(DGRENM,"-") ;Set room variable
  1.  ..S DGRBED=$P(DGRENM,"-",2) ;Set bed variable
  1.  ..S DGRWIEN=$O(^DG(405.4,DGCIEN,"W",0)) ;Set variable to Ward IEN
  1.  ..S I=$P($G(^DG(405.4,DGCIEN,"W",DGRWIEN,0)),"^") ;Set variable to IEN in Room-Bed file
  1.  ..S DGRWARD=$$GET1^DIQ(42,I,.01) ;Set variable to Ward location file name
  1.  ..I DGRWARD]"" S DGRWARD=$$WARDTRAN^DGRUUTL1(I,DGRWARD) ;p-381 added
  1.  ..S $P(^TMP($J,"DGRUGMFU",2),"^",5)=DGRWARD_$E(HL("ECH"))_DGROLDN_$E(HL("ECH"))_"HL7" ;
  1.  .I DGRFNUM=42 D
  1.  ..S DGRROOM="",DGRBED="",DGRWARD=$$GET1^DIQ(42,DGCIEN,.01)
  1.  .I DGRROOM]"" S DGRBH=$$RBTRAN^DGRUUTL1(DGCIEN,DGRROOM_"-"_DGRBED) S DGRROOM=$P(DGRBH,"-",1),DGRBED=$P(DGRBH,"-",2) ;modified p-328
  1.  .I DGRWARD]"" S DGRWARD=$$WARDTRAN^DGRUUTL1(DGCIEN,DGRWARD) ;changed p-349
  1.  .S DGREC="LOC"_HL("FS")_DGRWARD_$E(HL("ECH"))_DGRROOM_$E(HL("ECH"))_DGRBED_$E(HL("ECH"))_$E(HL("ECH"))_$E(HL("ECH"))_"NURSING UNIT"_HL("FS")_HL("FS")_"N"
  1.  .S ^TMP($J,"DGRUGMFU",3)=DGREC
  1. EXIT Q
  1.  ;
  1. ENGET() ;DETERMINE DIVISION TO GET SUBSCRIBERS
  1.  ;
  1.  N I,J,X
  1.  F I=1:1 X HLNEXT Q:HLQUIT'>0  D
  1.  .S X(I)=HLNODE,J=0
  1.  ..F  S J=$O(HLNODE(J)) Q:'J  S X(I,J)=HLNODE(J)
  1.  ;LOOK FOR LOC segment
  1.  S I=0
  1.  F  S I=$O(X(I)) Q:'I  D
  1.  .I $P(X(I),"^",1)="LOC" D
  1.  ..S DGWARD=$$WARD^DGRUDYN(X(I),2)
  1.  S DGDIV=+$$GET1^DIQ(42,DGWARD,.015,"I")
  1.  Q DGDIV
  1.  ;