Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: EASMTRP2

EASMTRP2.m

Go to the documentation of this file. 
  1. EASMTRP2 ; ALB/SCK - MEANS TEST REPORTS 2 ; 2/19/02
  1.  ;;1.0;ENROLLMENT APPLICATION SYSTEM;**3,15,22**;MAR 15,2001
  1.  ;
  1. QUE ; Que pending letter count (letters flagged to print)
  1.  N ZTSAVE,DIR,EASUM,Y
  1.  ;
  1.  S DIR(0)="YAO",DIR("A")="Print Summary Only? ",DIR("B")="YES"
  1.  S DIR("?")="'YES' will print a summary total only, 'NO' will print the summary and a detail listing by scheduled print date"
  1.  D ^DIR K DIR
  1.  Q:$D(DIRUT)
  1.  S EASUM=+Y
  1.  S ZTSAVE("EASUM")=""
  1.  D EN^XUTMDEVQ("PEND^EASMTRP2","EAS LETTERS DETAILED PENDING REPORT",.ZTSAVE)
  1.  Q
  1. PEND ; Print report
  1.  N CNT,EASIEN,PCNT,RCNT,EASX,TOT,PAGE,EAS0,EAS4,EAS6,EASPDT,EAX,TOTALS,DUOUT
  1.  ;
  1.  K ^TMP("EASPND",$J)
  1.  F EAX=0,30,60 S TOTALS(EAX)=0
  1.  S EASIEN=0
  1.  F  S EASIEN=$O(^EAS(713.2,"AC",0,EASIEN)) Q:'EASIEN  D
  1.  . I $P($G(^EAS(713.2,EASIEN,"Z")),U,2) D  Q
  1.  . . S EAS0=$P($G(^EAS(713.2,EASIEN,"Z")),U,1)
  1.  . . S ^TMP("EASPND",$J,EAS0,0)=$G(^TMP("EASPND",$J,EAS0,0))+1
  1.  . . S TOTALS(0)=TOTALS(0)+1
  1.  . ;
  1.  . I $P($G(^EAS(713.2,EASIEN,4)),U,2) D  Q
  1.  . . S EAS4=$P($G(^EAS(713.2,EASIEN,4)),U,1)
  1.  . . S ^TMP("EASPND",$J,EAS4,4)=$G(^TMP("EASPND",$J,EAS4,4))+1
  1.  . . S TOTALS(30)=TOTALS(30)+1
  1.  . ;
  1.  . I $P($G(^EAS(713.2,EASIEN,6)),U,2) D
  1.  . . S EAS6=$P($G(^EAS(713.2,EASIEN,6)),U,1)
  1.  . . S ^TMP("EASPND",$J,EAS6,6)=$G(^TMP("EASPND",$J,EAS6,6))+1
  1.  . . S TOTALS(60)=TOTALS(60)+1
  1.  ;
  1.  D HDR1
  1.  I 'EASUM,$E(IOST,1,2)="C-" D  Q:$D(DUOUT)
  1.  . S DIR(0)="FAO",DIR("A")="Press any key to continue..."
  1.  . D ^DIR K DIR
  1.  . Q:$D(DUOUT)
  1.  ;
  1.  D:'EASUM DETAIL
  1.  Q
  1.  ;
  1. DETAIL ; Print details section
  1.  N EASPDT,DIRUT
  1.  ;
  1.  D HDR
  1.  S EASPDT=0
  1.  F  S EASPDT=$O(^TMP("EASPND",$J,EASPDT)) Q:'EASPDT  D  Q:$D(DIRUT)
  1.  . I ($Y+4)>IOSL D  Q:$D(DIRUT)
  1.  . . I $E(IOST,1,2)="C-" D  Q:$D(DIRUT)
  1.  . . . S DIR(0)="E"
  1.  . . . D ^DIR K DIR
  1.  . . D HDR
  1.  . W !?4,$$FMTE^XLFDT(EASPDT),?20
  1.  . S TOT=0
  1.  . F EAX=6,4,0 D
  1.  . . S CNT=$G(^TMP("EASPND",$J,EASPDT,EAX))
  1.  . . W $J(+CNT,6),"    "
  1.  . . S TOT=$G(TOT)+(+CNT)
  1.  . W $J(TOT,8)
  1.  ;
  1.  K ^TMP("EASPND",$J)
  1.  Q
  1.  ;
  1. HDR1 ;
  1.  N TAB,LINE,DASH
  1.  ;
  1.  W @IOF
  1.  S LINE(1)="Count of Letters Pending to Print (Flag to Print marked 'YES')"
  1.  S LINE(2)="Printed: "_$$FMTE^XLFDT($$NOW^XLFDT)
  1.  S LINE(60)="60-Day letters flagged to print:    "_$FN(TOTALS(60),",")
  1.  S LINE(30)="30-Day letters flagged to print:    "_$FN(TOTALS(30),",")
  1.  S LINE(0)=" 0-Day letters flagged to print:    "_$FN(TOTALS(0),",")
  1.  ;
  1.  S TAB=(IOM-$L(LINE(1)))/2
  1.  W !?TAB,LINE(1)
  1.  W !?TAB,LINE(2)
  1.  S $P(DASH,"=",IOM)=""
  1.  W !,DASH
  1.  ;
  1.  F EAX=60,30,0 D
  1.  . S TAB=(IOM-$L(LINE(EAX)))/2
  1.  . W !?TAB,LINE(EAX)
  1.  Q
  1.  ;
  1. HDR ;
  1.  N TAB,LINE
  1.  ;
  1.  W @IOF
  1.  W !,"Detailed List of Letters Flagged to Print"
  1.  W !,"Printed: "_$$FMTE^XLFDT($$NOW^XLFDT)
  1.  S PAGE=$G(PAGE)+1
  1.  S TAB=IOM-8
  1.  W ?TAB,"PAGE: ",PAGE
  1.  W !!?4,"Sched. Date",?20,"60-Day","    ","30-Day","    "," 0-day","    ","   TOTAL"
  1.  S $P(LINE,"=",IOM)="" W !,LINE
  1.  Q