Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: FBUCUTL3

FBUCUTL3.m

Go to the documentation of this file. 
  1. FBUCUTL3 ;ALBISC/TET - UTILITY CONTINUATION ;10/10/2001
  1.  ;;3.5;FEE BASIS;**38**;JAN 30, 1995
  1.  ;;Per VHA Directive 10-93-142, this routine should not be modified.
  1. DELDAP(FBDA) ;delete disapproval reasons from disapproval multiple in 162.7
  1.  ;if current disposition is 1 (approved) and prior was >1
  1.  ;INPUT:  FBDA = ien of unauthorized claim, 162.7
  1.  ;OUTPUT: none - delete disapproval reasons, if any, from claim
  1.  N Y ;if coming from input template
  1.  I $D(^FB583(FBDA,"D")) N DA,DIK,FBX S DA(1)=FBDA,DIK="^FB583("_FBDA_",""D"",",FBX=0 F  S FBX=$O(^FB583(FBDA,"D","B",FBX)) Q:'FBX  D
  1.  .S DA=0 F  S DA=$O(^FB583(FBDA,"D","B",FBX,DA)) Q:'DA  D ^DIK
  1.  K DA,DIK,FBX Q
  1. DISDAP(FBDA) ;display disapproval reasons and enter in file if any selected
  1.  ;INPUT:  FBDA = ien of unauthorized claim, 162.7
  1.  ;OUTPUT:  if selection, and not already entered, reason is entered
  1.  ;          in REASON FOR DISAPPROVAL (field 15, subfile 162.715).
  1.  ;        FBOUT returned from call to FBUCUTL1
  1.  N FBAR,FBARY,FBI,FBX
  1.  D DISP9^FBUCUTL5(162.94) ;set array for selection
  1.  D DISPX^FBUCUTL1(2) Q:FBOUT  ;display/select choices & display selection
  1.  I 'FBOUT,+$G(FBARY) S FBI=0 F  S FBI=$O(^TMP("FBARY",$J,FBI)) Q:'FBI  S FBX=$G(^(FBI)) I +FBX D DISAP^FBUCUTL(FBDA,+FBX) ;file entry
  1.  K FBARY,FBI,FBX,^TMP("FBAR",$J),^TMP("FBARY",$J) Q
  1. ADD ;add new person to file 200, new person file, if other party submits claim
  1.  S FBY=$$ADD^XUSERNEW(".111:.116;9")
  1.  I +FBY>0,'$P(FBY,U,3) W !,"No entry has been made to the New Person file.",!,"If a new entry is needed, enter the name within quotes.",!,*7
  1.  K FBY Q
  1. DISPNP ;display letters not printed
  1.  ;INPUT:  none
  1.  ;OUTPUT: FBAR = display count in array;piece positions for display
  1.  ;        FBAR( array => ien;vet^ven^fee program^date of claim^status
  1.  K ^TMP("FBAR",$J),FBAR N FBI,FBDCT,Z S (FBI,FBDCT)=0 F  S FBI=$O(^FB583("AL",1,FBI)) Q:'FBI  S Z=$G(^FB583(FBI,0)) I Z]"" D
  1.  .S FBDCT=FBDCT+1,FBAR=FBI_";"_$E($$VET^FBUCUTL($P(Z,U,4)),1,12)_U_$E($$VEN^FBUCUTL($P(Z,U,3)),1,12)_U_$E($$PROG^FBUCUTL($P(Z,U,2)),1,14)_U_$$DATX^FBAAUTL($P(Z,U))_U_$E($P($G(^FB(162.92,+$P(Z,U,24),0)),U),1,16)
  1.  .S ^TMP("FBAR",$J,FBDCT)=FBAR
  1.  S FBAR=FBDCT I FBDCT S FBAR=FBAR_";"_"5^20^35^52^63^"
  1.  S ^TMP("FBAR",$J,"FBAR")=FBAR
  1.  Q
  1. LOOKUP(FBO,FBSAVE,FB1725R) ;lookup claim, based on veteran/vendor, and status
  1.  ;INPUT:  FBO = order string or 0 for all
  1.  ;        FBSAVE = 1 to save xref variable (optional)
  1.  ;        FB1725R = (optional) mill bill screening criteria with value
  1.  ;            "M" for just mill bill claims
  1.  ;            "N" for just non-mill bill claims
  1.  ;            "A" (or null) for all claims
  1.  ;OUTPUT:  FBARY = count;position^position, etc
  1.  ;         TMP(FBARY => array of user selection
  1.  ;        FBIX & FBIEN (returned only if fbsave)
  1.  S FBOUT=0 D IEN I 'FBIEN S FBOUT=1 G LOOKUPQ
  1.  D DISP7^FBUCUTL5(FBIX,FBIEN,FBO,$G(FB1725R)) ;screen on status/order
  1.  D DISPX^FBUCUTL1(1,FBO) ;display list from which to select
  1. LOOKUPQ K:'+$G(FBSAVE) FBIEN,FBIX K ^TMP("FBAR",$J) Q
  1. IEN ;get ien of vendor or veteran from 162.7
  1.  ;OUTPUT:  FBIEN = ien of either vendor, veteran or other claimant
  1.  ;                 or 0 if failed/time out/up arrow out
  1.  ;         FBIX  = lookup cross reference (APMS, AVMS or AOMS)
  1.  N DIR,DIRUT,DTOUT,DUOUT,Y S DIR(0)="162.7,23O",DIR("A")="Select unauthorized claim",DIR("?")="You may select the claim by entering the vendor, veteran or other party."
  1.  D ^DIR K DIR S FBIEN=$S($D(DIRUT):0,+Y'>0:0,1:+Y),FBIX=$S(Y["VA":"AOMS",Y["FB":"AVMS",1:"APMS")
  1.  Q
  1. LETDATE ;ask for date letter sent, don't allow future values
  1.  ;INPUT:  FBOUT (optional) - flag if time out or up-arror out
  1.  ;OUTPUT: FBOUT - 1 if time out or up-arrow out
  1.  ;        FBLETDT - date if no fbout flag, otherwise 0
  1.  N DIR,DIRUT,DTOUT,DUOUT,Y S FBLETDT=0 S:'$D(FBOUT) FBOUT=0 S DIR(0)="162.7,19.5" D ^DIR K DIR S:$D(DTOUT)!($D(DUOUT)) FBOUT=1 I 'FBOUT S FBLETDT=Y
  1.  Q
  1. AUTHLKUP(FBUCP,FBDA) ;look up authorization - match on 583,vendor,program,auth from & to dates and veteran
  1.  ;INPUT:  FBUCP = prior zero node of 162.7, unauthorized claim
  1.  ;        FBDA  = ien of unauthorized claim
  1.  ;OUTPUT: FBIEN = 0 if no match, otherwise ien of authorization
  1.  S FBIEN=0 I $S('+$G(FBDA):1,$G(FBUCP)']"":1,1:0) Q
  1.  N FBDA1,FBI,FBZ S FBDA1=+$P(FBUCP,U,4),FBI=0
  1.  F  S FBI=$O(^FBAAA("ATST",+$P(FBUCP,U,13),FBDA1,0)) Q:'FBI  S FBZ=$G(^FBAAA(FBDA1,1,FBI,0)) I $P(FBZ,U,2)=$P(FBUCP,U,14),$P(FBZ,U,3)=$P(FBUCP,U,2),$P(FBZ,U,4)=$P(FBUCP,U,3),+$P(FBZ,U,9)=FBDA S FBIEN=FBI Q
  1.  Q
  1. EDOK(X,FBW) ;ok to edit modify/reopen or disposition input templates
  1.  ;INPUT:  X= ien of 162.7
  1.  ;        FBW= 1 to write, 0 not to write (optional)
  1.  ;OUTPUT: 0 if NOT OK to edit; 1 if ok to edit
  1.  N FBY S FBY=1 S:'$G(FBW) FBW=0
  1.  I $$PAY^FBUCUTL(X,"^FB583(") D
  1.  .W:FBW !,"Payments on file!",*7,!
  1.  .I '$$OVER^FBUCUTL("FBAASUPERVISOR") W:FBW !,"You must hold the supervisor's key to edit any data other than Amount Approved.",! S FBY=0
  1.  Q FBY
  1.  ;