ENTIUTL ;WOIFO/SAB - Engineering Utilities ;2/14/2008
;;7.0;ENGINEERING;**87,89**;Aug 17, 1993;Build 20
;
DISEQ(ENDA) ; Display Equipment
N ENCMR,ENLOC,ENMFGR,ENMOD,ENNAM,ENSER,ENSVC
; display equipment data
S ENCMR=$$GET1^DIQ(6914,ENDA,19)
S ENLOC=$$GET1^DIQ(6914,ENDA,24)
S ENSVC=$$GET1^DIQ(6914,ENDA,21)
S ENNAM=$$GET1^DIQ(6914,ENDA,3)
S ENMFGR=$$GET1^DIQ(6914,ENDA,1)
S ENMOD=$$GET1^DIQ(6914,ENDA,4)
S ENSER=$$GET1^DIQ(6914,ENDA,5)
W !,"Entry #",?12,"CMR",?19,"Location",?41,"Using Service"
W !,"---------",?12,"-----",?19,"--------------------"
W ?41,"------------------------------"
W !,ENDA,?12,ENCMR,?19,ENLOC,?41,ENSVC
W !,ENNAM
W !!,"Mfgr: ",ENMFGR
W !,"Model: ",ENMOD,?39,"Serial #: ",ENSER
Q
;
CAPEQ(ENDA,ENTAG,SITC,END) ; Captioned Equipment Display
; input
; ENDA = equipment ien (file 6914)
; ENTAG = (optional) line tag to call at page break
; this utility expects there to be at least 5 lines to display
; the normal data and will only issue page breaks during the
; IT REMOTE LOCATION or IT COMMENTS output.
; SITC = (optional) flag, true to suppress IT comments from printing
; output
; END = true if user enter "^" or timed-out, passed by reference
N ENCMR,ENI,ENITRL,ENLOC,ENLOCS,ENMFGR,ENMOD,ENNAM,ENSER,ENSVC,X
S ENTAG=$G(ENTAG,"CAPEQHD^ENTIUTL")
S END=$G(END)
; display equipment data
S ENCMR=$$GET1^DIQ(6914,ENDA,19)
S ENLOC=$$GET1^DIQ(6914,ENDA,24)
S ENLOCS=$$GET1^DIQ(6914,ENDA,"24:1.5")
S ENSVC=$$GET1^DIQ(6914,ENDA,21)
S ENNAM=$$GET1^DIQ(6914,ENDA,3)
S ENMFGR=$$GET1^DIQ(6914,ENDA,1)
S ENMOD=$$GET1^DIQ(6914,ENDA,4)
S ENSER=$$GET1^DIQ(6914,ENDA,5)
W !,"Entry #: ",ENDA,?21,"CMR: ",ENCMR,?33,"Using Service: ",ENSVC
W !,?2,"Location: ",ENLOC,?34,"Svc of Location: ",ENLOCS
W !,?2,"Mfgr Name: ",$E(ENNAM,1,65) W:$E(ENNAM,66,80)]"" "*"
W !,?2,"Mfgr: ",ENMFGR
W !,?2,"Model: ",ENMOD,?41,"Ser. #: ",ENSER
S ENITRL=$$GET1^DIQ(6914,ENDA,91)
I ENITRL]"" D Q:END
. I $Y+3>IOSL D @ENTAG Q:END D CAPEQHD1
. N DIWF,DIWL,DIWR,X
. K ^UTILITY($J,"W")
. S DIWL=3,DIWR=79,DIWF="W|"
. S X="IT Remote Location: " D ^DIWP
. S X=ENITRL D ^DIWP
. D ^DIWW
I '$G(SITC),$O(^ENG(6914,ENDA,"ITC",0)) D
. N DIWF,DIWL,DIWR,X
. K ^UTILITY($J,"W")
. S DIWL=3,DIWR=79,DIWF="W|"
. S X="IT Comments: " D ^DIWP
. S ENI=0 F S ENI=$O(^ENG(6914,ENDA,"ITC",ENI)) Q:'ENI D Q:END
. . I $Y+3>IOSL D @ENTAG Q:END D CAPEQHD1
. . S X=$G(^ENG(6914,ENDA,"ITC",ENI,0)) D ^DIWP
. I END K ^UTILITY($J,"W") Q
. I $Y+3>IOSL D @ENTAG I END K ^UTILITY($J,"W") Q
. D ^DIWW
Q
;
CAPEQHD ; Captioned Equipment Display Default Header
I $E(IOST,1,2)="C-" S DIR(0)="E" D ^DIR K DIR I 'Y S END=1 Q
W @IOF
Q
CAPEQHD1 ; Captioned Equipment Display Second Header
W "Equipment Entry #: ",ENDA," (continued)"
Q
;
DISASGN(ENDA) ; Display Active Assignments for Equipment to Screen
N DIR,DIROUT,DIRUT,DTOUT,DUOUT,ENADA,END,ENSTAT,X,Y
; display assignment data
S END=0
D DISASGNH
I '$D(^ENG(6916.3,"AEA",ENDA)) W !," no active assignments" Q
S ENADA=0
F S ENADA=$O(^ENG(6916.3,"AEA",ENDA,ENADA)) Q:'ENADA D Q:END
. I $Y+4>IOSL D Q:END
. . S DIR(0)="E" D ^DIR K DIR I 'Y S END=1 Q
. . W @(IOF) D DISASGNH W !," Entry #: ",ENDA," (continued)"
. W !,$$GET1^DIQ(6916.3,ENADA,1)
. W ?32,$P($$GET1^DIQ(6916.3,ENADA,2),"@")
. S ENSTAT=$$GET1^DIQ(6916.3,ENADA,20)
. W ?46,ENSTAT
. I ENSTAT'="ASSIGNED" W ?57,$$GET1^DIQ(6916.3,ENADA,21)
Q
DISASGNH ; Display Assignments Header
W !!,"Responsible Person",?32,"Assigned DT",?46,"Status",?57,"Status DT"
W !,"------------------------------",?32,"------------"
W ?46,"---------",?57,"------------"
Q
;
BLDHL2(ENSM,ENSMV,ENSRT) ; Build Header Line 2 String for Reports
; input
; ENSM = equipment selection method code
; ENSMV = selection method ien value (for applicable methods)
; ENSRT = sort by code
; returns string for page header second line
N ENHL2
;
S ENHL2=" for "
S:ENSM="A" ENHL2=ENHL2_"All tracked IT equipment"
S:ENSM="E" ENHL2=ENHL2_"selected equipment"
S:ENSM="C" ENHL2=ENHL2_"CMR: "_$$GET1^DIQ(6914.1,ENSMV,.01)
S:ENSM="U" ENHL2=ENHL2_"Using Service: "_$$GET1^DIQ(49,ENSMV,.01)
S:ENSM="L" ENHL2=ENHL2_"Location: "_$$GET1^DIQ(6928,ENSMV,.01)
S:ENSM="S" ENHL2=ENHL2_"Service of Loc: "_$$GET1^DIQ(49,ENSMV,.01)
S ENHL2=ENHL2_" sorted by "
S:ENSRT="E" ENHL2=ENHL2_"Entry #"
S:ENSRT="C" ENHL2=ENHL2_"CMR"
S:ENSRT="U" ENHL2=ENHL2_"Using Service"
S:ENSRT="L" ENHL2=ENHL2_"Location"
S:ENSRT="S" ENHL2=ENHL2_"Service of Loc."
;
Q ENHL2
;
ADDNP ; Add New Person
; called by option ENIT ADD NEW PERSON
N DIR,DIROUT,DIRUT,DTOUT,DUOUT,ENX,X,Y
W !!,"This option should only be used to add a person to the NEW PERSON"
W !,"(#200) file when that person will be assigned responsibility for"
W !,"IT equipment but is not already in the file and will NOT be given"
W !,"a user account to sign on the computer.",!
;
S DIR(0)="Y"
S DIR("A")="Do you want to add an entry to the NEW PERSON file"
S DIR("B")="NO"
D ^DIR K DIR Q:$D(DIRUT)
;
I Y W ! S ENX=$$ADD^XUSERNEW()
I $P($G(ENX),U)>0,'$P(ENX,U,3) D
. W !!,$P(ENX,U,2)," already exists with internal number ",$P(ENX,U),"."
. W !,"If you want to enter a new record with that name, enter the"
. W !,"name within quotes (e.g. ""Last,First"")",!
Q
;
USRTRM ;Send MailMan message when user with active assignments is terminated
Q:'$D(^ENG(6916.3,"AOA",XUIFN))
N ENDA,ENERR,ENI,ENL,ENMFGNM,ENNAME,ENSPACE,ENTX,ENNBR,ENSTATUS,ENDATE,ENX,XMDUZ,XMMG,XMROU,XMSTRIP,XMSUB,XMTEXT,XMY,XMYBLOB,XMZ
K ^TMP($J,"ENITUTL") S ENDA=XUIFN,$P(ENSPACE," ",41)=""
D FIND^DIC(6916.3,"","@;.01;1;20;21","PQX",ENDA,"","AOA2","","","^TMP($J,""ENITUTL"")","ENERR")
I $P($G(^TMP($J,"ENITUTL","DILIST",0)),U)'>0 K ^TMP($J,"ENITUTL") Q
S ENNAME=$$GET1^DIQ(200,ENDA_",",".01","","","ENERR")
S ENTX(1)="Owner: "_ENNAME_" ("_ENDA_")"
S ENTX(2)="was terminated while having the following active IT responsibility assignments:"
S ENTX(3)=" ",ENTX(4)="Entry#"_$E(ENSPACE,1,6)_"Mfg Equip Name"_$E(ENSPACE,1,11)_"Assignment Status"_$E(ENSPACE,1,3)_"Status Date",ENL=4
S ENI=0
F S ENI=$O(^TMP($J,"ENITUTL","DILIST",ENI)) Q:+ENI'=ENI D
. S ENX=$G(^TMP($J,"ENITUTL","DILIST",ENI,0)) Q:ENX=""
. S ENNBR=$P(ENX,U,2),ENSTATUS=$P(ENX,U,4),ENDATE=$P(ENX,U,5)
. S ENMFGNM=$E($$GET1^DIQ(6914,ENNBR_",","3","","","ENERR"),1,20)
. S ENL=ENL+1,ENTX(ENL)=ENNBR_$E(ENSPACE,$L(ENNBR)+1,12)_ENMFGNM_$E(ENSPACE,$L(ENMFGNM)+1,25)_ENSTATUS_$E(ENSPACE,$L(ENSTATUS)+1,20)_ENDATE
S ENL=ENL+1,ENTX(ENL)=" ",ENL=ENL+1,ENTX(ENL)=" Number of Items= "_($P($G(^TMP($J,"ENITUTL","DILIST",0)),U)+0)
S ENL=ENL+1,ENTX(ENL)=" ",ENL=ENL+1,ENTX(ENL)="These IT assignments are still active for "_ENNAME_".",ENL=ENL+1,ENTX(ENL)="If appropriate, use the transfer or terminate option to make changes."
S XMDUZ="AEMS/MERS",XMSUB="Assigned Equipment of Terminated Owner: "_ENNAME
S XMY("G.EN IT EQUIPMENT")="",XMTEXT="ENTX("
D ^XMD
K ^TMP($J,"ENITUTL")
Q
;
;ENITUTL
--- Routine Detail --- with STRUCTURED ROUTINE LISTING ---[H[J[2J[HENTIUTL 7109 printed Oct 16, 2024@17:56:50 Page 2
ENTIUTL ;WOIFO/SAB - Engineering Utilities ;2/14/2008
+1 ;;7.0;ENGINEERING;**87,89**;Aug 17, 1993;Build 20
+2 ;
DISEQ(ENDA) ; Display Equipment
+1 NEW ENCMR,ENLOC,ENMFGR,ENMOD,ENNAM,ENSER,ENSVC
+2 ; display equipment data
+3 SET ENCMR=$$GET1^DIQ(6914,ENDA,19)
+4 SET ENLOC=$$GET1^DIQ(6914,ENDA,24)
+5 SET ENSVC=$$GET1^DIQ(6914,ENDA,21)
+6 SET ENNAM=$$GET1^DIQ(6914,ENDA,3)
+7 SET ENMFGR=$$GET1^DIQ(6914,ENDA,1)
+8 SET ENMOD=$$GET1^DIQ(6914,ENDA,4)
+9 SET ENSER=$$GET1^DIQ(6914,ENDA,5)
+10 WRITE !,"Entry #",?12,"CMR",?19,"Location",?41,"Using Service"
+11 WRITE !,"---------",?12,"-----",?19,"--------------------"
+12 WRITE ?41,"------------------------------"
+13 WRITE !,ENDA,?12,ENCMR,?19,ENLOC,?41,ENSVC
+14 WRITE !,ENNAM
+15 WRITE !!,"Mfgr: ",ENMFGR
+16 WRITE !,"Model: ",ENMOD,?39,"Serial #: ",ENSER
+17 QUIT
+18 ;
CAPEQ(ENDA,ENTAG,SITC,END) ; Captioned Equipment Display
+1 ; input
+2 ; ENDA = equipment ien (file 6914)
+3 ; ENTAG = (optional) line tag to call at page break
+4 ; this utility expects there to be at least 5 lines to display
+5 ; the normal data and will only issue page breaks during the
+6 ; IT REMOTE LOCATION or IT COMMENTS output.
+7 ; SITC = (optional) flag, true to suppress IT comments from printing
+8 ; output
+9 ; END = true if user enter "^" or timed-out, passed by reference
+10 NEW ENCMR,ENI,ENITRL,ENLOC,ENLOCS,ENMFGR,ENMOD,ENNAM,ENSER,ENSVC,X
+11 SET ENTAG=$GET(ENTAG,"CAPEQHD^ENTIUTL")
+12 SET END=$GET(END)
+13 ; display equipment data
+14 SET ENCMR=$$GET1^DIQ(6914,ENDA,19)
+15 SET ENLOC=$$GET1^DIQ(6914,ENDA,24)
+16 SET ENLOCS=$$GET1^DIQ(6914,ENDA,"24:1.5")
+17 SET ENSVC=$$GET1^DIQ(6914,ENDA,21)
+18 SET ENNAM=$$GET1^DIQ(6914,ENDA,3)
+19 SET ENMFGR=$$GET1^DIQ(6914,ENDA,1)
+20 SET ENMOD=$$GET1^DIQ(6914,ENDA,4)
+21 SET ENSER=$$GET1^DIQ(6914,ENDA,5)
+22 WRITE !,"Entry #: ",ENDA,?21,"CMR: ",ENCMR,?33,"Using Service: ",ENSVC
+23 WRITE !,?2,"Location: ",ENLOC,?34,"Svc of Location: ",ENLOCS
+24 WRITE !,?2,"Mfgr Name: ",$EXTRACT(ENNAM,1,65)
if $EXTRACT(ENNAM,66,80)]""
WRITE "*"
+25 WRITE !,?2,"Mfgr: ",ENMFGR
+26 WRITE !,?2,"Model: ",ENMOD,?41,"Ser. #: ",ENSER
+27 SET ENITRL=$$GET1^DIQ(6914,ENDA,91)
+28 IF ENITRL]""
Begin DoDot:1
+29 IF $Y+3>IOSL
DO @ENTAG
if END
QUIT
DO CAPEQHD1
+30 NEW DIWF,DIWL,DIWR,X
+31 KILL ^UTILITY($JOB,"W")
+32 SET DIWL=3
SET DIWR=79
SET DIWF="W|"
+33 SET X="IT Remote Location: "
DO ^DIWP
+34 SET X=ENITRL
DO ^DIWP
+35 DO ^DIWW
End DoDot:1
if END
QUIT
+36 IF '$GET(SITC)
IF $ORDER(^ENG(6914,ENDA,"ITC",0))
Begin DoDot:1
+37 NEW DIWF,DIWL,DIWR,X
+38 KILL ^UTILITY($JOB,"W")
+39 SET DIWL=3
SET DIWR=79
SET DIWF="W|"
+40 SET X="IT Comments: "
DO ^DIWP
+41 SET ENI=0
FOR
SET ENI=$ORDER(^ENG(6914,ENDA,"ITC",ENI))
if 'ENI
QUIT
Begin DoDot:2
+42 IF $Y+3>IOSL
DO @ENTAG
if END
QUIT
DO CAPEQHD1
+43 SET X=$GET(^ENG(6914,ENDA,"ITC",ENI,0))
DO ^DIWP
End DoDot:2
if END
QUIT
+44 IF END
KILL ^UTILITY($JOB,"W")
QUIT
+45 IF $Y+3>IOSL
DO @ENTAG
IF END
KILL ^UTILITY($JOB,"W")
QUIT
+46 DO ^DIWW
End DoDot:1
+47 QUIT
+48 ;
CAPEQHD ; Captioned Equipment Display Default Header
+1 IF $EXTRACT(IOST,1,2)="C-"
SET DIR(0)="E"
DO ^DIR
KILL DIR
IF 'Y
SET END=1
QUIT
+2 WRITE @IOF
+3 QUIT
CAPEQHD1 ; Captioned Equipment Display Second Header
+1 WRITE "Equipment Entry #: ",ENDA," (continued)"
+2 QUIT
+3 ;
DISASGN(ENDA) ; Display Active Assignments for Equipment to Screen
+1 NEW DIR,DIROUT,DIRUT,DTOUT,DUOUT,ENADA,END,ENSTAT,X,Y
+2 ; display assignment data
+3 SET END=0
+4 DO DISASGNH
+5 IF '$DATA(^ENG(6916.3,"AEA",ENDA))
WRITE !," no active assignments"
QUIT
+6 SET ENADA=0
+7 FOR
SET ENADA=$ORDER(^ENG(6916.3,"AEA",ENDA,ENADA))
if 'ENADA
QUIT
Begin DoDot:1
+8 IF $Y+4>IOSL
Begin DoDot:2
+9 SET DIR(0)="E"
DO ^DIR
KILL DIR
IF 'Y
SET END=1
QUIT
+10 WRITE @(IOF)
DO DISASGNH
WRITE !," Entry #: ",ENDA," (continued)"
End DoDot:2
if END
QUIT
+11 WRITE !,$$GET1^DIQ(6916.3,ENADA,1)
+12 WRITE ?32,$PIECE($$GET1^DIQ(6916.3,ENADA,2),"@")
+13 SET ENSTAT=$$GET1^DIQ(6916.3,ENADA,20)
+14 WRITE ?46,ENSTAT
+15 IF ENSTAT'="ASSIGNED"
WRITE ?57,$$GET1^DIQ(6916.3,ENADA,21)
End DoDot:1
if END
QUIT
+16 QUIT
DISASGNH ; Display Assignments Header
+1 WRITE !!,"Responsible Person",?32,"Assigned DT",?46,"Status",?57,"Status DT"
+2 WRITE !,"------------------------------",?32,"------------"
+3 WRITE ?46,"---------",?57,"------------"
+4 QUIT
+5 ;
BLDHL2(ENSM,ENSMV,ENSRT) ; Build Header Line 2 String for Reports
+1 ; input
+2 ; ENSM = equipment selection method code
+3 ; ENSMV = selection method ien value (for applicable methods)
+4 ; ENSRT = sort by code
+5 ; returns string for page header second line
+6 NEW ENHL2
+7 ;
+8 SET ENHL2=" for "
+9 if ENSM="A"
SET ENHL2=ENHL2_"All tracked IT equipment"
+10 if ENSM="E"
SET ENHL2=ENHL2_"selected equipment"
+11 if ENSM="C"
SET ENHL2=ENHL2_"CMR: "_$$GET1^DIQ(6914.1,ENSMV,.01)
+12 if ENSM="U"
SET ENHL2=ENHL2_"Using Service: "_$$GET1^DIQ(49,ENSMV,.01)
+13 if ENSM="L"
SET ENHL2=ENHL2_"Location: "_$$GET1^DIQ(6928,ENSMV,.01)
+14 if ENSM="S"
SET ENHL2=ENHL2_"Service of Loc: "_$$GET1^DIQ(49,ENSMV,.01)
+15 SET ENHL2=ENHL2_" sorted by "
+16 if ENSRT="E"
SET ENHL2=ENHL2_"Entry #"
+17 if ENSRT="C"
SET ENHL2=ENHL2_"CMR"
+18 if ENSRT="U"
SET ENHL2=ENHL2_"Using Service"
+19 if ENSRT="L"
SET ENHL2=ENHL2_"Location"
+20 if ENSRT="S"
SET ENHL2=ENHL2_"Service of Loc."
+21 ;
+22 QUIT ENHL2
+23 ;
ADDNP ; Add New Person
+1 ; called by option ENIT ADD NEW PERSON
+2 NEW DIR,DIROUT,DIRUT,DTOUT,DUOUT,ENX,X,Y
+3 WRITE !!,"This option should only be used to add a person to the NEW PERSON"
+4 WRITE !,"(#200) file when that person will be assigned responsibility for"
+5 WRITE !,"IT equipment but is not already in the file and will NOT be given"
+6 WRITE !,"a user account to sign on the computer.",!
+7 ;
+8 SET DIR(0)="Y"
+9 SET DIR("A")="Do you want to add an entry to the NEW PERSON file"
+10 SET DIR("B")="NO"
+11 DO ^DIR
KILL DIR
if $DATA(DIRUT)
QUIT
+12 ;
+13 IF Y
WRITE !
SET ENX=$$ADD^XUSERNEW()
+14 IF $PIECE($GET(ENX),U)>0
IF '$PIECE(ENX,U,3)
Begin DoDot:1
+15 WRITE !!,$PIECE(ENX,U,2)," already exists with internal number ",$PIECE(ENX,U),"."
+16 WRITE !,"If you want to enter a new record with that name, enter the"
+17 WRITE !,"name within quotes (e.g. ""Last,First"")",!
End DoDot:1
+18 QUIT
+19 ;
USRTRM ;Send MailMan message when user with active assignments is terminated
+1 if '$DATA(^ENG(6916.3,"AOA",XUIFN))
QUIT
+2 NEW ENDA,ENERR,ENI,ENL,ENMFGNM,ENNAME,ENSPACE,ENTX,ENNBR,ENSTATUS,ENDATE,ENX,XMDUZ,XMMG,XMROU,XMSTRIP,XMSUB,XMTEXT,XMY,XMYBLOB,XMZ
+3 KILL ^TMP($JOB,"ENITUTL")
SET ENDA=XUIFN
SET $PIECE(ENSPACE," ",41)=""
+4 DO FIND^DIC(6916.3,"","@;.01;1;20;21","PQX",ENDA,"","AOA2","","","^TMP($J,""ENITUTL"")","ENERR")
+5 IF $PIECE($GET(^TMP($JOB,"ENITUTL","DILIST",0)),U)'>0
KILL ^TMP($JOB,"ENITUTL")
QUIT
+6 SET ENNAME=$$GET1^DIQ(200,ENDA_",",".01","","","ENERR")
+7 SET ENTX(1)="Owner: "_ENNAME_" ("_ENDA_")"
+8 SET ENTX(2)="was terminated while having the following active IT responsibility assignments:"
+9 SET ENTX(3)=" "
SET ENTX(4)="Entry#"_$EXTRACT(ENSPACE,1,6)_"Mfg Equip Name"_$EXTRACT(ENSPACE,1,11)_"Assignment Status"_$EXTRACT(ENSPACE,1,3)_"Status Date"
SET ENL=4
+10 SET ENI=0
+11 FOR
SET ENI=$ORDER(^TMP($JOB,"ENITUTL","DILIST",ENI))
if +ENI'=ENI
QUIT
Begin DoDot:1
+12 SET ENX=$GET(^TMP($JOB,"ENITUTL","DILIST",ENI,0))
if ENX=""
QUIT
+13 SET ENNBR=$PIECE(ENX,U,2)
SET ENSTATUS=$PIECE(ENX,U,4)
SET ENDATE=$PIECE(ENX,U,5)
+14 SET ENMFGNM=$EXTRACT($$GET1^DIQ(6914,ENNBR_",","3","","","ENERR"),1,20)
+15 SET ENL=ENL+1
SET ENTX(ENL)=ENNBR_$EXTRACT(ENSPACE,$LENGTH(ENNBR)+1,12)_ENMFGNM_$EXTRACT(ENSPACE,$LENGTH(ENMFGNM)+1,25)_ENSTATUS_$EXTRACT(ENSPACE,$LENGTH(ENSTATUS)+1,20)_ENDATE
End DoDot:1
+16 SET ENL=ENL+1
SET ENTX(ENL)=" "
SET ENL=ENL+1
SET ENTX(ENL)=" Number of Items= "_($PIECE($GET(^TMP($JOB,"ENITUTL","DILIST",0)),U)+0)
+17 SET ENL=ENL+1
SET ENTX(ENL)=" "
SET ENL=ENL+1
SET ENTX(ENL)="These IT assignments are still active for "_ENNAME_"."
SET ENL=ENL+1
SET ENTX(ENL)="If appropriate, use the transfer or terminate option to make changes."
+18 SET XMDUZ="AEMS/MERS"
SET XMSUB="Assigned Equipment of Terminated Owner: "_ENNAME
+19 SET XMY("G.EN IT EQUIPMENT")=""
SET XMTEXT="ENTX("
+20 DO ^XMD
+21 KILL ^TMP($JOB,"ENITUTL")
+22 QUIT
+23 ;
+24 ;ENITUTL
