Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: DVBA43PI

DVBA43PI.m

Go to the documentation of this file. 
  1. DVBA43PI ;BP-CIOFO/MM Post Init Exam file Update - ;3/27/2002
  1.  ;;2.7;AMIE;**43**;Apr 10,1995
  1.  ;
  1.  ; This is the post-install for DVBA*2.7*43 to inactivate the old
  1.  ; entries and create new entries in the AMIE EXAM file (#396.6).
  1.  ;
  1. EN ;
  1.  D BMES^XPDUTL("DVBA*2.7*43 Post Installation --")
  1.  D MES^XPDUTL("   Update to AMIE EXAM file (#396.6).")
  1.  D MES^XPDUTL("  ")
  1.  I '$D(^DVB(396.6)) D BMES^XPDUTL("Missing AMIE EXAM (#396.6) file") Q
  1.  I $D(^DVB(396.6)) D
  1.  .D INACT
  1.  .D NEW
  1.  Q
  1.  ;
  1. INACT ;inactivate exams
  1.  N LINE,IEN,EXM,PNM,BDY,ROU,STAT,WKS,DIE,DR,DA,X,Y,DVBAI
  1.  D BMES^XPDUTL("Inactivating AMIE EXAM file entries..")
  1.  F DVBAI=1:1 S LINE=$P($T(TXTOLD+DVBAI),";;",2) Q:LINE="QUIT"  D
  1.  .D GET K X,Y,DA
  1.  .I $P($G(^DVB(396.6,IEN,0)),"^",1)'=EXM D  Q
  1.  ..D BMES^XPDUTL("  *** Warning - Entry #"_IEN)
  1.  ..D MES^XPDUTL("                for exam "_EXM)
  1.  ..D MES^XPDUTL("                could not be inactivated.")
  1.  .S DIE="^DVB(396.6,",DA=IEN,DR=".5///I" D ^DIE
  1.  .D BMES^XPDUTL("  Entry #"_IEN_" for exam "_EXM)
  1.  .D MES^XPDUTL("     successfully inactivated.")
  1.  D MES^XPDUTL("  ")
  1.  Q
  1.  ;
  1. NEW ;add new exam
  1.  N LINE,IEN,EXM,PNM,BDY,ROU,STAT,WKS,DIC,DIE,DR,DA,X,Y,DINUM,DVBAI
  1.  D BMES^XPDUTL("Adding new AMIE EXAM file entries...")
  1.  F DVBAI=1:1 S LINE=$P($T(TXTNEW+DVBAI),";;",2) Q:LINE="QUIT"  D
  1.  .D GET K X,Y,DA
  1.  .D BMES^XPDUTL("  Attempting to add Entry #"_IEN_"...")
  1.  .I $D(^DVB(396.6,IEN,0)) D  Q
  1.  ..D MES^XPDUTL("  You have an Entry #"_IEN_".")
  1.  ..D MES^XPDUTL("  Updating "_EXM_".")
  1.  ..S DIE="^DVB(396.6,",DA=IEN,DR=".01///"_EXM_";.07///"_WKS_";.5///"_STAT_";2///"_BDY_";6///"_PNM_";7///"_ROU
  1.  ..D ^DIE
  1.  .S DIC="^DVB(396.6,",DIC(0)="LZ",X=EXM,DINUM=IEN
  1.  .S DIC("DR")=".07///"_WKS_";.5///"_STAT_";2///"_BDY_";6///"_PNM_";7///"_ROU
  1.  .K DD,DO D FILE^DICN
  1.  .I +Y=IEN D  Q
  1.  ..D MES^XPDUTL("  Successfully added Entry #"_IEN)
  1.  ..D MES^XPDUTL("  for exam "_EXM_".")
  1.  .I +Y=-1 D
  1.  ..D MES^XPDUTL("  *** Warning - Unable to add Entry #"_IEN)
  1.  ..D MES^XPDUTL("                for exam "_EXM_".")
  1.  Q
  1. GET ;get exam data
  1.  S (IEN,EXM,PNM,BDY,ROU,STAT,WKS)=""
  1.  S IEN=$P(LINE,";",1) ;ien
  1.  S EXM=$P(LINE,";",2) ;exam name
  1.  S PNM=$P(LINE,";",3) ;print name
  1.  S BDY=$P(LINE,";",4) ;body system
  1.  S ROU=$P(LINE,";",5) ;routine name
  1.  S STAT=$P(LINE,";",6) ;status
  1.  S WKS=$P(LINE,";",8) ;worksheet number
  1.  Q
  1.  ;
  1.  ; Entries to be inactivated.
  1.  ; format:  ien;exam name;;;routine;status;;wks#
  1. TXTOLD ;
  1.  ;;164;REVIEW EXAMINATION FOR POST-TRAUMATIC STRESS DISORDER; ; ;DVBCWPE;I; ;0920
  1.  ;;165;INITIAL EVALUATION FOR POST-TRAUMATIC STRESS DISORDER (PTSD); ; ;DVBCWPD;I; ;0910
  1.  ;;167;MENTAL DISORDERS (EXCEPT PTSD AND EATING DISORDERS); ; ;DVBCWME;I; ;0905
  1.  ;;QUIT
  1.  ;
  1.  ;
  1.  ; New exam to activate 
  1.  ; format:  ien;exam name;print name;body system;routine;status;;wks#
  1. TXTNEW ;
  1.  ;;171;REVIEW EXAMINATION FOR POST-TRAUMATIC STRESS DISORDER;REV EXAM FOR PTSD;MENTAL;DVBCWPE3;A; ;0920
  1.  ;;172;INITIAL EVALUATION FOR POST-TRAUMATIC STRESS DISORDER (PTSD);STRESS DISORDER;MENTAL;DVBCWPD3;A; ;0910
  1.  ;;173;MENTAL DISORDERS (EXCEPT PTSD AND EATING DISORDERS);MENTAL DISORDER;MENTAL;DVBCWME2;A; ;0905
  1.  ;;QUIT