Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ENFARC1

ENFARC1.m

Go to the documentation of this file. 
  1. ENFARC1 ;WIRMFO/SAB-FIXED ASSET RPT, TRANSACTION REGISTER (CONT); 5.16.97
  1.  ;;7.0;ENGINEERING;**39**;Aug 17, 1993
  1. QEN ; queued entry
  1.  ; in
  1.  ;   ENDTS - start date
  1.  ;   ENDTE - end date
  1.  ;   ENAV  - flag, when true then print adjustment voucher data
  1.  ;
  1.  U IO
  1.  ;
  1. GETDATA ; collect/sort data
  1.  ; loop thru FAP document file transactions within selected date range
  1.  K ^TMP($J) F ENFILE="6915.2","6915.3","6915.4","6915.5","6915.6" D
  1.  . S ENDT=ENDTS
  1.  . F  S ENDT=$O(^ENG(ENFILE,"D",ENDT)) Q:ENDT=""!($P(ENDT,".")>ENDTE)  D
  1.  . . S ENDA("F?")=0
  1.  . . F  S ENDA("F?")=$O(^ENG(ENFILE,"D",ENDT,ENDA("F?"))) Q:'ENDA("F?")  D
  1.  . . . S ^TMP($J,ENDT,ENFILE_";"_ENDA("F?"))=""
  1.  ;
  1. PRINT ; print
  1.  ; load table for converting FA Type to SGL
  1.  K ENFAPTY S ENDA=0 F   S ENDA=$O(^ENG(6914.3,ENDA)) Q:'ENDA  D
  1.  . S ENX=$G(^ENG(6914.3,ENDA,0))
  1.  . I $P(ENX,U,3)]"" S ENFAPTY($P(ENX,U,3))=$P(ENX,U)
  1.  ;
  1.  S (END,ENPG)=0 D NOW^%DTC S Y=% D DD^%DT S ENDTR=Y
  1.  S ENTAG("HD")="HD^ENFARC1",ENTAG("HDC")="HDC^ENFARC1"
  1.  S ENTAG("FT")="FT^ENFARC1"
  1.  S ENL="",$P(ENL,"-",IOM)=""
  1.  D HD
  1.  I '$D(^TMP($J)) W !!,"No activity in selected period",!
  1.  ; loop thru sorted data
  1.  S ENDT="" F  S ENDT=$O(^TMP($J,ENDT)) Q:ENDT=""  D  Q:END
  1.  . S ENFAP="" F  S ENFAP=$O(^TMP($J,ENDT,ENFAP)) Q:ENFAP=""  D  Q:END
  1.  . . S ENFILE=$P(ENFAP,";"),ENDA("F?")=$P(ENFAP,";",2)
  1.  . . S ENY0=$G(^ENG(ENFILE,ENDA("F?"),0))
  1.  . . S ENY1=$G(^ENG(ENFILE,ENDA("F?"),1))
  1.  . . S ENDA("EQ")=$P($G(^ENG(ENFILE,ENDA("F?"),0)),U)
  1.  . . S ENDA("FA")=$$AFA^ENFAR5A(ENFILE,ENDA("F?")) ; associated FA
  1.  . . S ENFAY3=$G(^ENG(6915.2,ENDA("FA"),3))
  1.  . . S ENSN=$TR($E($P(ENFAY3,U,5),1,5)," ","")
  1.  . . S:ENFILE=6915.2 ENFUND=$P(ENFAY3,U,10)
  1.  . . S:ENFILE'=6915.2 ENFUND=$$FUND^ENFAR5A(ENFILE,ENDA("F?"),ENDA("FA"))
  1.  . . S ENSGL=$S($P(ENFAY3,U,6)]"":$G(ENFAPTY($P(ENFAY3,U,6))),1:"")
  1.  . . S ENAMT=0
  1.  . . I ENFILE=6915.2 S ENAMT=$P($G(^ENG(ENFILE,ENDA("F?"),3)),U,27)
  1.  . . I ENFILE=6915.3 S ENAMT=$P($G(^ENG(ENFILE,ENDA("F?"),4)),U,4)
  1.  . . I ENFILE=6915.4 S ENX=$P($G(^ENG(ENFILE,ENDA("F?"),4)),U,6),ENAMT=$S(ENX="":0,1:ENX-$P($G(^ENG(ENFILE,ENDA("F?"),100)),U,4))
  1.  . . I ENFILE=6915.5 S ENAMT="-"_$P($G(^ENG(ENFILE,ENDA("F?"),100)),U,2)
  1.  . . I ENFILE=6915.6 S ENAMT=$P($G(^ENG(ENFILE,ENDA("F?"),100)),U,8)
  1.  . . S:ENFILE=6915.2 ENTRC="FA 00"
  1.  . . S:ENFILE=6915.3 ENTRC="FB "_$$GET1^DIQ(ENFILE,ENDA("F?"),23)
  1.  . . S:ENFILE=6915.4 ENTRC="FC "_$$GET1^DIQ(ENFILE,ENDA("F?"),27)
  1.  . . S:ENFILE=6915.5 ENTRC="FD "_$$GET1^DIQ(ENFILE,ENDA("F?"),100,"I")
  1.  . . S:ENFILE=6915.6 ENTRC="FR"
  1.  . . I $Y+12>IOSL D FT,HD Q:END
  1.  . . W !!,?2,ENTRC,?8,$P(ENY1,U,9)
  1.  . . W ?20,$TR($$FMTE^XLFDT($P(ENY0,U,2),"2DF")," ",0)
  1.  . . W ?30,ENSN,?37,ENFUND,?45,ENSGL
  1.  . . I ENFILE=6915.6 D  ; check FR doc for FUND change
  1.  . . . S ENFUNDNW=$P($G(^ENG(ENFILE,ENDA("F?"),3)),U,9)
  1.  . . . I ENFUND=ENFUNDNW S ENAMT=0 Q  ; fund didn't change
  1.  . . . S ENAMT=-ENAMT ; subtract from old fund
  1.  . . W ?51,$J($FN(ENAMT,",",2),16)
  1.  . . W ?69,$E($P($$GET1^DIQ(ENFILE,ENDA("F?"),1.5),","),1,10)
  1.  . . I ENFILE=6915.6,ENFUND'=ENFUNDNW D
  1.  . . . ; show addition to new fund
  1.  . . . W !,?37,ENFUNDNW,?45,ENSGL
  1.  . . . W ?51,$J($FN(-ENAMT,",",2),16)
  1.  . . ;
  1.  . . W !,?4,"ENTRY #: ",ENDA("EQ")
  1.  . . D @("F"_$P(ENFILE,".",2)_"^ENFARC2")
  1.  . . I 'END,ENAV,$$GET1^DIQ(ENFILE,ENDA("F?"),301)]"" D
  1.  . . . ; print adjustment voucher
  1.  . . . I $Y+6>IOSL D FT,HD Q:END  D HDC
  1.  . . . W !,?4,"AV REASON: ",$E($$GET1^DIQ(ENFILE,ENDA("F?"),303),1,20)
  1.  . . . W ?37,"DATE: ",$P($$GET1^DIQ(ENFILE,ENDA("F?"),301),"@")
  1.  . . . W ?57,"BY: ",$P($$GET1^DIQ(ENFILE,ENDA("F?"),302),",")
  1.  . . . K ^UTILITY($J,"W") S DIWL=5,DIWR=(IOM-5),DIWF="W|"
  1.  . . . S X="AV COMMENTS: ",ENI=0
  1.  . . . F  S ENI=$O(^ENG(ENFILE,ENDA("F?"),301,ENI)) Q:'ENI  S X=X_^(ENI,0) D ^DIWP S X="" I $Y+6>IOSL D FT,HD Q:END  D HDC
  1.  . . . Q:END
  1.  . . . D ^DIWW
  1.  I 'END D FT I $E(IOST,1,2)="C-" S DIR(0)="E" D ^DIR K DIR
  1. WRAPUP ; wrap up
  1.  D ^%ZISC
  1.  I $D(ZTQUEUED) S ZTREQ="@"
  1.  K DIWF,DIWL,DIWR,X,Y
  1.  K ^TMP($J),ENAMT,ENAV,END,ENDA,ENDT,ENDTE,ENDTR,ENDTS,ENFAP,ENFAPTY
  1.  K ENFAY3,ENFILE,ENFUND,ENFUNDNW,ENI,ENL,ENPG,ENSGL,ENSN,ENTAG,ENTRC
  1.  K ENX,ENY,ENY0,ENY1
  1.  Q
  1. HD ; page header
  1.  I $D(ZTQUEUED),$$S^%ZTLOAD S ZTSTOP=1,END=1 Q
  1.  I $E(IOST,1,2)="C-",ENPG S DIR(0)="E" D ^DIR K DIR I 'Y S END=1 Q
  1.  I $E(IOST,1,2)="C-"!ENPG W @IOF
  1.  S ENPG=ENPG+1
  1.  S $X=0
  1.  W "TRANSACTION REGISTER"
  1.  W " FROM ",$$FMTE^XLFDT(ENDTS,"2")," TO ",$$FMTE^XLFDT(ENDTE,"2")
  1.  W ?49,ENDTR,?72,"page ",ENPG
  1.  W !!,?2,"...... TRANSACTION .......",?30,"STN",?37,"FUND"
  1.  W ?45,"SGL",?51,"NET AMOUNT",?69,"SENDER"
  1.  W !,?2,"CODE* NUMBER      DATE"
  1.  W !,?2,"----- ----------- --------",?30,"-----",?37,"------"
  1.  W ?45,"----",?51,"----------------",?69,"----------"
  1.  Q
  1. HDC ; header for continued transaction
  1.  W !,?5,"Transaction: ",$P(ENY1,U,6),"-",$P(ENY1,U,9)," (continued)"
  1.  Q
  1. FT ; footer
  1.  W !!," * Betterment # follows FB and FC. T (Turn-In) or D (Final Disp.) follows FD."
  1.  Q
  1.  ;ENFARC1