Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: DMSQF2

DMSQF2.m

Go to the documentation of this file.
  1. DMSQF2 ;SFISC/JHM-BUILD INDEX AND PARENT FOREIGN KEYS ;7/28/97 11:10
  1. ;;22.2;VA FileMan;;Jan 05, 2016;Build 42
  1. ;;Per VA Directive 6402, this routine should not be modified.
  1. ;;Submitted to OSEHRA 5 January 2015 by the VISTA Expertise Network.
  1. ;;Based on Medsphere Systems Corporation's MSC FileMan 1051.
  1. ;;Licensed under the terms of the Apache License, Version 2.0.
  1. ;
  1. Q
  1. PFK(TI) ;BUILD FOREIGN KEYS FOR PARENT TABLES
  1. N T,GL,FL,PEI,S,TE,TC
  1. D INIT F I=1:1:$O(TE(""),-1)-1 D BFK(I)
  1. Q
  1. BFK(L) ;BUILD A LEVEL L FOREIGN KEY FOR TABLE PRIMARY KEYS
  1. N I,FF,FTI,FT,FTN,FKN,FPEI,FPE,IEN,TT,FDA,ERR,FIEN,PI
  1. S FF=$P(FL,",",L),FTI=$O(^DMSQ("T","C",FF,"")) Q:FTI=""
  1. S FT=^DMSQ("T",FTI,0),FTN=$P(FT,U),FKN=FTN_"_PFK"
  1. S FPEI=$O(^DMSQ("E","F",FTI,"P","")) Q:FPEI=""
  1. S FPE=^DMSQ("E",FPEI,0),FDI=$P(FPE,U,2)
  1. ;BUILD FOREIGN KEY TABLE ELEMENT
  1. S IEN=$O(^DMSQ("E","G",TI,FKN,"")),TT=1.5216,IEN=$S(IEN:IEN,1:"+1")_","
  1. S FDA(TT,IEN,.01)=FKN ; FOREIGN KEY NAME
  1. S FDA(TT,IEN,1)=FDI ; DOMAIN OF FOREIGN TABLE
  1. S FDA(TT,IEN,2)=TI ; FOREIGN KEY IS IN THIS TABLE
  1. S FDA(TT,IEN,3)="F" ; TYPE F FOR FOREIGN KEY
  1. S FDA(TT,IEN,4)="Foreign key to ancestor "_FTN ; COMMENT
  1. S FIEN=$$PUT^DMSQU(IEN,"FDA","ERR")
  1. I $D(ERR)!'FIEN D ERR^DMSQU(F,L,"FOREIGN KEY: ANCESTOR FOREIGN KEY INSERT FAILED") Q
  1. S (IENL,FKI)=""
  1. F I=1:1:L S FKI=$O(^DMSQ("F","B",FIEN,FKI)) Q:FKI="" D
  1. . S $P(IENL,U,I)=FKI
  1. F I=1:1:L D BFKI(I)
  1. Q
  1. BFKI(L) ;BUILD FOREIGN KEY COLUMN ELEMENT
  1. S CEI=$P(TC(L),U),CI=$O(^DMSQ("C","B",CEI,""))
  1. I 'CI D ERR^DMSQU(F,L,"FOREIGN KEY: NO POINTED-TO COLUMN AT LEVEL") Q
  1. S PI=$O(^DMSQ("P","C",FPEI,L,""))
  1. I 'PI D ERR^DMSQU(F,L,"FOREIGN KEY: NO ANCESTOR PRIMARY KEY") Q
  1. ;BUILD FK COLUMN
  1. S FI=$P(IENL,U,I),TT=1.5219,IEN=$S(FI:FI,1:"+1")_","
  1. S FDA(TT,IEN,.01)=FIEN ; FK TABLE ELEMENT ID
  1. S FDA(TT,IEN,1)=PI ; FOREIGN PRIMARY KEY ID
  1. S FDA(TT,IEN,2)=CI ; LOCAL PRIMARY KEY COLUMN ID
  1. S FI=$$PUT^DMSQU(IEN,"FDA","ERR")
  1. I $D(ERR)!'FI D ERR^DMSQU(F,L,"FOREIGN KEY: ANCESTOR FOREIGN KEY COLUMN INSERT FAILED")
  1. Q
  1. INIT ;SET PRIMARY KEY VARIABLES FOR TABLE TI
  1. N S,P,PI,K,KCI,KC,PEI
  1. S S=0,T=^DMSQ("T",TI,0),GL=^(1),(F,P,FL)=$P(T,U,7)
  1. F S P=$G(^DD(P,0,"UP")) Q:P="" S FL=P_","_FL
  1. S PEI=$O(^DMSQ("E","F",TI,"P","")),PI=""
  1. F S PI=$O(^DMSQ("P","B",PEI,PI)) Q:PI="" D
  1. . S K=^DMSQ("P",PI,0),S=$P(K,U,3),KCI=$P(K,U,2),KC=^DMSQ("C",KCI,0)
  1. . S TE(S)=$P(^DMSQ("E",$P(KC,U),0),U,1,2),TC(S)=KC
  1. Q
  1. INDEX(TI) ;BUILD ALL REGULAR INDICIES FOR TABLE TI
  1. I '$G(DIFM) D ENV^DMSQU
  1. N T,GL,FL,PI,K,TE,TC,KC,KCI,IN,FI,CI,IC,IE,I,IF,IX,C,CEI,L,TN,CN,INM,IEI,IEN,FDA,ERR,TIEN,PIEN,DIEN,CIEN
  1. D INIT S FI=0
  1. FI S FI=$O(^DD(F,FI)) Q:'FI S IN=0
  1. IN S IN=$O(^DD(F,FI,1,IN)) G FI:'IN D IDX(F,FI,IN,.TC,.TE) G IN
  1. ;
  1. IDX(F,FI,IN,TC,TE) ;BUILD INDEX
  1. N P,S,IGL,IC,IE,I,IF,IX,CI,ITI,CEI,CE,L,TN,GF,INM1,INM2,TN1,TN2
  1. S I=$G(^DD(F,FI,1,IN,0)) I $P(I,U,3)]"" Q
  1. I I="" D ERR^DMSQU(F,FI,"INDEX: MISSING DATA DICTIONARY DATA") Q
  1. S IF=+I,IX=$P(I,U,2) I IX=""!'IF Q
  1. I $G(^DD(F,FI,1,IN,1))'[",DA)" D Q
  1. . D ERR^DMSQU(F,FI,"INDEX: IRREGULAR FORMAT")
  1. S CI=$O(^DMSQ("C","D",F,FI,"")),ITI=$$T(IF)
  1. I 'CI D ERR^DMSQU(F,FI,"INDEX: NO ASSOCIATED COLUMN RECORD") Q
  1. F L=$L(FL,","):-1:1 Q:$P(FL,",",L)=IF
  1. M IC=TC,IE=TE
  1. S C=^DMSQ("C",CI,0),CEI=$P(C,U),CE=^DMSQ("E",CEI,0)
  1. S IC(L-.5)=C,IE(L-.5)=CE
  1. ;S TN=$P(T,U),CN=$P(CE,U),INM=$$SQLI^DMSQU(TN_"_X"_IX_"_"_CN,30)
  1. S TN=$P(T,U),TN1=$E(TN,1,$L(TN)-1),TN2=$E(TN,$L(TN)),CN=$P(CE,U)
  1. S INM1=$$SQLI^DMSQU(TN1,18),INM2=$$SQLI^DMSQU("X"_IX_"_"_CN,10)
  1. S INM=INM1_TN2_"_"_INM2
  1. S IGL=GL,GF=$P(IGL,"{K}",L)_$C(34)_IX_$C(34)_",{K},"
  1. S $P(IGL,"{K}",L)=GF F I=L+1:1:$L(GL,"{K}") S $P(IGL,"{K}",I)=","
  1. S IEI=$O(^DMSQ("T","B",INM,""))
  1. ;BUILD TABLE
  1. S TT=1.5215,IEN=$S(IEI:IEI,1:"+1")_","
  1. S FDA(TT,IEN,.01)=INM ; INDEX TABLE NAME
  1. S FDA(TT,IEN,1)=1 ; SCHEMA SQLI
  1. S FDA(TT,IEN,2)="Index of "_TN_" by "_CN ;COMMENT
  1. S FDA(TT,IEN,3)=TI ; MASTER TABLE ID
  1. S FDA(TT,IEN,4)=1 ; VERSION NUMBER
  1. S FDA(TT,IEN,7)=DT ; UPDATE DATE
  1. S FDA(TT,IEN,8)=IGL ; GLOBAL NAME
  1. S TIEN=$$PUT^DMSQU(IEN,"FDA","ERR")
  1. I $D(ERR) D ERR^DMSQU(F,FI,"INDEX: TABLE INSERT FAILED") Q
  1. S DIEN=$O(^DMSQ("DM","C",TIEN,""))
  1. ; BUILD TABLE DOMAIN
  1. S TT=1.5212,IEN=$S(DIEN:DIEN,1:"+1")_","
  1. S FDA(TT,IEN,.01)=$$SQLI^DMSQU(INM_"_ID",30) ; DOMAIN NAME
  1. S FDA(TT,IEN,1)=1 ; TYPE = PRIMARY KEY
  1. S FDA(TT,IEN,2)="Domain of table "_INM ; COMMENT
  1. S FDA(TT,IEN,3)=TIEN ; TABLE ID
  1. S DIEN=$$PUT^DMSQU(IEN,"FDA","ERR")
  1. I $D(ERR) D ERR^DMSQU(F,FI,"INDEX: TABLE DOMAIN INSERT FAILED") Q
  1. S PIEN=$O(^DMSQ("E","F",TIEN,"P",""))
  1. ;BUILD PRIMARY KEY HEADER ELEMENT
  1. S TT=1.5216,IEN=$S(PIEN:PIEN,1:"+1")_","
  1. S FDA(TT,IEN,.01)=$$SQLI^DMSQU(INM_"_PK",30) ; PRIMARY KEY NAME
  1. S FDA(TT,IEN,1)=DIEN ; TABLE DOMAIN
  1. S FDA(TT,IEN,2)=TIEN ; TABLE ID
  1. S FDA(TT,IEN,3)="P" ; TYPE = P FOR PRIMARY KEY
  1. S FDA(TT,IEN,4)="Primary key header for "_INM ; COMMENT
  1. S PIEN=$$PUT^DMSQU(IEN,"FDA","ERR")
  1. I $D(ERR) D ERR^DMSQU(F,FI,"INDEX: PRIMARY KEY ELEMENT INSERT FAILED") Q
  1. S S=0,(K,P)="" F S K=$O(IE(K)) Q:K="" D
  1. . S S=S+1 D PKI(S,PIEN,$P(IGL,"{K}",S),IE(K),IC(K),.P)
  1. Q
  1. PKI(S,PEI,G,E,C,P) ;BUILD COLUMN ELEMENT, COLUMN AND PRIMARY KEY ELEMENT
  1. N ICN,CI,CEI,PI,W,KFI S (CI,CEI,PI,KFI)="",W=$P(C,U,2)
  1. I W>30 S KFI=$O(^DMSQ("KF","B","LONG_CHARACTER",""))
  1. S PI=$O(^DMSQ("P","C",PEI,S,""))
  1. I PI S CI=$P($G(^DMSQ("P",PI,0)),U,2)
  1. I CI S CEI=$P($G(^DMSQ("C",CI,0)),U)
  1. S ICN=$P(E,U)
  1. ;BUILD COLUMN ELEMENT
  1. S TT=1.5216,IEN=$S(CEI:CEI,1:"+1")_","
  1. S FDA(TT,IEN,.01)=ICN ; COLUMN NAME
  1. S FDA(TT,IEN,1)=$P(E,U,2) ; DOMAIN ID
  1. S FDA(TT,IEN,2)=TIEN ; TABLE ID
  1. S FDA(TT,IEN,3)="C" ; TYPE = COLUMN
  1. S FDA(TT,IEN,4)="Index Primary Key #"_S_" for "_INM_"."_ICN
  1. S CEI=$$PUT^DMSQU(IEN,"FDA","ERR")
  1. I $D(ERR)!'CEI D ERR^DMSQU(F,FI,"INDEX: COLUMN ELEMENT INSERT FAILED") Q
  1. ;BUILD COLUMN
  1. S TT=1.5217,IEN=$S(CI:CI,1:"+1")_","
  1. S FDA(TT,IEN,.01)=CEI ; COLUMN ELEMENT ID
  1. I P S FDA(TT,IEN,8)=P ; PARENT POINTER
  1. S FDA(TT,IEN,9)=G ; GLOBAL FRAGMENT
  1. S CI=$$PUT^DMSQU(IEN,"FDA","ERR")
  1. I $D(ERR)!'CI D ERR^DMSQU(F,FI,"INDEX: COLUMN INSERT FAILED")
  1. ;BUILD PRIMARY KEY
  1. S TT=1.5218,IEN=$S(PI:PI,1:"+1")_","
  1. S FDA(TT,IEN,.01)=PEI ; PRIMARY KEY HEADER ID
  1. S FDA(TT,IEN,1)=CI ; COLUMN ID
  1. S FDA(TT,IEN,2)=S ; KEY SEQUENCE
  1. I KFI S FDA(TT,IEN,7)=KFI ; KEY FORMAT
  1. S PI=$$PUT^DMSQU(IEN,"FDA","ERR")
  1. I $D(ERR)!'PI D ERR^DMSQU(F,FI,"INDEX: PRIMARY KEY INSERT FAILED")
  1. S P=CI
  1. Q
  1. T(F) Q $O(^DMSQ("T","C",F,""))