Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: DIFROMSX

DIFROMSX.m

Go to the documentation of this file. 
  1. DIFROMSX ;SFIRMFO/DCM/TKW-MOVE INDEX FILE ENTRIES ;12:31 PM  31 Oct 2001
  1.  ;;22.2;VA FileMan;;Jan 05, 2016;Build 42
  1.  ;;Per VA Directive 6402, this routine should not be modified.
  1.  ;;Submitted to OSEHRA 5 January 2015 by the VISTA Expertise Network.
  1.  ;;Based on Medsphere Systems Corporation's MSC FileMan 1051.
  1.  ;;Licensed under the terms of the Apache License, Version 2.0.
  1.  ;
  1. DDIXOUT(DIFRFILE,DIFRF2,DIFRFDD,DIFRTA) ; retrieve INDEX entries for file
  1.  ; DIFRFILE=top level file#
  1.  ; DIFRF2=current file/subfile #
  1.  ; DIFRFDD=1 if sending full DD
  1.  ; DIFRTA=Global reference of transport global.
  1.  N DIFRNAME,DIFRD0,DIFRD1,DIFRF,DIFRFLD,DIOUT,X,DICNT1,DICNT2
  1.  S DIFRNAME="",DIOUT=0
  1.  F  S DIFRNAME=$O(^DD("IX","BB",DIFRF2,DIFRNAME)) Q:DIFRNAME=""  D  Q:DIOUT
  1.  . S DIFRD0=$O(^DD("IX","BB",DIFRF2,DIFRNAME,0)) Q:'DIFRD0
  1.  . S (DIFRD1,DICNT1,DICNT2)=0
  1.  . F  S DIFRD1=$O(^DD("IX",DIFRD0,11.1,DIFRD1)) Q:'DIFRD1  D  Q:DIOUT
  1.  . . S X=$G(^DD("IX",DIFRD0,11.1,DIFRD1,0))
  1.  . . S DIFRF=$P(X,U,3),DIFRFLD=$P(X,U,4) Q:'DIFRFLD!('DIFRF)
  1.  . . S DICNT1=DICNT1+1,X=$$FNO^DILIBF(DIFRF)
  1.  . . I '$D(@DIFRTA@("^DD",X,DIFRF,DIFRFLD)) D  Q
  1.  . . . Q:'DIFRFDD&($G(@DIFRTA@("FIA",X,DIFRF))'=0)
  1.  . . . D ERR1(DIFRF,DIFRFLD,DIFRNAME,"INDEX") Q
  1.  . . S DICNT2=DICNT2+1
  1.  . . Q
  1.  . Q:DIOUT  I DICNT2=0,'DIFRFDD Q
  1.  . ;I DICNT1'=DICNT2 D ERR2(DIFRF2,DIFRNAME,"INDEX") Q
  1.  . M @DIFRTA@("IX",DIFRFILE,DIFRF2,DIFRNAME)=^DD("IX",DIFRD0)
  1.  . K @DIFRTA@("IX",DIFRFILE,DIFRF2,DIFRNAME,11.1,"AC")
  1.  . K @DIFRTA@("IX",DIFRFILE,DIFRF2,DIFRNAME,11.1,"B")
  1.  . K @DIFRTA@("IX",DIFRFILE,DIFRF2,DIFRNAME,11.1,"BB")
  1.  . Q
  1.  Q
  1.  ;
  1. DDIXIN(DIFRFILE,DIFRF2,DIFRSA) ; Install INDEX file entries for file DIFRFILE
  1.  ; DIFRFILE=source file#
  1.  ; DIFRF2=current file/subfile#
  1.  ; DIFRSA=name of array containing incoming data.
  1.  N DIFRER,DIFRIN,DIFRNAME,DIFRD1,DIOUT,DIFRIN1,DIFRF,DIFRFLD,X
  1.  I '$D(^DD(.11)) S DIFRER("FILE")=.11 D BLD^DIALOG(401,.DIFRER) Q
  1.  S DIFRIN=$NA(@DIFRSA@("IX",DIFRFILE,DIFRF2))
  1.  S DIFRNAME=""
  1.  F  S DIFRNAME=$O(@DIFRIN@(DIFRNAME)) Q:DIFRNAME=""  D
  1.  . S (DIFRD1,DIOUT)=0,DIFRIN1=$NA(@DIFRIN@(DIFRNAME))
  1.  . F  S DIFRD1=$O(@DIFRIN1@(11.1,DIFRD1)) Q:'DIFRD1  D  Q:DIOUT
  1.  . . S X=$G(@DIFRIN1@(11.1,DIFRD1,0))
  1.  . . S DIFRF=$P(X,U,3),DIFRFLD=$P(X,U,4)
  1.  . . I 'DIFRF!('DIFRFLD) Q
  1.  . . I '$D(^DD(DIFRF,DIFRFLD,0)) D ERR3(DIFRF,DIFRFLD,DIFRNAME,"INDEX") Q
  1.  . . I $O(^DD(DIFRF,DIFRFLD,5,0)) D
  1.  . . . Q:$D(^TMP("DIFROMS2",$J,"TRIG",DIFRFILE,DIFRF,DIFRFLD))
  1.  . . . D TRMOD^DICR(DIFRF,DIFRFLD)
  1.  . . . S ^TMP("DIFROMS2",$J,"TRIG",DIFRFLD,DIFRF,DIFRFLD)="" Q
  1.  . . Q
  1.  . Q:DIOUT
  1.  . N DIEN,DIK,DA,DIC,DO
  1.  . S DIEN=$O(^DD("IX","BB",DIFRF2,DIFRNAME,0))
  1.  . I DIEN D  N DINUM S DINUM=DIEN
  1.  . . S DIK="^DD(""IX"",",DA=DIEN N DIEN D ^DIK Q
  1.  . S DIC="^DD(""IX"",",DIC(0)="L",DIC("DR")=".02///^S X="_""""_DIFRNAME_"""",X=DIFRF2 D FILE^DICN S DIEN=+Y
  1.  . I DIEN'>0 D ERR4(DIFRF2,DIFRNAME,"INDEX") Q
  1.  . M ^DD("IX",DIEN)=@DIFRIN1
  1.  . K DIK,DA S DIK="^DD(""IX"",",DA=DIEN D IX1^DIK
  1.  . Q
  1.  Q
  1.  ;
  1. ERR1(DIFRF,DIFRFLD,DIFRNAME,DIFRTYPE) ;
  1.  N DIFRER S DIFRER(1)=DIFRFLD
  1.  S DIFRER(2)=DIFRF
  1.  S DIFRER(3)=DIFRNAME,DIFRER(4)=DIFRTYPE
  1.  D BLD^DIALOG(9543,.DIFRER) S DIOUT=1 Q
  1. ERR2(DIFRF2,DIFRNAME,DIFRTYPE) ;
  1.  N DIFRER S DIFRER(1)=DIFRNAME,DIFRER(2)=DIFRTYPE
  1.  S DIFRER(3)=DIFRF2
  1.  D BLD^DIALOG(9544,.DIFRER) Q
  1. ERR3(DIFRF,DIFRFLD,DIFRNAME,DIFRTYPE) ;
  1.  N DIFRER S DIFRER(1)=DIFRTYPE,DIFRER(2)=DIFRNAME
  1.  S DIFRER(3)=DIFRFLD
  1.  S DIFRER(4)=DIFRF
  1.  D BLD^DIALOG(9545,.DIFRER) S DIOUT=1 Q
  1. ERR4(DIFRF2,DIFRNAME,DIFRTYPE) ;
  1.  N DIFRER S DIFRER(1)=DIFRTYPE,DIFRER(2)=DIFRNAME,DIFRER(3)=DIFRF2
  1.  D BLD^DIALOG(9549,.DIFRER) Q
  1.  ;
  1.  ;9543  Field |1| of file |2|, part of '|3|' |4| entry, is missing from the transport global...
  1.  ;9544  Field(s) that are part of |1| |2| entry are missing from the transport global.
  1.  ;9545  |1| entry |2| not installed.  The REFERENCE FIELD |3| in file |4| does not exist on the system.
  1.  ;9549 |1| "|2|" on file |3| not installed, FILE^DICN call failed.
  1.  ;