Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: FBLTCAR2

FBLTCAR2.m

Go to the documentation of this file. 
  1. FBLTCAR2 ;WOIFO/SS-LTC AUTHORIZATIONS REPORTS ;11/20/02
  1.  ;;3.5;FEE BASIS;**49**;JAN 30, 1995
  1.  ;
  1. EN ;ask program
  1.  N FBLTCAR
  1.  S DIC("B")=$S(FBLTCPR="CONTRACT NURSING HOME":FBLTCPR,1:"OUTPATIENT")
  1.  S DIC="^FBAA(161.8,",DIC(0)="AQEM",DIC("S")="S FBLTCAR=$P(^(0),U,1) I FBLTCAR=""OUTPATIENT""!(FBLTCAR=""CONTRACT NURSING HOME"")"
  1.  D ^DIC K DIC I Y'>0 G EXIT
  1.  S FBPROG=+Y
  1.  ;
  1.  ; ask purpose of visit(s)
  1.  S DIR(0)="Y",DIR("A")="For ALL LTC Purpose of Visits? Y/N",DIR("B")="YES"
  1.  D ^DIR K DIR G:$D(DIRUT) EXIT
  1.  S FBPOV=Y
  1.  I 'FBPOV D  G:'$D(FBPOV) EXIT S FBPOV=0
  1.  . K FBPOV
  1.  . W !,"Select one or more LTC Purpose of Visits"
  1.  . S DIC="^FBAA(161.82,",DIC(0)="AQEM",DIC("S")="I $P(^(0),U,2)=FBPROG&(+$P(^(0),U,4)>0)"
  1.  . F  D  Q:Y'>0
  1.  . . D ^DIC I Y>0 S FBPOV(+Y)=$P(Y,U,2)
  1.  . K DIC
  1.  ;
  1.  ; ask dates
  1.  S DIR(0)="D^::EX",DIR("A")="From Date"
  1.  ;   default from date is first day of previous month
  1.  S DIR("B")=$$FMTE^XLFDT($E($$FMADD^XLFDT($E(DT,1,5)_"01",-1),1,5)_"01")
  1.  D ^DIR K DIR G:$D(DIRUT) EXIT
  1.  S FBDT1=Y
  1.  S DIR(0)="DA^"_FBDT1_"::EX",DIR("A")="To Date: "
  1.  ;   default to date is last day of specified month
  1.  S X=FBDT1 D DAYS^FBAAUTL1
  1.  S DIR("B")=$$FMTE^XLFDT($E(FBDT1,1,5)_X)
  1.  D ^DIR K DIR G:$D(DIRUT) EXIT
  1.  S FBDT2=Y
  1.  ;
  1.  ; ask if remarks should be printed
  1.  S DIR(0)="Y",DIR("A")="Print authorization remarks",DIR("B")="NO"
  1.  D ^DIR K DIR G:$D(DIRUT) EXIT
  1.  S FBAR=Y
  1.  ;
  1.  ; ask device
  1.  S %ZIS="QM" D ^%ZIS G:POP EXIT
  1.  I $D(IO("Q")) D  G EXIT
  1.  . S ZTRTN="QEN^FBLTCAR2",ZTDESC="LTC Authorizations Report"
  1.  . F FBX="FBLTCRT","FBPROG","FBPOV*","FBDT*","FBAR" S ZTSAVE(FBX)=""
  1.  . D ^%ZTLOAD,HOME^%ZIS K ZTSK,ZTDESC,ZTREQ,ZTRTN,ZTSAVE,ZTSTOP,ZTQUEUED
  1.  ;
  1. QEN ; queued entry
  1.  U IO
  1.  ;
  1. GATHER ; collect and sort data
  1.  N FBVN
  1.  K ^TMP($J)
  1.  ; loop thru Fee Basis Patients
  1.  S FBDFN=0 F  S FBDFN=$O(^FBAAA(FBDFN)) Q:'FBDFN  D
  1.  . S FBPNAME=$$GET1^DIQ(161,FBDFN,.01)
  1.  . S:FBPNAME="" FBPNAME="UNKNOWN"
  1.  . ; loop thru authorizations
  1.  . S FBAU=0 F  S FBAU=$O(^FBAAA(FBDFN,1,FBAU)) Q:'FBAU  D
  1.  . . S FBA=$G(^FBAAA(FBDFN,1,FBAU,0))
  1.  . . Q:$P(FBA,U,3)'=FBPROG  ; not program
  1.  . . Q:$P($G(^FBAAA(FBDFN,1,FBAU,"ADEL")),U)  ; austin deleted
  1.  . . Q:$P(FBA,U,7)=""  ; blank purpose of visit
  1.  . . I 'FBPOV Q:'$D(FBPOV($P(FBA,U,7)))  ; not selected POV
  1.  . . Q:+$P($G(^FBAA(161.82,+$P(FBA,U,7),0)),U,4)=0  ;non-LTC
  1.  . . ; ensure authorization is not outside the period of interest
  1.  . . I +$G(FBLTCRT)=0 Q  ;FBLTCRT should be defined
  1.  . . I +$G(FBLTCRT)>0 Q:$$LTCRPT^FBLTCAR($P(FBA,U),$P(FBA,U,2),FBDT1,FBDT2,+$G(FBLTCRT))  ;for LTC reports FBLTCRT is difined in ^FBLTCAR
  1.  . . ; passed all criteria
  1.  . . S FBVN=$S($P(FBA,U,4):$P($G(^FBAAV($P(FBA,U,4),0)),U),1:"")
  1.  . . I FBVN="" S FBVN="not specified"
  1.  . . ; sort by purpose of visit,vendor,name^dfn,auth from date^auth ien
  1.  . . S ^TMP($J,$P(FBA,U,7),FBVN,FBPNAME_U_FBDFN,$P(FBA,U)_U_FBAU)=FBA
  1.  ;
  1. PRINT ; report data
  1.  N FBVN,FBD
  1.  S (FBQUIT,FBPG)=0 D NOW^%DTC S Y=% D DD^%DT S FBDTR=Y
  1.  K FBDL S FBDL="",$P(FBDL,"-",IOM)=""
  1.  ;
  1.  ; build page header text for selection criteria
  1.  K FBHDT
  1.  S FBHDT(1)="  FROM "_$$FMTE^XLFDT(FBDT1)_" TO "_$$FMTE^XLFDT(FBDT2)
  1.  S FBHDT(1)=FBHDT(1)_"  FOR THE "_$$GET1^DIQ(161.8,FBPROG,.01)_" PROGRAM"
  1.  S FBHDT(2)="  FOR "_$S(FBPOV:"ALL ",1:"")_"PURPOSE OF VISIT(S)"
  1.  I 'FBPOV D
  1.  . S FBL=2,FBHDT(FBL)=FBHDT(FBL)_": "
  1.  . S (FBC,FBI)=0 F  S FBI=$O(FBPOV(FBI)) Q:'FBI  D
  1.  . . I $L(FBHDT(FBL))+2+$L(FBPOV(FBI))>75 D
  1.  . . . I FBC S FBHDT(FBL)=FBHDT(FBL)_","
  1.  . . . S FBL=FBL+1
  1.  . . . S FBC=0,FBHDT(FBL)="    "
  1.  . . S FBHDT(FBL)=FBHDT(FBL)_$S(FBC:", ",1:"")_FBPOV(FBI)
  1.  . . S FBC=FBC+1 ; count of POVs on current line (FBL)
  1.  ;
  1.  ; determine if DAYS column should be displayed (true/false)
  1.  S FBDD=$$GET1^DIQ(161.8,FBPROG,.01)="STATE HOME"
  1.  ;
  1.  D HD
  1.  I '$D(^TMP($J)) W !,"No authorizations found during period."
  1.  S FBC("TOT")=0 ; initialize count of authorizations on report
  1.  ; loop thru purpose of visit
  1.  S FBPOV=0 F  S FBPOV=$O(^TMP($J,FBPOV)) Q:'FBPOV  D  Q:FBQUIT
  1.  . S FBPOV("E")=$$GET1^DIQ(161.82,FBPOV,.01)
  1.  . I $Y+9>IOSL D HD Q:FBQUIT
  1.  . W !!,"POV: ",FBPOV("E")
  1.  . S FBC("POV")=0 ; initialize count of authorizations for POV
  1.  . S:FBDD FBD("POV")=0 ; initialize count of days for POV
  1.  . ; loop thru vendors
  1.  . S FBVN="" F  S FBVN=$O(^TMP($J,FBPOV,FBVN)) Q:FBVN=""  D  Q:FBQUIT
  1.  . . I $Y+7>IOSL D HD Q:FBQUIT  D HDPOV
  1.  . . W !!,"  Vendor: ",FBVN,!
  1.  . . S FBC("VEN")=0 ; initialize count of auth for vendor (in POV)
  1.  . . S:FBDD FBD("VEN")=0 ; initialize count of days for vendor (in POV)
  1.  . . ; loop thru veterans
  1.  . . S FBPAT=""
  1.  . . F  S FBPAT=$O(^TMP($J,FBPOV,FBVN,FBPAT)) Q:FBPAT=""  D  Q:FBQUIT
  1.  . . . S FBPNAME=$P(FBPAT,U)
  1.  . . . S FBDFN=$P(FBPAT,U,2)
  1.  . . . D
  1.  . . . . N DFN S DFN=FBDFN D DEM^VADPT ; obtain patient demographics
  1.  . . . ; loop thru authorizations
  1.  . . . S FBAUT=""
  1.  . . . F  S FBAUT=$O(^TMP($J,FBPOV,FBVN,FBPAT,FBAUT)) Q:FBAUT=""  D  Q:FBQUIT
  1.  . . . . S FBDTF=$P(FBAUT,U)
  1.  . . . . S FBAU=$P(FBAUT,U,2)
  1.  . . . . S FBA=^TMP($J,FBPOV,FBVN,FBPAT,FBAUT)
  1.  . . . . S:FBDD FBDAYS=$$DOC^FBSHUTL($P(FBA,U),$P(FBA,U,2),FBDT1,FBDT2)
  1.  . . . . S FBC("VEN")=FBC("VEN")+1
  1.  . . . . S:FBDD FBD("VEN")=FBD("VEN")+FBDAYS
  1.  . . . . I $Y+6>IOSL D HD Q:FBQUIT  D HDPOV,HDVEN
  1.  . . . . W !,?4,FBPNAME,?35,$P(VADM(2),U,2)
  1.  . . . . W:FBDD ?48,$J(FBDAYS,3)
  1.  . . . . W ?53,$$FMTE^XLFDT($P(FBA,U)),?67,$$FMTE^XLFDT($P(FBA,U,2))
  1.  . . . . W !,?6,"DOB: ",$P(VADM(3),U,2)
  1.  . . . . I +VADM(6) W ?25,"*** Patient Died on ",$P(VADM(6),U,2)
  1.  . . . . ; print remarks (optional)
  1.  . . . . I $G(FBAR),$O(^FBAAA(FBDFN,1,FBAU,2,0)) D
  1.  . . . . . N DIWL,DIWR,DIWF,FBRR
  1.  . . . . . K ^UTILITY($J,"W") S DIWL=7,DIWR=(IOM-5),DIWF="W"
  1.  . . . . . S X="REMARKS: ",FBRR=0
  1.  . . . . . F  S FBRR=$O(^FBAAA(FBDFN,1,FBAU,2,FBRR)) Q:'FBRR  S X=X_^(FBRR,0) D ^DIWP S X="" I $Y+6>IOSL D HD Q:FBQUIT  D HDPOV,HDVEN,HDPAT
  1.  . . . . . D:'FBQUIT ^DIWW
  1.  . . . . ; print additional information for LTC reports
  1.  . . . . I +$G(FBLTCRT)>0 D PRNVIS^FBLTCAR(+FBDFN,+FBAU,FBVN,+FBDT1,+FBDT2,+$P(FBA,U),+$P(FBA,U,2))
  1.  . . . D KVA^VADPT ; clean up patient demographics
  1.  . . Q:FBQUIT
  1.  . . S FBC("POV")=FBC("POV")+FBC("VEN")
  1.  . . S:FBDD FBD("POV")=FBD("POV")+FBD("VEN")
  1.  . . I $Y+5>IOSL D HD Q:FBQUIT  D HDPOV,HDVEN
  1.  . . W !,?32,"----"
  1.  . . W:FBDD ?47,"----"
  1.  . . W !,"  Vendor Subtotal:",?25,"Count: ",$J(FBC("VEN"),4)
  1.  . . W:FBDD ?41,"Days: ",$J(FBD("VEN"),4)
  1.  . Q:FBQUIT
  1.  . S FBC("TOT")=FBC("TOT")+FBC("POV")
  1.  . I $Y+5>IOSL D HD Q:FBQUIT  D HDPOV
  1.  . W !,?32,"===="
  1.  . W:FBDD ?47,"===="
  1.  . W !,"POV Subtotal: ",?25,"Count: ",$J(FBC("POV"),4)
  1.  . W:FBDD ?41,"Days: ",$J(FBD("POV"),4)
  1.  ;
  1.  I FBQUIT W !!,"REPORT STOPPED AT USER REQUEST"
  1.  E  W !!,FBC("TOT")," Authorization",$S(FBC("TOT")=1:"",1:"s")," on report"
  1.  I 'FBQUIT,$E(IOST,1,2)="C-" S DIR(0)="E" D ^DIR K DIR
  1.  D ^%ZISC
  1.  ;
  1. EXIT ;
  1.  I $D(ZTQUEUED) S ZTREQ="@"
  1.  K ^TMP($J)
  1.  K FBA,FBAR,FBAU,FBAUT,FBC,FBDAYS,FBDD,FBDFN,FBDL,FBDT1,FBDT2,FBDTF
  1.  K FBDTR,FBHDT,FBI,FBL,FBPAT,FBPG,FBPNAME,FBPOV,FBPROG,FBSSN,FBQUIT,FBX
  1.  K DIC,DIR,DIROUT,DIRUT,DTOUT,DUOUT,X,Y,POP,VADM
  1.  Q
  1. HD ; page header
  1.  I $D(ZTQUEUED),$$S^%ZTLOAD S ZTSTOP=1,FBQUIT=1 Q
  1.  I $E(IOST,1,2)="C-",FBPG S DIR(0)="E" D ^DIR K DIR I 'Y S FBQUIT=1 Q
  1.  I $E(IOST,1,2)="C-"!FBPG W @IOF
  1.  S FBPG=FBPG+1
  1.  W !,$S(FBLTCRT=1:"ENDING ",1:"ACTIVE "),"AUTHORIZATIONS by POV, Vendor, Patient"
  1.  W ?49,FBDTR,?72,"page ",FBPG
  1.  S FBI=0 F  S FBI=$O(FBHDT(FBI)) Q:'FBI  W !,FBHDT(FBI)
  1.  W !!,?4,"VETERAN",?35,"Pt. ID"
  1.  W:FBDD ?47,"DAYS"
  1.  W ?56,"AUTHORIZATION"
  1.  W !,?53,"FROM DATE",?67,"TO DATE"
  1.  W !,FBDL
  1.  Q
  1. HDPOV ; page header for continued POV
  1.  W !,"POV:",FBPOV("E")," (continued)"
  1.  Q
  1. HDVEN ; page header for continued Vendor
  1.  W !,"  Vendor: ",FBVN," (continued)"
  1.  Q
  1. HDPAT ; page header for continued Patient
  1.  W !,"    Patient: ",FBPNAME," (continued)"
  1.  Q
  1.  ;
  1.  ;FBLTCAR2