Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ENWO1

ENWO1.m

Go to the documentation of this file. 
  1. ENWO1 ;WCIOFO/DLM/DH/SAB-Process Work Order ;1/2/2001
  1.  ;;7.0;ENGINEERING;**35,51,59,67**;Aug 17, 1993
  1. ENT ;Edit work orders
  1.  D WO^ENWOUTL S DA=+Y G:DA'>0 EXIT L +^ENG(6920,DA):5 I '$T W !!,"This work order is being edited by another user.  Please try again later.",*7,! G ENT
  1.  I $D(^ENG(6920,DA,5)),$P(^(5),U,2)]"" D
  1.  . W !,*7,"NOTE: This work order has already been closed out."
  1.  . I '$D(^XUSEC("ENEDCLWO",DUZ)) W !,"Security key ENEDCLWO is needed to edit closed work orders." L -^ENG(6920,DA) S DA="" Q
  1.  . S DIR(0)="Y",DIR("A")="Are you sure you want to edit this work order",DIR("B")="NO"
  1.  . D ^DIR K DIR I Y'>0 L -^ENG(6920,DA) S DA="" Q
  1.  . I $P($G(^ENG(6920,DA,3)),U,8)>0 D KILLHS^ENEQHS I $G(R)="^" S DA="" Q
  1.  . S ENWOCLOD=$P(^ENG(6920,DA,5),U,2)
  1.  . S $P(^ENG(6920,DA,5),U,2)="",$P(^ENG(6920,DA,4),U,3)=""
  1.  . D TEST^ENWOCOMP
  1.  . ; if PM work order then back out PM hours
  1.  . I $E($P($G(^ENG(6920,DA,0)),U),1,3)="PM-" D
  1.  . . N ENPMDT,PMTOT,X
  1.  . . D PMHRS^ENEQPMR4 Q:'$D(PMTOT)
  1.  . . S X=$P($P(^ENG(6920,DA,0),U),"-",2)
  1.  . . F I=1:1:$L(X) S:$E(X,I)?1N ENPMDT=$G(ENPMDT)_$E(X,I)
  1.  . . S ENPMDT=$E(ENPMDT,1,4)
  1.  . . D UNPOST^ENBCPM8
  1.  G:DA="" ENT
  1.  S DIE="^ENG(6920,",DR=$S($D(^DIE("B","ENZWOEDIT")):"[ENZWOEDIT]",1:"[ENWOEDIT]")
  1.  S ENDA=DA
  1.  D ^DIE
  1.  ; if PM work order closed then post PM hours
  1.  I $G(DA),$E($P($G(^ENG(6920,DA,0)),U),1,3)="PM-",$P($G(^(5)),U,2)]"" D
  1.  . N ENPMDT,PMTOT,X
  1.  . D PMHRS^ENEQPMR4 Q:'$D(PMTOT)
  1.  . S X=$P($P(^ENG(6920,DA,0),U),"-",2)
  1.  . F I=1:1:$L(X) S:$E(X,I)?1N ENPMDT=$G(ENPMDT)_$E(X,I)
  1.  . S ENPMDT=$E(ENPMDT,1,4)
  1.  . D COUNT^ENBCPM8
  1.  L -^ENG(6920,ENDA) K ENDA
  1.  G ENT
  1.  ;
  1. CLSOUT ;Close work order
  1.  D WO^ENWOUTL S DA=+Y I DA'>0 G EXIT
  1.  I $E(^ENG(6920,DA,0),1,3)="Y2-" W !,*7,"Please use the Y2K Equipment Management Module to close Y2K work orders." G CLSOUT
  1.  L +^ENG(6920,DA):5 I '$T W !!,"This work order is being edited by another user.  Please try again later.",*7 G CLSOUT
  1.  I $D(^ENG(6920,DA,5)),$P(^(5),U,2)]"" D
  1.  . W !,*7,"NOTE: This work order has already been closed out."
  1.  . I $D(^XUSEC("ENEDCLWO",DUZ)) W !,"You may use the work order EDIT or DISPLAY option to edit this work order."
  1.  . L -^ENG(6920,DA) S DA=""
  1.  I DA="" G CLSOUT
  1.  S DIE="^ENG(6920,",DR=""
  1.  ; select template
  1.  D
  1.  . I $E(^ENG(6920,DA,0),1,3)="PM-" S DR=$S($D(^DIE("B","ENZPMCLOSE")):"[ENZPMCLOSE]",1:"[ENPMCLOSE]") Q
  1.  . S X=$P($G(^ENG(6920,DA,2)),U)
  1.  . I X>0,$P($G(^DIC(6922,X,0)),U,5) S DR=$S($D(^DIE("B","ENZWOBIOCLSE")):"[ENZWOBIOCLSE]",1:"[ENWOBIOCLSE]") Q
  1.  . S DR=$S($D(^DIE("B","ENZWOCLOSE")):"[ENZWOCLOSE]",1:"[ENWOCLOSE]")
  1.  S ENDA=DA
  1.  D ^DIE
  1.  ; if PM work order closed then post PM hours, update equip file
  1.  I $D(DA),$E($P($G(^ENG(6920,DA,0)),U),1,3)="PM-",$P($G(^(5)),U,2)]"" D
  1.  . N ENPMDT,PMTOT,X
  1.  . D PMHRS^ENEQPMR4,PMINV^ENEQPMR4
  1.  . Q:'$D(PMTOT)
  1.  . S X=$P($P(^ENG(6920,DA,0),U),"-",2)
  1.  . F I=1:1:$L(X) S:$E(X,I)?1N ENPMDT=$G(ENPMDT)_$E(X,I)
  1.  . S ENPMDT=$E(ENPMDT,1,4)
  1.  . D COUNT^ENBCPM8
  1.  L -^ENG(6920,ENDA) K ENDA
  1.  W !!
  1.  G CLSOUT
  1.  ;
  1. EQHIV ;EQUIPMENT HIST
  1.  Q  ;Obsolete entry point
  1.  ;
  1. EQHI ;  Equipment work order history, by entry number
  1.  S DIC("S")="I $D(^(3))" D GETEQ^ENUTL G:Y'>0 EXIT S ENDA=+Y
  1.  D NOW^%DTC S ENSTMPL="ENWOHIST"_%
  1.  W !,"Compiling SORT TEMPLATE ["_ENSTMPL_"]",!
  1.  K DD,DO S DIC="^DIBT(",DIC(0)="X",X=ENSTMPL D FILE^DICN S DA=+Y
  1.  I DA'>0 W !,"Process ABORTED.",*7 G EXIT
  1.  S ENSTMPL(0)=DA
  1.  S DIE="^DIBT(",DR="2///^S X=DT;4///^S X=6920;5///^S X=DUZ;15///^S X=""EQUIPMENT ID# EQUALS ""_ENDA" D ^DIE
  1.  F I=0:0 S I=$O(^ENG(6920,"G",ENDA,I)) Q:I'>0  S ^DIBT(DA,1,I)="" W "."
  1.  I '$D(^DIBT(DA,1)) W !!,"No work orders found.  Nothing to report.",*7,! S DIK="^DIBT(" D ^DIK K DIK G EQHI
  1.  S DIC="^ENG(6914,",DA=ENDA,DIQ="ENEQ",DIQ(0)="E",DR=".01;1;4;5;53"
  1.  D EN^DIQ1 K DA,DIC,DIQ,DR
  1.  S I=0,ENCRIT="" F  S I=$O(^ENG(6914,ENDA,4,I)) Q:'I  D
  1.  . S J=$P($G(^ENG(6914,ENDA,4,I,0)),U,4) I J>ENCRIT S ENCRIT=J
  1.  D DEV^ENLIB G:POP EXIT
  1.  S IOP=ION,L="0",DIC="^ENG(6920,",FLDS=$S($D(^DIPT("B","ENZ EQ HIST")):"[ENZ EQ HIST]",1:"[EN EQ HIST]"),BY="["_ENSTMPL_"]",FR="@"
  1.  I $D(IO("Q")) D  K ZTSK D HOME^%ZIS G EXIT
  1.  . S ZTIO=IOP,ZTRTN="DQHI^ENWO1",ZTDESC="Equipment History from Work Order Module"
  1.  . S ZTSAVE("IOP")="",ZTSAVE("EN*")="",ZTSAVE("DIC")=""
  1.  . S ZTSAVE("FLDS")="",ZTSAVE("BY")="",ZTSAVE("FR")="",ZTSAVE("L")=""
  1.  . D ^%ZTLOAD
  1.  S DIOEND="I IOST[""C-"" R !!,""Press <RETURN> to continue"",X:DTIME"
  1. DQHI ;
  1.  D EN1^DIP
  1.  S DIK="^DIBT(",DA=ENSTMPL(0) D ^DIK K DIK
  1.  G:'$D(ZTQUEUED) EQHI
  1.  G EXIT
  1. DSY ;Screen display work order
  1.  G EDIT^ENWOD
  1.  ;
  1. DEL ; Delete open work order
  1.  W !
  1.  K DA
  1.  S DIC("S")="I $P($G(^(5)),U,2)=""""" D WO^ENWOUTL K DIC
  1.  S DA=+Y G:DA'>0 EXIT
  1.  L +^ENG(6920,DA):5 I '$T W !!,"This work order is being edited by another user and can't be deleted.",$C(7),! G DEL
  1.  S DIR(0)="Y",DIR("A")="Delete work order "_$P($G(^ENG(6920,DA,0)),U)
  1.  D ^DIR K DIR I $D(DIRUT) G EXIT
  1.  I 'Y G DEL
  1.  S DIK="^ENG(6920," D ^DIK K DIK
  1.  W !,"  The work order has been deleted."
  1.  G DEL
  1.  ;
  1. INIT K DIC("S") S DIC="^DIC(6922,",DIC(0)="AEQM" D ^DIC S ENSHKEY=+Y Q
  1. EXIT K %IS,DIC,DIE,DA,Y,DR,N,I,J,K,O,S,X,Y,Z,ENWO
  1.  K ENSTMPL,L,FLDS,BY,FR,TO,ENVANO,IOP,ENDA,ENEQ,ENCRIT
  1.  S:$D(ZTQUEUED) ZTREQ="@"
  1.  Q
  1.  ;ENWO1