Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ENFARA1

ENFARA1.m

Go to the documentation of this file. 
  1. ENFARA1 ;WIRMFO/SAB-FIXED ASSET RPT, ADJUSTMENT VOUCHER (CONT) ;5.16.97
  1.  ;;7.0;ENGINEERING;**39**;Aug 17, 1993
  1. QEN ; queued entry
  1.  ; in
  1.  ;   ENDTS - start date
  1.  ;   ENDTE - end date
  1.  ;   ENSRT("U") - true if sort by user
  1.  ;   if ENSRT("U") true
  1.  ;     ENSRT("U",0) - DUZ of selected user or * for all
  1.  ;     ENSRT("U",0,"E") - external value for ENSRT("U",0)
  1.  U IO
  1. GETDATA ; collect/sort data
  1.  S ENUSR="*"
  1.  ; loop thru FAP document file transactions within selected date range
  1.  K ^TMP($J) F ENFILE="6915.2","6915.3","6915.4","6915.5","6915.6" D
  1.  . S ENDT=ENDTS
  1.  . ;***F  S ENDT=$O(^ENG(ENFILE,"AV",ENDT)) Q:ENDT=""!(ENDT>ENDTE)  D
  1.  . F  S ENDT=$O(^ENG(ENFILE,"AV",ENDT)) Q:ENDT=""!($P(ENDT,".")>ENDTE)  D
  1.  . . S ENDA("F?")=0
  1.  . . F  S ENDA("F?")=$O(^ENG(ENFILE,"AV",ENDT,ENDA("F?"))) Q:'ENDA("F?")  D
  1.  . . . I ENSRT("U") S ENUSR=$$GET1^DIQ(ENFILE,ENDA("F?"),302,"I")
  1.  . . . I ENSRT("U"),ENSRT("U",0)'="*",ENUSR'=ENSRT("U",0) Q
  1.  . . . S ^TMP($J,ENUSR,ENDT,ENFILE_";"_ENDA("F?"))=""
  1. PRINT ; print
  1.  ; load table for converting FA Type to SGL
  1.  K ENFAPTY S ENDA=0 F   S ENDA=$O(^ENG(6914.3,ENDA)) Q:'ENDA  D
  1.  . S ENY0=$G(^ENG(6914.3,ENDA,0))
  1.  . I $P(ENY0,U,3)]"" S ENFAPTY($P(ENY0,U,3))=$P(ENY0,U)
  1.  ;
  1.  S (END,ENPG)=0 D NOW^%DTC S Y=% D DD^%DT S ENDTR=Y
  1.  S ENL="",$P(ENL,"-",IOM)=""
  1.  I '$D(^TMP($J)) D HD W !!,"No activity in selected period",!
  1.  S ENUSR="" F  S ENUSR=$O(^TMP($J,ENUSR)) Q:ENUSR=""  D  Q:END
  1.  . S ENUSR("E")=$S('ENSRT("U"):"",1:$$GET1^DIQ(200,ENUSR,.01))
  1.  . K ENT
  1.  . D HD Q:END
  1.  . S ENDT="" F  S ENDT=$O(^TMP($J,ENUSR,ENDT)) Q:ENDT=""  D  Q:END
  1.  . . S ENY="" F  S ENY=$O(^TMP($J,ENUSR,ENDT,ENY)) Q:ENY=""  D  Q:END
  1.  . . . S ENFILE=$P(ENY,";"),ENDA("F?")=$P(ENY,";",2)
  1.  . . . S ENY0=$G(^ENG(ENFILE,ENDA("F?"),0))
  1.  . . . S ENY1=$G(^ENG(ENFILE,ENDA("F?"),1))
  1.  . . . S ENDA=$P($G(^ENG(ENFILE,ENDA("F?"),0)),U)
  1.  . . . S ENDA("FA")=$$AFA^ENFAR5A(ENFILE,ENDA("F?")) ; associated FA
  1.  . . . S ENFAY3=$G(^ENG(6915.2,ENDA("FA"),3))
  1.  . . . S ENSN=$TR($E($P(ENFAY3,U,5),1,5)," ","")
  1.  . . . S:ENFILE=6915.2 ENFUND=$P(ENFAY3,U,10)
  1.  . . . S:ENFILE'=6915.2 ENFUND=$$FUND^ENFAR5A(ENFILE,ENDA("F?"),ENDA("FA"))
  1.  . . . S ENSGL=$S($P(ENFAY3,U,6)]"":$G(ENFAPTY($P(ENFAY3,U,6))),1:"")
  1.  . . . S ENAMT=0
  1.  . . . I ENFILE=6915.2 S ENAMT=$P($G(^ENG(ENFILE,ENDA("F?"),3)),U,27)
  1.  . . . I ENFILE=6915.3 S ENAMT=$P($G(^ENG(ENFILE,ENDA("F?"),4)),U,4)
  1.  . . . I ENFILE=6915.4 S ENX=$P($G(^ENG(ENFILE,ENDA("F?"),4)),U,6),ENAMT=$S(ENX="":0,1:ENX-$P($G(^ENG(ENFILE,ENDA("F?"),100)),U,4))
  1.  . . . I ENFILE=6915.5 S ENAMT="-"_$P($G(^ENG(ENFILE,ENDA("F?"),100)),U,2)
  1.  . . . I ENFILE=6915.6 S ENAMT=$P($G(^ENG(ENFILE,ENDA("F?"),100)),U,8)
  1.  . . . I $Y+8>IOSL D HD Q:END
  1.  . . . W !,$E($TR($$FMTE^XLFDT(ENDT,"2F")," ",0),1,14)
  1.  . . . W ?16,$P(ENY1,U,6),?22,$P(ENY1,U,9)
  1.  . . . W ?34,$TR($$FMTE^XLFDT($P(ENY0,U,2),"2DF")," ",0)
  1.  . . . W ?44,ENSN,?51,ENFUND,?58,ENSGL
  1.  . . . I ENFILE=6915.6 D  ; check FR doc for FUND change
  1.  . . . . S ENFUNDNW=$P($G(^ENG(ENFILE,ENDA("F?"),3)),U,9)
  1.  . . . . I ENFUND=ENFUNDNW S ENAMT=0 Q  ; fund didn't change
  1.  . . . . S ENAMT=-ENAMT ; subtract from old fund
  1.  . . . W ?63,$J($FN(ENAMT,",",2),16)
  1.  . . . S ENT(ENSN,ENFUND,ENSGL)=$G(ENT(ENSN,ENFUND,ENSGL))+ENAMT
  1.  . . . I ENFILE=6915.6,ENFUND'=ENFUNDNW D
  1.  . . . . ; show addition to new fund
  1.  . . . . W !,?44,ENSN,?51,ENFUNDNW,?58,ENSGL
  1.  . . . . W ?63,$J($FN(-ENAMT,",",2),16)
  1.  . . . . S ENT(ENSN,ENFUNDNW,ENSGL)=$G(ENT(ENSN,ENFUNDNW,ENSGL))-ENAMT
  1.  . . . ;
  1.  . . . W !,?4,"EQUIP #: ",ENDA,?26,$$GET1^DIQ(6914,ENDA,3)
  1.  . . . W !,?4,"P.O. #: ",$P($G(^ENG(6914,ENDA,2)),U,2)
  1.  . . . W ?26,"A.V. REASON: ",$$GET1^DIQ(ENFILE,ENDA("F?"),303)
  1.  . . . K ^UTILITY($J,"W") S DIWL=5,DIWR=(IOM-5),DIWF="W|"
  1.  . . . S X="COMMENTS: ",ENI=0
  1.  . . . F  S ENI=$O(^ENG(ENFILE,ENDA("F?"),301,ENI)) Q:'ENI  S X=X_^(ENI,0) D ^DIWP S X="" I $Y+6>IOSL D HD Q:END  D HDAV
  1.  . . . Q:END
  1.  . . . D ^DIWW
  1.  . Q:END
  1.  . I $Y+10>IOSL D HD Q:END
  1.  . W !,?30,"TOTALS:"
  1.  . S ENTU=0 ; initialize user/grand total
  1.  . S ENSN="" F  S ENSN=$O(ENT(ENSN)) Q:ENSN=""  D  Q:END
  1.  . . S ENTS="0" ; initialize station totals
  1.  . . S ENFUND="" F  S ENFUND=$O(ENT(ENSN,ENFUND)) Q:ENFUND=""  D  Q:END
  1.  . . . S ENTF="0" ; initialize fund totals
  1.  . . . S ENSGL=""
  1.  . . . F  S ENSGL=$O(ENT(ENSN,ENFUND,ENSGL)) Q:ENSGL=""  D  Q:END
  1.  . . . . I $Y+6>IOSL D HD Q:END  W !,?30,"TOTALS: (continued)"
  1.  . . . . W !,?44,ENSN,?51,ENFUND,?58,ENSGL
  1.  . . . . W ?63,$J($FN($P(ENT(ENSN,ENFUND,ENSGL),U),",",2),16)
  1.  . . . . S $P(ENTF,U)=$P(ENTF,U)+$P(ENT(ENSN,ENFUND,ENSGL),U)
  1.  . . . Q:END
  1.  . . . S $P(ENTS,U)=$P(ENTS,U)+$P(ENTF,U)
  1.  . . . I $Y+6>IOSL D HD Q:END  W !,?30,"TOTALS: (continued)"
  1.  . . . W !,?63,"----------------"
  1.  . . . W !,?44,ENSN,?51,ENFUND,?58,"TOTAL",?63,$J($FN($P(ENTF,U),",",2),16),!
  1.  . . Q:END
  1.  . . S $P(ENTU,U)=$P(ENTU,U)+$P(ENTS,U)
  1.  . . I $Y+6>IOSL D HD Q:END  W !,?30,"TOTALS: (continued)"
  1.  . . W !,?63,"----------------"
  1.  . . W !,?44,ENSN,?50,"TOTAL",?63,$J($FN($P(ENTS,U),",",2),16),!
  1.  . Q:END
  1.  . I $Y+6>IOSL D HD Q:END  W !,?30,"TOTALS: (continued)"
  1.  . W !,?63,"================"
  1.  . W !,?44,$S(ENSRT("U"):"USER",1:"GRAND")," TOTAL"
  1.  . W ?63,$J($FN($P(ENTU,U),",",2),16),!
  1.  . D FT
  1.  I 'END,$E(IOST,1,2)="C-" S DIR(0)="E" D ^DIR K DIR
  1. WRAPUP ; wrap up
  1.  D ^%ZISC
  1.  I $D(ZTQUEUED) S ZTREQ="@"
  1.  K DIWF,DIWL,DIWR,X,Y
  1.  K ^TMP($J),ENAMT,END,ENDA,ENDT,ENDTE,ENDTR,ENDTS,ENFAPTY,ENFAY3
  1.  K ENFILE,ENFUND,ENFUNDNW,ENI,ENIEN,ENL,ENPG,ENSGL,ENSN,ENSRT,ENUSR
  1.  K ENT,ENTS,ENTF,ENTU,ENX,ENY,ENY0,ENY1
  1.  Q
  1. HD ; page header
  1.  I $D(ZTQUEUED),$$S^%ZTLOAD S ZTSTOP=1,END=1 Q
  1.  I $E(IOST,1,2)="C-",ENPG S DIR(0)="E" D ^DIR K DIR I 'Y S END=1 Q
  1.  I $E(IOST,1,2)="C-"!ENPG W @IOF
  1.  S ENPG=ENPG+1
  1.  S $X=0
  1.  W "ADJUSTMENT VOUCHERS",?49,ENDTR,?72,"page ",ENPG
  1.  W !,?2,"FROM ",$$FMTE^XLFDT(ENDTS,"2")," TO ",$$FMTE^XLFDT(ENDTE,"2")
  1.  I ENSRT("U") D
  1.  . W "  (SORT BY USER FOR ",ENSRT("U",0,"E"),")"
  1.  . I ENSRT("U",0)="*",$G(ENUSR("E"))]"" W !,"A.V.s By: ",ENUSR("E")
  1.  W !!,"ADJ. VOUCHER",?16,"...... TRANSACTION .......",?44,"STN"
  1.  W ?51,"FUND",?58,"SGL",?63,"NET AMOUNT"
  1.  W !,"DATE/TIME",?16,"CODE  NUMBER      DATE"
  1.  W !,"--------------",?16,"----- ----------- --------",?44,"-----"
  1.  W ?51,"------",?58,"----",?63,"----------------"
  1.  Q
  1. HDAV ; header for continued adjustment voucher
  1.  W !,?4,"Transaction: ",$P(ENY1,U,6),"-",$P(ENY1,U,9),"(continued)"
  1.  Q
  1. FT ; report footer when hardcopy
  1.  Q:$E(IOST,1,2)="C-"!'ENPG
  1.  W !!!,?4,"--------------------  --------"
  1.  W ?44,"--------------------  --------"
  1.  W !,?4,"ACCOUNTABLE OFFICER   DATE"
  1.  W ?44,"APPROVING OFFICIAL    DATE"
  1.  Q
  1.  ;ENFARA1