Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ECXASUR

ECXASUR.m

Go to the documentation of this file. 
  1. ECXASUR ;ALB/JAP - SUR Extract Audit Report ;5/9/14  14:59
  1.  ;;3.0;DSS EXTRACTS;**8,33,44,123,149**;Dec 22, 1997;Build 27
  1.  ;
  1. EN ;entry point for SUR extract audit report
  1.  ;select extract
  1.  N %X,%Y,X,Y,DIC,DA,DR,DIQ,DIR,SITES,ECX,ECXPORT,RCNT ;149
  1.  ;ecxaud=0 for 'extract' audit
  1.  S ECXERR=0
  1.  S ECXHEAD="SUR",ECXAUD=0
  1.  W !!,"Setup for ",ECXHEAD," Extract Audit Report --",!!
  1.  D AUDIT^ECXUTLA(ECXHEAD,.ECXERR,.ECXARRAY,ECXAUD)
  1.  Q:ECXERR
  1.  ;determine if facility is multidivisional
  1.  K ECX D FILE^DID(133,,"ENTRIES","ECX") S SITES=ECX("ENTRIES") K ECX
  1.  I SITES=1 S ECXALL=1
  1.  I SITES>1 D
  1.  .W !!
  1.  .S DIR(0)="Y",DIR("A")="Do you want the "_ECXHEAD_" extract audit report for all divisions"
  1.  .S DIR("B")="NO" D ^DIR K DIR
  1.  .I $G(DIRUT) S ECXERR=1 Q
  1.  .;if y=0 i.e., 'no', then ecxall=0 i.e., 'selected'
  1.  .S ECXALL=Y
  1.  I ECXERR=1 D  Q
  1.  .W !!,?5,"Try again later... exiting.",!
  1.  .D AUDIT^ECXKILL
  1.  ;select divisions/sites; all divisions if ecxall=1
  1.  W !
  1.  S ECXSTART=ECXARRAY("START"),ECXEND=ECXARRAY("END")
  1.  D SUR^ECXDVSN2(.ECXDIV,ECXALL,.ECXERR)
  1.  I ECXERR=1 D  Q
  1.  .W !!,?5,"Try again later... exiting.",!
  1.  .D AUDIT^ECXKILL
  1.  S ECXPORT=$$EXPORT^ECXUTL1 Q:ECXPORT=-1  I $G(ECXPORT) D  Q  ;149 Section added
  1.  .K ^TMP($J,"ECXPORT")
  1.  .S ^TMP($J,"ECXPORT",0)="EXTRACT LOG #^SURGERY DIVISION^TYPE OF PROCEDURES^CPT CODE^PROCEDURE^# OF PROCEDURES",RCNT=1
  1.  .D PROCESS
  1.  .D EXPDISP^ECXUTL1
  1.  .D AUDIT^ECXKILL
  1.  ;determine output device and queue if requested
  1.  S ECXPGM="PROCESS^ECXASUR",ECXDESC="SUR Extract Audit Report"
  1.  S ECXSAVE("ECXHEAD")="",ECXSAVE("ECXALL")="",ECXSAVE("ECXDIV(")="",ECXSAVE("ECXARRAY(")=""
  1.  W !
  1.  D DEVICE^ECXUTLA(ECXPGM,ECXDESC,.ECXSAVE)
  1.  I ECXSAVE("POP")=1 D  Q
  1.  .W !!,?5,"Try again later... exiting.",!
  1.  .D AUDIT^ECXKILL
  1.  I ECXSAVE("ZTSK")=0 D
  1.  .K ECXSAVE,ECXPGM,ECXDESC
  1.  .D PROCESS^ECXASUR
  1.  I IO'=IO(0) D ^%ZISC
  1.  D HOME^%ZIS
  1.  D AUDIT^ECXKILL
  1.  Q
  1.  ;
  1. PROCESS ;process data in file #727.811
  1.  N X,Y,JJ,DIV,IEN,DATA,DATE,CASE,CASES,OR,LOC,PROC,PROCN,PSI,CAN,CPT,DIC,QQFLG,CNT
  1.  K ^TMP($J,"ECXAUD"),^TMP($J,"ECXS")
  1.  S (CNT,QQFLG)=0
  1.  S ECXEXT=ECXARRAY("EXTRACT"),ECXDEF=ECXARRAY("DEF")
  1.  S X=ECXARRAY("START") D ^%DT S ECXSTART=Y S X=ECXARRAY("END") D ^%DT S ECXEND=Y
  1.  ;get run date in external format
  1.  D NOW^%DTC S Y=$E(%,1,12) D DD^%DT S ECXRUN=Y
  1.  ;get records within date range and surgery site(s)
  1.  S IEN="" F  S IEN=$O(^ECX(727.811,"AC",ECXEXT,IEN)) Q:IEN=""  D  Q:QQFLG
  1.  .S DATA=^ECX(727.811,IEN,0),DATA1=^(1),DATE=$P(DATA,U,9)
  1.  .S DIV=$P(DATA,U,4)
  1.  .;convert free text date to fm internal format date
  1.  .S $E(DATE,1,2)=$E(DATE,1,2)-17
  1.  .Q:$L(DATE)<7  Q:(DATE<ECXSTART)  Q:(DATE>ECXEND)
  1.  .Q:'$D(ECXDIV(DIV))
  1.  .Q:$P(DATA,U,17)="I"
  1.  .S CASE=$P(DATA,U,10),OR=$P(DATA,U,12),PSI=$P(DATA,U,17)
  1.  .S CAN=$P(DATA,U,28)
  1.  .S PROC=$E($P(DATA1,U,11),1,5)
  1.  .Q:(PROC="")&(PSI="I")
  1.  .S (CPT,PROCN)="" I PROC]"" D
  1.  ..;from cpt code get procedure name; variable cpt should be same as variable proc
  1.  ..S Y=$$CPT^ICPTCOD(PROC,DATE)
  1.  ..S CPT=$P($G(Y),U,2),PROCN=$P($G(Y),U,3)
  1.  .S:CPT="" CPT="Unknown" S:PROCN="" PROCN="Unknown" S CPT="A"_CPT
  1.  .S LOC=$S(OR="":2,1:1)
  1.  .I CAN'="" S LOC=3
  1.  .;tally procedures by location and division
  1.  .I '$D(^TMP($J,"ECXAUD",DIV,LOC,CPT)) S ^TMP($J,"ECXAUD",DIV,LOC,CPT)=0_U_PROCN
  1.  .S $P(^(CPT),U,1)=$P(^TMP($J,"ECXAUD",DIV,LOC,CPT),U,1)+1,CNT=CNT+1
  1.  .I $D(ZTQUEUED),(CNT>499),'(CNT#500),$$S^%ZTLOAD S QQFLG=1,ZTSTOP=1 K ZTREQ Q
  1.  .I '$D(^TMP($J,"ECXS",DIV,LOC,CASE)) S ^TMP($J,"ECXS",DIV,LOC,CASE)=""
  1.  ;total cases for each division and location
  1.  I $D(ZTQUEUED),$$S^%ZTLOAD S ZTSTOP=1 K ZTREQ Q
  1.  S DIV="" F  S DIV=$O(^TMP($J,"ECXS",DIV)) Q:DIV=""  F LOC=1:1:3 S CASES(DIV,LOC)=0,CASE="" D
  1.  .F  S CASE=$O(^TMP($J,"ECXS",DIV,LOC,CASE)) Q:CASE=""  S CASES(DIV,LOC)=CASES(DIV,LOC)+1
  1.  K ^TMP($J,"ECXS")
  1.  ;print the report
  1.  D PRINT
  1.  I $G(ECXPORT) Q  ;149
  1.  D AUDIT^ECXKILL
  1.  Q
  1.  ;
  1. PRINT ;print the SUR audit report by location and division
  1.  N LN,PG,QFLG,TOT,GTOT,DIVNM,CPT,CPTN,PROCN,LOCNM,LOCNMC,SS,DIR,DR,DIRUT,DTOUT,DUOUT
  1.  U IO
  1.  I $D(ZTQUEUED),$$S^%ZTLOAD S ZTSTOP=1 K ZTREQ Q
  1.  S (QFLG,PG)=0,$P(LN,"-",80)="",DIV=""
  1.  F  S DIV=$O(ECXDIV(DIV)) Q:DIV=""  F LOC=1:1:3 D  Q:QFLG
  1.  .S DIVNM=$P(ECXDIV(DIV),U,2)_" ("_DIV_")",GTOT(LOC)=0
  1.  .S LOCNM=$S(LOC=1:"O.R. Surgical Procedures",LOC=2:"Non-O.R. Surgical Procedures",1:"Cancelled/Aborted Procedures")
  1.  .I '$G(ECXPORT) D HEADER ;149
  1.  .I '$D(^TMP($J,"ECXAUD",DIV,LOC)) D
  1.  ..I $G(ECXPORT) S ^TMP($J,"ECXPORT",RCNT)=ECXARRAY("EXTRACT")_U_DIVNM_U_"No data available for "_LOCNM,RCNT=RCNT+1 Q  ;149
  1.  ..W !!,?3,"No data available for "_LOCNM_".",!!
  1.  .I $D(^TMP($J,"ECXAUD",DIV,LOC)) S CPT="" F  S CPT=$O(^TMP($J,"ECXAUD",DIV,LOC,CPT)) Q:CPT=""  S TOT(LOC)=$P(^(CPT),U,1),PROCN=$P(^(CPT),U,2),CPTN=$E(CPT,2,99) D  Q:QFLG
  1.  ..S GTOT(LOC)=GTOT(LOC)+TOT(LOC)
  1.  ..;write procedure and total
  1.  ..I '$G(ECXPORT) D:($Y+3>IOSL) HEADER Q:QFLG  W !,?3,CPTN,?14,$E(PROCN,1,40),?63,$$RJ^XLFSTR(TOT(LOC),5," ") ;149
  1.  ..I $G(ECXPORT) S ^TMP($J,"ECXPORT",RCNT)=ECXARRAY("EXTRACT")_U_DIVNM_U_LOCNM_U_CPTN_U_PROCN_U_TOT(LOC),RCNT=RCNT+1 ;149
  1.  .;write the division totals
  1.  .I $G(ECXPORT) D  Q  ;149 Section added
  1.  ..S ^TMP($J,"ECXPORT",RCNT)="^",RCNT=RCNT+1
  1.  ..S ^TMP($J,"ECXPORT",RCNT)="^For Division "_DIVNM_"^^^"_"Total "_LOCNM_U_GTOT(LOC),RCNT=RCNT+1
  1.  ..S LOCNMC=$P(LOCNM,"Pro",1) S:'$D(CASES(DIV,LOC)) CASES(DIV,LOC)=0
  1.  ..S ^TMP($J,"ECXPORT",RCNT)="^For Division "_DIVNM_"^^^"_"Total "_LOCNMC_"Cases"_U_CASES(DIV,LOC),RCNT=RCNT+1
  1.  ..S ^TMP($J,"ECXPORT",RCNT)="^",RCNT=RCNT+1
  1.  .D:($Y+3>IOSL) HEADER Q:QFLG  W !,?3,$E(LN,1,65)
  1.  .D:($Y+3>IOSL) HEADER Q:QFLG  W !!,"For Division "_DIVNM_"--"
  1.  .D:($Y+3>IOSL) HEADER Q:QFLG  W !,?3,"Total "_LOCNM_":",?63,$$RJ^XLFSTR(GTOT(LOC),5," ")
  1.  .S LOCNMC=$P(LOCNM,"Pro",1) S:'$D(CASES(DIV,LOC)) CASES(DIV,LOC)=0
  1.  .D:($Y+3>IOSL) HEADER Q:QFLG  W !,?3,"Total "_LOCNMC_"Cases:",?63,$$RJ^XLFSTR(CASES(DIV,LOC),5," ")
  1.  ;print the audit descriptive narrative
  1.  I $G(ECXPORT) Q  ;149
  1.  I $E(IOST)'="C" D
  1.  .W @IOF S PG=PG+1
  1.  .W !,ECXARRAY("TYPE")_" ("_ECXHEAD_") Extract Audit Report"
  1.  .W !,"DSS Extract Log #:    "_ECXEXT
  1.  .W !,"Date Range of Audit:  "_ECXARRAY("START")_" to "_ECXARRAY("END")
  1.  .W !,"Report Run Date/Time: "_ECXRUN,?68,"Page: ",PG
  1.  .W !!,LN,!!
  1.  .S DIC="^ECX(727.1,",DA=ECXARRAY("DEF"),DR="1" D EN^DIQ
  1.  I $E(IOST)="C",'QFLG D
  1.  .S SS=22-$Y F JJ=1:1:SS W !
  1.  .S DIR(0)="E" W ! D ^DIR K DIR
  1.  Q
  1.  ;
  1.  Q:QFLG  ;149 Don't print header if user entered "^"
  1.  N JJ,SS
  1.  I $E(IOST)="C" D
  1.  .S SS=22-$Y F JJ=1:1:SS W !
  1.  .I PG>0 S DIR(0)="E" W ! D ^DIR K DIR S:'Y QFLG=1
  1.  Q:QFLG
  1.  W:$Y!($E(IOST)="C") @IOF S PG=PG+1
  1.  W !,ECXARRAY("TYPE")_" ("_ECXHEAD_") Extract Audit Report"
  1.  W !,"DSS Extract Log #:    "_ECXARRAY("EXTRACT")
  1.  W !,"Date Range of Audit:  "_ECXARRAY("START")_" to "_ECXARRAY("END")
  1.  W !,"Report Run Date/Time: "_ECXRUN
  1.  W !,"Surgery Division:     "_$P(ECXDIV(DIV),U,2)_" ("_DIV_")",?63,"Page: "_PG
  1.  W !!,LOCNM
  1.  W !,?3,"CPT Code",?14,"Procedure",?63,"# of Procedures"
  1.  W !,LN,!
  1.  Q