Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ENLIB3

ENLIB3.m

Go to the documentation of this file. 
  1. ENLIB3 ;WCIOFO/DH,SAB-Package Utilities (FAP) ;9/2/1998
  1.  ;;7.0;ENGINEERING;**25,33,35,37,39,46,57**;Aug 17,1993
  1. PO ; Populate appropriate equipment data from IFCAP purchase order.
  1.  ; Normally called when PO entered into Equipment File
  1.  ; Input Variables
  1.  ;   X  => PO# 
  1.  ;   DA => Equipment IEN
  1.  N BBFY,FCP,FSC,PO,PODATE
  1.  S PO("E")=X
  1.  ; make sure item has not been reported to FAP
  1.  I $D(^ENG(6915.2,"B",DA)),+$$CHKFA^ENFAUTL(DA) Q  ; active FA Document
  1.  ; find P.O.
  1.  S PO("I")=$$FIND1^DIC(442,"","X",PO("E"),"C^B")
  1.  Q:'PO("I")  ; couldn't find IFCAP P.O.
  1.  ; update Vendor Pointer when null
  1.  I $P($G(^ENG(6914,DA,2)),U)="" D
  1.  . S X=$$GET1^DIQ(442,PO("I"),5,"I")
  1.  . I X]"" S $P(^ENG(6914,DA,2),U)=X
  1.  ; update Acquisition Source when null
  1.  I $P($G(^ENG(6914,DA,2)),U,14)="" D
  1.  . S X=$$GET1^DIQ(442,PO("I"),8,"I")
  1.  . I X]"" S $P(^ENG(6914,DA,2),U,14)=X
  1.  ; update Service Pointer when null
  1.  I $P($G(^ENG(6914,DA,3)),U,2)="" D
  1.  . S X=$$GET1^DIQ(442,PO("I"),5.2,"I")
  1.  . I X]"" S $P(^ENG(6914,DA,3),U,2)=X,^ENG(6914,"AC",X,DA)=""
  1.  ; update Fund Control Point when null
  1.  S FCP=$$GET1^DIQ(442,PO("I"),1)
  1.  I $P($G(^ENG(6914,DA,8)),U,3)="" D
  1.  . I FCP]"" S $P(^ENG(6914,DA,8),U,3)=FCP
  1.  ; update Cost Center when null ***obsolete: now computed from CMR***
  1.  ;I $P($G(^ENG(6914,DA,8)),U,4)="" D
  1.  ;. S X=$$GET1^DIQ(442,PO("I"),2,"I")
  1.  ;. I X]"" S $P(^ENG(6914,DA,8),U,4)=X
  1.  ; check availability of data
  1.  S FSC=$P($$GET1^DIQ(6914,DA,18),"-")
  1.  S PODATE=$$GET1^DIQ(442,PO("I"),.1,"I")
  1.  S BBFY=$$GET1^DIQ(442,PO("I"),26,"I")
  1.  Q:FCP=""!(PODATE="")!(BBFY="")!(FSC'?4N)  ; can't proceed
  1.  ;
  1. FAP N AO,BOC,BOCX,BUDFY,DEPT,DOCFY,ENI,ENX,ENY,EQUITY,FUND,FUNDX
  1.  N IENS,SGL,STATION
  1.  S STATION=$P($$GET1^DIQ(442,PO("I"),.01),"-")
  1.  S DOCFY=$E($E(PODATE,1,3)+$E(PODATE,4),2,3) ; 2 digit document FY
  1.  S BUDFY=$E(BBFY,1,3)+1700 ; 4 digit beginning budget FY
  1.  S DEPT=$E($$GET1^DIQ(6914,DA,19),1,2)
  1.  ; determine BOC
  1.  ;   loop thru item multiple for item matching FSC
  1.  S ENI=0,BOC="",BOCX=""
  1.  F  S ENI=$O(^PRC(442,PO("I"),2,ENI)) Q:'ENI  D  Q:BOC]""
  1.  . S IENS=ENI_","_PO("I")_","
  1.  . Q:$$GET1^DIQ(442.01,IENS,8)'=FSC
  1.  . S BOCX=$E($$GET1^DIQ(442.01,IENS,3.5),1,4)
  1.  . I BOCX]"" S BOC=$$BOCI(BOCX)
  1.  ;   if not found then loop thru BOC multiple for a NX BOC
  1.  I BOC="" S ENI=0 F  S ENI=$O(^PRC(442,PO("I"),22,ENI)) Q:'ENI  D  Q:BOC]""
  1.  . S IENS=ENI_","_PO("I")_","
  1.  . S BOCX=$E($$GET1^DIQ(442.041,IENS,.01),1,4)
  1.  . I BOCX]"" S BOC=$$BOCI(BOCX)
  1.  ; determine SGL
  1.  I $G(BOC)>0 S SGL=$P(^ENG(6914.4,BOC,0),U,3)
  1.  E  S SGL=10 ;Expensed NX
  1.  ; determine AO and FUND
  1.  S X=$$ACC^PRC0C(STATION,FCP_U_DOCFY_U_BUDFY)
  1.  I $P(X,U)]"" S AO=$O(^ENG(6914.7,"B",$P(X,U),0))
  1.  I $P(X,U,5)]"" S FUND="",FUNDX=$P(X,U,5) D
  1.  . ; check for matching Fund table entry
  1.  . S FUND=$$FUNDI(FUNDX) Q:FUND]""
  1.  . ; then how about a Fund table entry that matches the 1st 5 char
  1.  . I $L(FUNDX)>5 S FUND=$$FUNDI($E(FUNDX,1,5)) Q:FUND]""
  1.  . ; then how about a Fund table entry that matches the 1st 4 char
  1.  . I $L(FUNDX)>4 S FUND=$$FUNDI($E(FUNDX,1,4)) Q:FUND]""
  1.  . ; then how about a Fund table entry whose associated fund field
  1.  . ;   matches the 1st four char
  1.  . I $L(FUNDX)>3 S FUND=$$AFUNDI($E(FUNDX,1,4)) Q:FUND]""
  1.  . ; then how about a Fund table entry that starts with the 1st 4 char
  1.  . I $L(FUNDX)>3 S ENX=$E(FUNDX,1,4)_" " F  D  Q:ENX=""!(FUND]"")
  1.  . . S ENX=$O(^ENG(6914.6,"B",ENX)) ; next fund in table
  1.  . . I $E(ENX,1,4)'=$E(FUNDX,1,4) S ENX="" Q  ; can stop looking
  1.  . . S FUND=$$FUNDI(ENX)
  1.  ;
  1.  I $G(FUND)="" D
  1.  . I DEPT="06" S FUND=2 Q  ; CANTEEN
  1.  . I DEPT=56 S FUND=3 Q  ; CWT
  1.  . ;S FUND=1 ; AMAF ; Stopped using AMAF with Patch EN*7*57 (9/98)
  1.  ;
  1.  ;I $G(AO)="" D  ;Disabled at request of FMS (9/96)
  1.  ;. I DEPT>59,DEPT<69 S AO=4 Q
  1.  ;. I DEPT=57!(DEPT=58) S AO=5 Q
  1.  ;. I DEPT=72 S AO=2 Q
  1.  ;. S X=$E(STATION) I X=3 S AO=4 Q
  1.  ;. I "8^9"[X S AO=5 Q
  1.  ;. I "4^5^6"[X S AO=3
  1.  ;
  1.  S EQUITY=$S("^5^12^"[(U_$G(FUND)_U):3402,$G(AO)=3:3299,$G(AO)=4:3210,$G(AO)=5:3210,$G(AO)=7:3210,1:"")
  1.  ;
  1.  S ENY=$G(^ENG(6914,DA,8))
  1.  S:$P(ENY,U,6)="" $P(ENY,U,6)=$G(SGL)
  1.  S ^ENG(6914,DA,8)=ENY
  1.  ;
  1.  S ENY=$G(^ENG(6914,DA,9))
  1.  S:$P(ENY,U,6)="" $P(ENY,U,6)=$G(BOC)
  1.  S:$P(ENY,U,7)="" $P(ENY,U,7)=$G(FUND)
  1.  S:$P(ENY,U,8)="" $P(ENY,U,8)=$G(AO)
  1.  S:$P(ENY,U,9)="" $P(ENY,U,9)=$G(EQUITY)
  1.  S ^ENG(6914,DA,9)=ENY
  1.  Q
  1.  ;
  1. BOCI(ENBOC) ; Returns ien of active BOC or null value
  1.  N ENI,ENDT
  1.  S ENI=$S(ENBOC]"":$O(^ENG(6914.4,"B",ENBOC,0)),1:"")
  1.  ; check if deactivated
  1.  I ENI S ENDT=$P($G(^ENG(6914.4,ENI,0)),U,5) I ENDT]"",ENDT'>DT S ENI=""
  1.  Q ENI
  1.  ;
  1. FUNDI(ENFUND) ; Returns ien of active FUND or null value
  1.  N ENI,ENDT
  1.  S ENI=$S(ENFUND]"":$O(^ENG(6914.6,"B",ENFUND,0)),1:"")
  1.  ; check if deactivated
  1.  I ENI S ENDT=$P($G(^ENG(6914.6,ENI,0)),U,5) I ENDT]"",ENDT'>DT S ENI=""
  1.  Q ENI
  1.  ;
  1. TYPE N A,ENX I '$D(^ENG(6915.2,"B",DA)) Q
  1.  I $D(^ENG(6915.5,"B",DA)) S ENX=$$CHKFA^ENFAUTL(DA) Q:'$P(ENX,U)
  1.  S A(1)="This item has been reported to the Fixed Assets Package. TYPE"
  1.  S A(2)="cannot be changed until an FD document is processed."
  1.  D EN^DDIOL(.A)
  1.  K X
  1.  Q
  1.  ;
  1. CAP N A,ENX I '$D(^ENG(6915.2,"B",DA)) Q
  1.  I $D(^ENG(6915.5,"B",DA)) S ENX=$$CHKFA^ENFAUTL(DA) Q:'$P(ENX,U)
  1.  S A(1)="This item has been reported to the Fixed Assets Package. It cannot"
  1.  S A(2)="be expensed until an FD document is processed."
  1.  D EN^DDIOL(.A)
  1.  K X
  1.  Q
  1.  ;
  1. NX N A,ENX I '$D(^ENG(6915.2,"B",DA)) Q
  1.  I $D(^ENG(6915.5,"B",DA)) S ENX=$$CHKFA^ENFAUTL(DA) I '$P(ENX,U) Q
  1.  S A(1)="Since this item has been reported to FAP, this field may be edited"
  1.  S A(2)="only by means of an FAP document."
  1.  D EN^DDIOL(.A)
  1.  K X
  1.  Q
  1.  ;
  1. DTCHK(ENFLD) ;Input Transform Check that TURN-IN DATE, REPLACEMENT DATE, and
  1.  ; DISPOSITION DATE follow ACQUISITION DATE.
  1.  ;     DA => Equipment Entry Number
  1.  ;     ENFLD => Field being checked (16, 20.5, or 22)
  1.  ;     X => value entered (internal format) - killed if check fails
  1.  I X'>$P($G(^ENG(6914,DA,2)),U,4) D  K X ; failed check
  1.  . N ENLBL
  1.  . S ENLBL=$$GET1^DID(6914,ENFLD,"","LABEL")
  1.  . D EN^DDIOL(ENLBL_" must follow ACQUISITION DATE")
  1.  Q
  1.  ;
  1. DISPM ;  Expand DISPOSITION METHOD on DJ screens ENEQ2*
  1.  ;    Expects value (1U) in loc var V(V)
  1.  ;    Returns expanded value in V(V)
  1.  ;    Called by PRE-ACTION field of DJ Screen File
  1.  ;
  1.  Q:$G(V(V))'?1U  N X
  1.  S X=$O(^ENG(6914.8,"B",V(V),0)) I X>0,$D(^ENG(6914.8,X,0)) S V(V)=V(V)_"  "_$E($P(^(0),U,2),1,25)
  1.  Q
  1.  ;
  1. DISPW ;  Prohibit direct edit of DISPOSITION METHOD for capitalized assets
  1.  ;
  1.  W !,"Capitalized asset. DISP METHOD may be edited only by means of FAP documents."
  1.  W !,"Press <RETURN> to continue..." R X:DTIME
  1.  Q
  1.  ;
  1. AFUNDI(ENFUND) ; Returns ien of active FUND or null value
  1.  ; input - associated fund
  1.  N ENI,ENJ,ENDT
  1.  S ENI=""
  1.  ; loop thru associated fund x-ref looking for active entry that matches
  1.  S ENJ=0
  1.  I ENFUND]"" F  S ENJ=$O(^ENG(6914.6,"E",ENFUND,ENJ)) Q:'ENJ!(ENI]"")  D
  1.  . ; check if deactivated
  1.  . S ENDT=$P($G(^ENG(6914.6,ENJ,0)),U,5) I ENDT]"",ENDT'>DT Q
  1.  . S ENI=ENJ ; found active fund entry for associated fund value
  1.  Q ENI
  1.  ;
  1.  ;ENLIB3