ENFARA1 ;WIRMFO/SAB-FIXED ASSET RPT, ADJUSTMENT VOUCHER (CONT) ;5.16.97
;;7.0;ENGINEERING;**39**;Aug 17, 1993
QEN ; queued entry
; in
; ENDTS - start date
; ENDTE - end date
; ENSRT("U") - true if sort by user
; if ENSRT("U") true
; ENSRT("U",0) - DUZ of selected user or * for all
; ENSRT("U",0,"E") - external value for ENSRT("U",0)
U IO
GETDATA ; collect/sort data
S ENUSR="*"
; loop thru FAP document file transactions within selected date range
K ^TMP($J) F ENFILE="6915.2","6915.3","6915.4","6915.5","6915.6" D
. S ENDT=ENDTS
. ;***F S ENDT=$O(^ENG(ENFILE,"AV",ENDT)) Q:ENDT=""!(ENDT>ENDTE) D
. F S ENDT=$O(^ENG(ENFILE,"AV",ENDT)) Q:ENDT=""!($P(ENDT,".")>ENDTE) D
. . S ENDA("F?")=0
. . F S ENDA("F?")=$O(^ENG(ENFILE,"AV",ENDT,ENDA("F?"))) Q:'ENDA("F?") D
. . . I ENSRT("U") S ENUSR=$$GET1^DIQ(ENFILE,ENDA("F?"),302,"I")
. . . I ENSRT("U"),ENSRT("U",0)'="*",ENUSR'=ENSRT("U",0) Q
. . . S ^TMP($J,ENUSR,ENDT,ENFILE_";"_ENDA("F?"))=""
PRINT ; print
; load table for converting FA Type to SGL
K ENFAPTY S ENDA=0 F S ENDA=$O(^ENG(6914.3,ENDA)) Q:'ENDA D
. S ENY0=$G(^ENG(6914.3,ENDA,0))
. I $P(ENY0,U,3)]"" S ENFAPTY($P(ENY0,U,3))=$P(ENY0,U)
;
S (END,ENPG)=0 D NOW^%DTC S Y=% D DD^%DT S ENDTR=Y
S ENL="",$P(ENL,"-",IOM)=""
I '$D(^TMP($J)) D HD W !!,"No activity in selected period",!
S ENUSR="" F S ENUSR=$O(^TMP($J,ENUSR)) Q:ENUSR="" D Q:END
. S ENUSR("E")=$S('ENSRT("U"):"",1:$$GET1^DIQ(200,ENUSR,.01))
. K ENT
. D HD Q:END
. S ENDT="" F S ENDT=$O(^TMP($J,ENUSR,ENDT)) Q:ENDT="" D Q:END
. . S ENY="" F S ENY=$O(^TMP($J,ENUSR,ENDT,ENY)) Q:ENY="" D Q:END
. . . S ENFILE=$P(ENY,";"),ENDA("F?")=$P(ENY,";",2)
. . . S ENY0=$G(^ENG(ENFILE,ENDA("F?"),0))
. . . S ENY1=$G(^ENG(ENFILE,ENDA("F?"),1))
. . . S ENDA=$P($G(^ENG(ENFILE,ENDA("F?"),0)),U)
. . . S ENDA("FA")=$$AFA^ENFAR5A(ENFILE,ENDA("F?")) ; associated FA
. . . S ENFAY3=$G(^ENG(6915.2,ENDA("FA"),3))
. . . S ENSN=$TR($E($P(ENFAY3,U,5),1,5)," ","")
. . . S:ENFILE=6915.2 ENFUND=$P(ENFAY3,U,10)
. . . S:ENFILE'=6915.2 ENFUND=$$FUND^ENFAR5A(ENFILE,ENDA("F?"),ENDA("FA"))
. . . S ENSGL=$S($P(ENFAY3,U,6)]"":$G(ENFAPTY($P(ENFAY3,U,6))),1:"")
. . . S ENAMT=0
. . . I ENFILE=6915.2 S ENAMT=$P($G(^ENG(ENFILE,ENDA("F?"),3)),U,27)
. . . I ENFILE=6915.3 S ENAMT=$P($G(^ENG(ENFILE,ENDA("F?"),4)),U,4)
. . . I ENFILE=6915.4 S ENX=$P($G(^ENG(ENFILE,ENDA("F?"),4)),U,6),ENAMT=$S(ENX="":0,1:ENX-$P($G(^ENG(ENFILE,ENDA("F?"),100)),U,4))
. . . I ENFILE=6915.5 S ENAMT="-"_$P($G(^ENG(ENFILE,ENDA("F?"),100)),U,2)
. . . I ENFILE=6915.6 S ENAMT=$P($G(^ENG(ENFILE,ENDA("F?"),100)),U,8)
. . . I $Y+8>IOSL D HD Q:END
. . . W !,$E($TR($$FMTE^XLFDT(ENDT,"2F")," ",0),1,14)
. . . W ?16,$P(ENY1,U,6),?22,$P(ENY1,U,9)
. . . W ?34,$TR($$FMTE^XLFDT($P(ENY0,U,2),"2DF")," ",0)
. . . W ?44,ENSN,?51,ENFUND,?58,ENSGL
. . . I ENFILE=6915.6 D ; check FR doc for FUND change
. . . . S ENFUNDNW=$P($G(^ENG(ENFILE,ENDA("F?"),3)),U,9)
. . . . I ENFUND=ENFUNDNW S ENAMT=0 Q ; fund didn't change
. . . . S ENAMT=-ENAMT ; subtract from old fund
. . . W ?63,$J($FN(ENAMT,",",2),16)
. . . S ENT(ENSN,ENFUND,ENSGL)=$G(ENT(ENSN,ENFUND,ENSGL))+ENAMT
. . . I ENFILE=6915.6,ENFUND'=ENFUNDNW D
. . . . ; show addition to new fund
. . . . W !,?44,ENSN,?51,ENFUNDNW,?58,ENSGL
. . . . W ?63,$J($FN(-ENAMT,",",2),16)
. . . . S ENT(ENSN,ENFUNDNW,ENSGL)=$G(ENT(ENSN,ENFUNDNW,ENSGL))-ENAMT
. . . ;
. . . W !,?4,"EQUIP #: ",ENDA,?26,$$GET1^DIQ(6914,ENDA,3)
. . . W !,?4,"P.O. #: ",$P($G(^ENG(6914,ENDA,2)),U,2)
. . . W ?26,"A.V. REASON: ",$$GET1^DIQ(ENFILE,ENDA("F?"),303)
. . . K ^UTILITY($J,"W") S DIWL=5,DIWR=(IOM-5),DIWF="W|"
. . . S X="COMMENTS: ",ENI=0
. . . F S ENI=$O(^ENG(ENFILE,ENDA("F?"),301,ENI)) Q:'ENI S X=X_^(ENI,0) D ^DIWP S X="" I $Y+6>IOSL D HD Q:END D HDAV
. . . Q:END
. . . D ^DIWW
. Q:END
. I $Y+10>IOSL D HD Q:END
. W !,?30,"TOTALS:"
. S ENTU=0 ; initialize user/grand total
. S ENSN="" F S ENSN=$O(ENT(ENSN)) Q:ENSN="" D Q:END
. . S ENTS="0" ; initialize station totals
. . S ENFUND="" F S ENFUND=$O(ENT(ENSN,ENFUND)) Q:ENFUND="" D Q:END
. . . S ENTF="0" ; initialize fund totals
. . . S ENSGL=""
. . . F S ENSGL=$O(ENT(ENSN,ENFUND,ENSGL)) Q:ENSGL="" D Q:END
. . . . I $Y+6>IOSL D HD Q:END W !,?30,"TOTALS: (continued)"
. . . . W !,?44,ENSN,?51,ENFUND,?58,ENSGL
. . . . W ?63,$J($FN($P(ENT(ENSN,ENFUND,ENSGL),U),",",2),16)
. . . . S $P(ENTF,U)=$P(ENTF,U)+$P(ENT(ENSN,ENFUND,ENSGL),U)
. . . Q:END
. . . S $P(ENTS,U)=$P(ENTS,U)+$P(ENTF,U)
. . . I $Y+6>IOSL D HD Q:END W !,?30,"TOTALS: (continued)"
. . . W !,?63,"----------------"
. . . W !,?44,ENSN,?51,ENFUND,?58,"TOTAL",?63,$J($FN($P(ENTF,U),",",2),16),!
. . Q:END
. . S $P(ENTU,U)=$P(ENTU,U)+$P(ENTS,U)
. . I $Y+6>IOSL D HD Q:END W !,?30,"TOTALS: (continued)"
. . W !,?63,"----------------"
. . W !,?44,ENSN,?50,"TOTAL",?63,$J($FN($P(ENTS,U),",",2),16),!
. Q:END
. I $Y+6>IOSL D HD Q:END W !,?30,"TOTALS: (continued)"
. W !,?63,"================"
. W !,?44,$S(ENSRT("U"):"USER",1:"GRAND")," TOTAL"
. W ?63,$J($FN($P(ENTU,U),",",2),16),!
. D FT
I 'END,$E(IOST,1,2)="C-" S DIR(0)="E" D ^DIR K DIR
WRAPUP ; wrap up
D ^%ZISC
I $D(ZTQUEUED) S ZTREQ="@"
K DIWF,DIWL,DIWR,X,Y
K ^TMP($J),ENAMT,END,ENDA,ENDT,ENDTE,ENDTR,ENDTS,ENFAPTY,ENFAY3
K ENFILE,ENFUND,ENFUNDNW,ENI,ENIEN,ENL,ENPG,ENSGL,ENSN,ENSRT,ENUSR
K ENT,ENTS,ENTF,ENTU,ENX,ENY,ENY0,ENY1
Q
HD ; page header
I $D(ZTQUEUED),$$S^%ZTLOAD S ZTSTOP=1,END=1 Q
I $E(IOST,1,2)="C-",ENPG S DIR(0)="E" D ^DIR K DIR I 'Y S END=1 Q
I $E(IOST,1,2)="C-"!ENPG W @IOF
S ENPG=ENPG+1
S $X=0
W "ADJUSTMENT VOUCHERS",?49,ENDTR,?72,"page ",ENPG
W !,?2,"FROM ",$$FMTE^XLFDT(ENDTS,"2")," TO ",$$FMTE^XLFDT(ENDTE,"2")
I ENSRT("U") D
. W " (SORT BY USER FOR ",ENSRT("U",0,"E"),")"
. I ENSRT("U",0)="*",$G(ENUSR("E"))]"" W !,"A.V.s By: ",ENUSR("E")
W !!,"ADJ. VOUCHER",?16,"...... TRANSACTION .......",?44,"STN"
W ?51,"FUND",?58,"SGL",?63,"NET AMOUNT"
W !,"DATE/TIME",?16,"CODE NUMBER DATE"
W !,"--------------",?16,"----- ----------- --------",?44,"-----"
W ?51,"------",?58,"----",?63,"----------------"
Q
HDAV ; header for continued adjustment voucher
W !,?4,"Transaction: ",$P(ENY1,U,6),"-",$P(ENY1,U,9),"(continued)"
Q
FT ; report footer when hardcopy
Q:$E(IOST,1,2)="C-"!'ENPG
W !!!,?4,"-------------------- --------"
W ?44,"-------------------- --------"
W !,?4,"ACCOUNTABLE OFFICER DATE"
W ?44,"APPROVING OFFICIAL DATE"
Q
;ENFARA1
--- Routine Detail --- with STRUCTURED ROUTINE LISTING ---[H[J[2J[HENFARA1 6587 printed Oct 16, 2024@17:54:32 Page 2
ENFARA1 ;WIRMFO/SAB-FIXED ASSET RPT, ADJUSTMENT VOUCHER (CONT) ;5.16.97
+1 ;;7.0;ENGINEERING;**39**;Aug 17, 1993
QEN ; queued entry
+1 ; in
+2 ; ENDTS - start date
+3 ; ENDTE - end date
+4 ; ENSRT("U") - true if sort by user
+5 ; if ENSRT("U") true
+6 ; ENSRT("U",0) - DUZ of selected user or * for all
+7 ; ENSRT("U",0,"E") - external value for ENSRT("U",0)
+8 USE IO
GETDATA ; collect/sort data
+1 SET ENUSR="*"
+2 ; loop thru FAP document file transactions within selected date range
+3 KILL ^TMP($JOB)
FOR ENFILE="6915.2","6915.3","6915.4","6915.5","6915.6"
Begin DoDot:1
+4 SET ENDT=ENDTS
+5 ;***F S ENDT=$O(^ENG(ENFILE,"AV",ENDT)) Q:ENDT=""!(ENDT>ENDTE) D
+6 FOR
SET ENDT=$ORDER(^ENG(ENFILE,"AV",ENDT))
if ENDT=""!($PIECE(ENDT,".")>ENDTE)
QUIT
Begin DoDot:2
+7 SET ENDA("F?")=0
+8 FOR
SET ENDA("F?")=$ORDER(^ENG(ENFILE,"AV",ENDT,ENDA("F?")))
if 'ENDA("F?")
QUIT
Begin DoDot:3
+9 IF ENSRT("U")
SET ENUSR=$$GET1^DIQ(ENFILE,ENDA("F?"),302,"I")
+10 IF ENSRT("U")
IF ENSRT("U",0)'="*"
IF ENUSR'=ENSRT("U",0)
QUIT
+11 SET ^TMP($JOB,ENUSR,ENDT,ENFILE_";"_ENDA("F?"))=""
End DoDot:3
End DoDot:2
End DoDot:1
PRINT ; print
+1 ; load table for converting FA Type to SGL
+2 KILL ENFAPTY
SET ENDA=0
FOR
SET ENDA=$ORDER(^ENG(6914.3,ENDA))
if 'ENDA
QUIT
Begin DoDot:1
+3 SET ENY0=$GET(^ENG(6914.3,ENDA,0))
+4 IF $PIECE(ENY0,U,3)]""
SET ENFAPTY($PIECE(ENY0,U,3))=$PIECE(ENY0,U)
End DoDot:1
+5 ;
+6 SET (END,ENPG)=0
DO NOW^%DTC
SET Y=%
DO DD^%DT
SET ENDTR=Y
+7 SET ENL=""
SET $PIECE(ENL,"-",IOM)=""
+8 IF '$DATA(^TMP($JOB))
DO HD
WRITE !!,"No activity in selected period",!
+9 SET ENUSR=""
FOR
SET ENUSR=$ORDER(^TMP($JOB,ENUSR))
if ENUSR=""
QUIT
Begin DoDot:1
+10 SET ENUSR("E")=$SELECT('ENSRT("U"):"",1:$$GET1^DIQ(200,ENUSR,.01))
+11 KILL ENT
+12 DO HD
if END
QUIT
+13 SET ENDT=""
FOR
SET ENDT=$ORDER(^TMP($JOB,ENUSR,ENDT))
if ENDT=""
QUIT
Begin DoDot:2
+14 SET ENY=""
FOR
SET ENY=$ORDER(^TMP($JOB,ENUSR,ENDT,ENY))
if ENY=""
QUIT
Begin DoDot:3
+15 SET ENFILE=$PIECE(ENY,";")
SET ENDA("F?")=$PIECE(ENY,";",2)
+16 SET ENY0=$GET(^ENG(ENFILE,ENDA("F?"),0))
+17 SET ENY1=$GET(^ENG(ENFILE,ENDA("F?"),1))
+18 SET ENDA=$PIECE($GET(^ENG(ENFILE,ENDA("F?"),0)),U)
+19 ; associated FA
SET ENDA("FA")=$$AFA^ENFAR5A(ENFILE,ENDA("F?"))
+20 SET ENFAY3=$GET(^ENG(6915.2,ENDA("FA"),3))
+21 SET ENSN=$TRANSLATE($EXTRACT($PIECE(ENFAY3,U,5),1,5)," ","")
+22 if ENFILE=6915.2
SET ENFUND=$PIECE(ENFAY3,U,10)
+23 if ENFILE'=6915.2
SET ENFUND=$$FUND^ENFAR5A(ENFILE,ENDA("F?"),ENDA("FA"))
+24 SET ENSGL=$SELECT($PIECE(ENFAY3,U,6)]"":$GET(ENFAPTY($PIECE(ENFAY3,U,6))),1:"")
+25 SET ENAMT=0
+26 IF ENFILE=6915.2
SET ENAMT=$PIECE($GET(^ENG(ENFILE,ENDA("F?"),3)),U,27)
+27 IF ENFILE=6915.3
SET ENAMT=$PIECE($GET(^ENG(ENFILE,ENDA("F?"),4)),U,4)
+28 IF ENFILE=6915.4
SET ENX=$PIECE($GET(^ENG(ENFILE,ENDA("F?"),4)),U,6)
SET ENAMT=$SELECT(ENX="":0,1:ENX-$PIECE($GET(^ENG(ENFILE,ENDA("F?"),100)),U,4))
+29 IF ENFILE=6915.5
SET ENAMT="-"_$PIECE($GET(^ENG(ENFILE,ENDA("F?"),100)),U,2)
+30 IF ENFILE=6915.6
SET ENAMT=$PIECE($GET(^ENG(ENFILE,ENDA("F?"),100)),U,8)
+31 IF $Y+8>IOSL
DO HD
if END
QUIT
+32 WRITE !,$EXTRACT($TRANSLATE($$FMTE^XLFDT(ENDT,"2F")," ",0),1,14)
+33 WRITE ?16,$PIECE(ENY1,U,6),?22,$PIECE(ENY1,U,9)
+34 WRITE ?34,$TRANSLATE($$FMTE^XLFDT($PIECE(ENY0,U,2),"2DF")," ",0)
+35 WRITE ?44,ENSN,?51,ENFUND,?58,ENSGL
+36 ; check FR doc for FUND change
IF ENFILE=6915.6
Begin DoDot:4
+37 SET ENFUNDNW=$PIECE($GET(^ENG(ENFILE,ENDA("F?"),3)),U,9)
+38 ; fund didn't change
IF ENFUND=ENFUNDNW
SET ENAMT=0
QUIT
+39 ; subtract from old fund
SET ENAMT=-ENAMT
End DoDot:4
+40 WRITE ?63,$JUSTIFY($FNUMBER(ENAMT,",",2),16)
+41 SET ENT(ENSN,ENFUND,ENSGL)=$GET(ENT(ENSN,ENFUND,ENSGL))+ENAMT
+42 IF ENFILE=6915.6
IF ENFUND'=ENFUNDNW
Begin DoDot:4
+43 ; show addition to new fund
+44 WRITE !,?44,ENSN,?51,ENFUNDNW,?58,ENSGL
+45 WRITE ?63,$JUSTIFY($FNUMBER(-ENAMT,",",2),16)
+46 SET ENT(ENSN,ENFUNDNW,ENSGL)=$GET(ENT(ENSN,ENFUNDNW,ENSGL))-ENAMT
End DoDot:4
+47 ;
+48 WRITE !,?4,"EQUIP #: ",ENDA,?26,$$GET1^DIQ(6914,ENDA,3)
+49 WRITE !,?4,"P.O. #: ",$PIECE($GET(^ENG(6914,ENDA,2)),U,2)
+50 WRITE ?26,"A.V. REASON: ",$$GET1^DIQ(ENFILE,ENDA("F?"),303)
+51 KILL ^UTILITY($JOB,"W")
SET DIWL=5
SET DIWR=(IOM-5)
SET DIWF="W|"
+52 SET X="COMMENTS: "
SET ENI=0
+53 FOR
SET ENI=$ORDER(^ENG(ENFILE,ENDA("F?"),301,ENI))
if 'ENI
QUIT
SET X=X_^(ENI,0)
DO ^DIWP
SET X=""
IF $Y+6>IOSL
DO HD
if END
QUIT
DO HDAV
+54 if END
QUIT
+55 DO ^DIWW
End DoDot:3
if END
QUIT
End DoDot:2
if END
QUIT
+56 if END
QUIT
+57 IF $Y+10>IOSL
DO HD
if END
QUIT
+58 WRITE !,?30,"TOTALS:"
+59 ; initialize user/grand total
SET ENTU=0
+60 SET ENSN=""
FOR
SET ENSN=$ORDER(ENT(ENSN))
if ENSN=""
QUIT
Begin DoDot:2
+61 ; initialize station totals
SET ENTS="0"
+62 SET ENFUND=""
FOR
SET ENFUND=$ORDER(ENT(ENSN,ENFUND))
if ENFUND=""
QUIT
Begin DoDot:3
+63 ; initialize fund totals
SET ENTF="0"
+64 SET ENSGL=""
+65 FOR
SET ENSGL=$ORDER(ENT(ENSN,ENFUND,ENSGL))
if ENSGL=""
QUIT
Begin DoDot:4
+66 IF $Y+6>IOSL
DO HD
if END
QUIT
WRITE !,?30,"TOTALS: (continued)"
+67 WRITE !,?44,ENSN,?51,ENFUND,?58,ENSGL
+68 WRITE ?63,$JUSTIFY($FNUMBER($PIECE(ENT(ENSN,ENFUND,ENSGL),U),",",2),16)
+69 SET $PIECE(ENTF,U)=$PIECE(ENTF,U)+$PIECE(ENT(ENSN,ENFUND,ENSGL),U)
End DoDot:4
if END
QUIT
+70 if END
QUIT
+71 SET $PIECE(ENTS,U)=$PIECE(ENTS,U)+$PIECE(ENTF,U)
+72 IF $Y+6>IOSL
DO HD
if END
QUIT
WRITE !,?30,"TOTALS: (continued)"
+73 WRITE !,?63,"----------------"
+74 WRITE !,?44,ENSN,?51,ENFUND,?58,"TOTAL",?63,$JUSTIFY($FNUMBER($PIECE(ENTF,U),",",2),16),!
End DoDot:3
if END
QUIT
+75 if END
QUIT
+76 SET $PIECE(ENTU,U)=$PIECE(ENTU,U)+$PIECE(ENTS,U)
+77 IF $Y+6>IOSL
DO HD
if END
QUIT
WRITE !,?30,"TOTALS: (continued)"
+78 WRITE !,?63,"----------------"
+79 WRITE !,?44,ENSN,?50,"TOTAL",?63,$JUSTIFY($FNUMBER($PIECE(ENTS,U),",",2),16),!
End DoDot:2
if END
QUIT
+80 if END
QUIT
+81 IF $Y+6>IOSL
DO HD
if END
QUIT
WRITE !,?30,"TOTALS: (continued)"
+82 WRITE !,?63,"================"
+83 WRITE !,?44,$SELECT(ENSRT("U"):"USER",1:"GRAND")," TOTAL"
+84 WRITE ?63,$JUSTIFY($FNUMBER($PIECE(ENTU,U),",",2),16),!
+85 DO FT
End DoDot:1
if END
QUIT
+86 IF 'END
IF $EXTRACT(IOST,1,2)="C-"
SET DIR(0)="E"
DO ^DIR
KILL DIR
WRAPUP ; wrap up
+1 DO ^%ZISC
+2 IF $DATA(ZTQUEUED)
SET ZTREQ="@"
+3 KILL DIWF,DIWL,DIWR,X,Y
+4 KILL ^TMP($JOB),ENAMT,END,ENDA,ENDT,ENDTE,ENDTR,ENDTS,ENFAPTY,ENFAY3
+5 KILL ENFILE,ENFUND,ENFUNDNW,ENI,ENIEN,ENL,ENPG,ENSGL,ENSN,ENSRT,ENUSR
+6 KILL ENT,ENTS,ENTF,ENTU,ENX,ENY,ENY0,ENY1
+7 QUIT
HD ; page header
+1 IF $DATA(ZTQUEUED)
IF $$S^%ZTLOAD
SET ZTSTOP=1
SET END=1
QUIT
+2 IF $EXTRACT(IOST,1,2)="C-"
IF ENPG
SET DIR(0)="E"
DO ^DIR
KILL DIR
IF 'Y
SET END=1
QUIT
+3 IF $EXTRACT(IOST,1,2)="C-"!ENPG
WRITE @IOF
+4 SET ENPG=ENPG+1
+5 SET $X=0
+6 WRITE "ADJUSTMENT VOUCHERS",?49,ENDTR,?72,"page ",ENPG
+7 WRITE !,?2,"FROM ",$$FMTE^XLFDT(ENDTS,"2")," TO ",$$FMTE^XLFDT(ENDTE,"2")
+8 IF ENSRT("U")
Begin DoDot:1
+9 WRITE " (SORT BY USER FOR ",ENSRT("U",0,"E"),")"
+10 IF ENSRT("U",0)="*"
IF $GET(ENUSR("E"))]""
WRITE !,"A.V.s By: ",ENUSR("E")
End DoDot:1
+11 WRITE !!,"ADJ. VOUCHER",?16,"...... TRANSACTION .......",?44,"STN"
+12 WRITE ?51,"FUND",?58,"SGL",?63,"NET AMOUNT"
+13 WRITE !,"DATE/TIME",?16,"CODE NUMBER DATE"
+14 WRITE !,"--------------",?16,"----- ----------- --------",?44,"-----"
+15 WRITE ?51,"------",?58,"----",?63,"----------------"
+16 QUIT
HDAV ; header for continued adjustment voucher
+1 WRITE !,?4,"Transaction: ",$PIECE(ENY1,U,6),"-",$PIECE(ENY1,U,9),"(continued)"
+2 QUIT
FT ; report footer when hardcopy
+1 if $EXTRACT(IOST,1,2)="C-"!'ENPG
QUIT
+2 WRITE !!!,?4,"-------------------- --------"
+3 WRITE ?44,"-------------------- --------"
+4 WRITE !,?4,"ACCOUNTABLE OFFICER DATE"
+5 WRITE ?44,"APPROVING OFFICIAL DATE"
+6 QUIT
+7 ;ENFARA1
