ENXHIPR.m

ENXHIPR ;WISC/SAB-PRE INIT ;4/1/97

 ;;7.0;ENGINEERING;**28**;Aug 17, 1993

 N ENDA,ENY

 D MES^XPDUTL("  Performing Pre-Init...")

 ; This patch renames field #74 from A/E SITE SURVEY to A/E SITE VISITS.

 ; It also adds a new field #72.3 called A/E SITE SURVEY.

 ; This pre-init routine will move any existing data values from #74

 ; to #72.3. This should only be done once so the pre-init checks

 ; that field #74 has not yet been renamed before moving data.

 I $$GET1^DID(6925,74,"","LABEL")="A/E SITE SURVEY" D

 . D MES^XPDUTL("    Moving A/E SITE SURVEY data to new location...")

 . S ENDA=0 F  S ENDA=$O(^ENG("PROJ",ENDA)) Q:'ENDA  D

 . . S ENY=$G(^ENG("PROJ",ENDA,5))

 . . I $P(ENY,U,5)]"",$P(ENY,U,10)="" D

 . . . S $P(ENY,U,10)=$P(ENY,U,5)

 . . . S $P(ENY,U,5)=""

 . . . S ^ENG("PROJ",ENDA,5)=ENY

 . . S ENY=$G(^ENG("PROJ",ENDA,64))

 . . I $P(ENY,U,5)]"",$P(ENY,U,10)="" D

 . . . S $P(ENY,U,10)=$P(ENY,U,5)

 . . . S $P(ENY,U,5)=""

 . . . S ^ENG("PROJ",ENDA,64)=ENY

 D MES^XPDUTL("  Completed Pre-Init")

 Q

 ;ENXHIPR

--- Routine Detail   --- with STRUCTURED ROUTINE LISTING ---ENXHIPR   1046     printed  Apr 09, 2024@21:00:13                                                                                                                                                                                                     Page 2

ENXHIPR   ;WISC/SAB-PRE INIT ;4/1/97

 +1       ;;7.0;ENGINEERING;**28**;Aug 17, 1993

 +2        NEW ENDA,ENY

 +3        DO MES^XPDUTL("  Performing Pre-Init...")

 +4       ; This patch renames field #74 from A/E SITE SURVEY to A/E SITE VISITS.

 +5       ; It also adds a new field #72.3 called A/E SITE SURVEY.

 +6       ; This pre-init routine will move any existing data values from #74

 +7       ; to #72.3. This should only be done once so the pre-init checks

 +8       ; that field #74 has not yet been renamed before moving data.

 +9        IF $$GET1^DID(6925,74,"","LABEL")="A/E SITE SURVEY"

               Begin DoDot:1

 +10               DO MES^XPDUTL("    Moving A/E SITE SURVEY data to new location...")

 +11               SET ENDA=0

                   FOR 

                       SET ENDA=$ORDER(^ENG("PROJ",ENDA))

                       if 'ENDA

                           QUIT 

                       Begin DoDot:2

 +12                       SET ENY=$GET(^ENG("PROJ",ENDA,5))

 +13                       IF $PIECE(ENY,U,5)]""

                               IF $PIECE(ENY,U,10)=""

                                   Begin DoDot:3

 +14                                   SET $PIECE(ENY,U,10)=$PIECE(ENY,U,5)

 +15                                   SET $PIECE(ENY,U,5)=""

 +16                                   SET ^ENG("PROJ",ENDA,5)=ENY

                                   End DoDot:3

 +17                       SET ENY=$GET(^ENG("PROJ",ENDA,64))

 +18                       IF $PIECE(ENY,U,5)]""

                               IF $PIECE(ENY,U,10)=""

                                   Begin DoDot:3

 +19                                   SET $PIECE(ENY,U,10)=$PIECE(ENY,U,5)

 +20                                   SET $PIECE(ENY,U,5)=""

 +21                                   SET ^ENG("PROJ",ENDA,64)=ENY

                                   End DoDot:3

                       End DoDot:2

               End DoDot:1

 +22       DO MES^XPDUTL("  Completed Pre-Init")

 +23       QUIT 

 +24      ;ENXHIPR