Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: GECSMUT1

GECSMUT1.m

Go to the documentation of this file. 
  1. GECSMUT1 ;WISC/RFJ-maintenance utilities (batching)                 ;01 Nov 93
  1.  ;;2.0;GCS;**2,6**;MAR 14, 1995
  1.  ;edited by IRMFO-SF/RJH 12-95
  1.  Q
  1.  ;
  1. MARKBAT(DA)        ;  mark code sheet da for batching
  1.  ;  return 1 for marked, 0 for unmarked
  1.  N %,%DT,D0,DI,DIC,DIE,DQ,DR,X,Y
  1.  S %=$G(^GECS(2100,DA,0)) I %="" Q 0
  1.  W !!?5,"** CODE SHEET NUMBER: ",$P(%,"^")," **"
  1.  S DR=".15///@;.8///@;.1///Y;.95////"_DUZ_";"
  1.  I $G(GECSAUTO)="BATCH" S DR=DR_".6///TODAY;.9///3;"
  1.  E  S DR=DR_".6//TODAY;.9//3;"
  1.  S (DIC,DIE)="^GECS(2100," W ! D ^DIE
  1.  ;  ^ entered, retain in file
  1.  I $D(Y) D RETAIN^GECSUSTA(DA) S %=$$STATUS^GECSUSTA(DA) Q 0
  1.  I $G(GECSAUTO)="BATCH" W !,"CODE SHEET AUTOMATICALLY MARKED FOR BATCHING !" Q 1
  1.  S %=$$STATUS^GECSUSTA(DA)
  1.  Q 1
  1.  ;
  1. ASKREBAT()         ;  ask to rebatch
  1.  ;  return 1 for yes, 0 for no
  1.  S XP="DO YOU WANT TO MARK FOR REBATCHING",XH="'YES' to mark for rebatching.",XH(1)="'NO' or '^' to abort."
  1.  I $$YN^GECSUTIL(2)'=1 Q 0
  1.  Q 1
  1.  ;
  1. REMARK ;  remark a code sheet for batching
  1.  N %,GECS,GECSBATC,GECSDA,GECSSTAT,GECSBTYP
  1.  D ^GECSSITE Q:'$D(GECS("SITE"))
  1.  D BATNOFMS^GECSUSEL Q:'$G(GECS("BATDA"))
  1.  S GECSBTYP=GECS("BATCH")
  1.  F  S GECSDA=$$CODESHET^GECSUSEL(GECSBTYP) Q:'GECSDA  D
  1.  .  D VARIABLE^GECSUTIL(GECSDA)
  1.  .  I $G(GECS("SYSID"))="FMS" W !,"*** FMS DOCUMENTS DO NOT HAVE TO BE BATCHED ***" Q
  1.  .  I $G(GECS("CSDA")) D  Q
  1.  .  .   W ! S GECSSTAT=$$STATUS^GECSUSTA(GECS("CSDA")) W !
  1.  .  .   S GECSBATC=$P($G(^GECS(2100,GECS("CSDA"),"TRANS")),"^",9)
  1.  .  .   I GECSBATC="" W !,"YOU CAN ONLY SELECT CODE SHEETS WHICH HAVE BEEN MARKED FOR BATCHING." Q
  1.  .  .   I $$ASKREBAT S %=$$MARKBAT(GECS("CSDA")) D KILLBATC(GECSBATC) Q
  1.  .  D ERROR^GECSUTIL(GECSDA)
  1.  Q
  1.  ;
  1. REVIEW ;  review code sheets waiting to be batched
  1.  N %,GECS,GECSDA,GECSSTAT,GECSBTYP
  1.  D ^GECSSITE Q:'$D(GECS("SITE"))
  1.  W ! D BATTYPE^GECSUSEL($G(GECSSYS),$S($L($G(GECSSYS)):1,1:0)) Q:'$G(GECS("BATDA"))
  1.  S GECSBTYP=GECS("BATCH")
  1.  F  S GECSDA=$$CODESHET^GECSUSEL(GECSBTYP) Q:'GECSDA  D
  1.  .  D VARIABLE^GECSUTIL(GECSDA)
  1.  .  I $G(GECS("CSDA")) D  Q
  1.  .  .   W ! S GECSSTAT=$$STATUS^GECSUSTA(GECS("CSDA")) W !
  1.  .  .   I GECS("SYSID")'="FMS",$P($G(^GECS(2100,GECS("CSDA"),"TRANS")),"^")'="Y" W !,"YOU CAN ONLY SELECT CODE SHEETS WHICH HAVE BEEN MARKED FOR BATCHING." Q
  1.  .  .   I GECS("SYSID")="FMS",$P($G(^GECS(2100,GECS("CSDA"),"TRANS")),"^",3)'="" W !,"YOU CAN ONLY SELECT FMS DOCUMENTS WHICH HAVE NOT BEEN TRANSMITTED." Q
  1.  .  .   I '$$MAPDATA^GECSXBLD(GECS("CSDA")) Q
  1.  .  .   D ASKTOBAT^GECSXBL1(GECS("CSDA"))
  1.  .  D ERROR^GECSUTIL(GECSDA)
  1.  Q
  1.  ;
  1. DELETE ;  delete selected code sheets
  1.  N %,GECS,GECSDA,GECSSTAT,GECSBTYP
  1.  D ^GECSSITE Q:'$D(GECS("SITE"))
  1.  W ! D BATTYPE^GECSUSEL($G(GECSSYS),$S($L($G(GECSSYS)):1,1:0)) Q:'$G(GECS("BATDA"))
  1.  S GECSBTYP=GECS("BATCH")
  1.  F  S GECSDA=$$CODESHET^GECSUSEL(GECSBTYP) Q:'GECSDA  D
  1.  .  D VARIABLE^GECSUTIL(GECSDA)
  1.  .  W ! S GECSSTAT=$$STATUS^GECSUSTA(GECSDA) W !
  1.  .  D DELASK^GECSUTIL(GECSDA)
  1.  Q
  1.  ;
  1. EDITBAT ;  edit code sheet batch
  1.  N %,GECS,GECSBATC,GECSDA,GECSDICS,GECSSTAT,GECSBTYP
  1.  D ^GECSSITE Q:'$G(GECS("SITE"))
  1.  D BATNOFMS^GECSUSEL Q:'$G(GECS("BATDA"))
  1.  S GECSBTYP=GECS("BATCH")
  1.  F  S GECSDA=$$CODESHET^GECSUSEL(GECSBTYP) Q:'GECSDA  D
  1.  .  D VARIABLE^GECSUTIL(GECSDA)
  1.  .  I $G(GECS("CSDA")) D  Q
  1.  .  .   W ! S GECSSTAT=$$STATUS^GECSUSTA(GECS("CSDA")) W !
  1.  .  .   I '$D(^GECS(2100,GECS("CSDA"),"TRANS")) W !,"CODE SHEET MUST BE READY FOR BATCHING BEFORE THE BATCH NUMBER CAN BE EDIT.",!,"USE THE 'Code Sheet Edit' OPTION." Q
  1.  .  .   I $P($G(^GECS(2100,GECS("CSDA"),"TRANS")),"^",9)'="" D  Q:%=0
  1.  .  .   .   S XP="Do you want to DELETE this batch number",XH="Enter 'YES' to DELETE batch number, 'NO' ro select a NEW batch number,",XH(1)="or '^' to exit."
  1.  .  .   .   S %=$$YN^GECSUTIL(2) I %'=1 Q
  1.  .  .   .   S GECSBATC=$P(^GECS(2100,GECS("CSDA"),"TRANS"),"^",9)
  1.  .  .   .   S %=$$MARKBAT(GECS("CSDA"))
  1.  .  .   .   D KILLBATC(GECSBATC)
  1.  .  .   .   S %=0
  1.  .  .   S GECSDICS="I $P(^(0),U,6)=GECS(""BATDA""),$P(^(0),U,4)="""""
  1.  .  .   S GECSBATC=$$BATCHSEL^GECSUSEL(GECSDICS) I 'GECSBATC Q
  1.  .  .   S GECSBATC=$P($G(^GECS(2101.3,GECSBATC,0)),"^") I GECSBATC="" Q
  1.  .  .   S XP="READY TO CHANGE THE BATCH NUMBER",XH="Enter 'YES' to change the batch number, 'NO' or '^' to exit."
  1.  .  .   I $$YN^GECSUTIL(1)'=1 Q
  1.  .  .   D SETBATCH(GECS("CSDA"),GECSBATC)
  1.  .  D ERROR^GECSUTIL(GECSDA)
  1.  Q
  1.  ;
  1. SETBATCH(DA,GECSBATC) ;  set code sheet da to gecsbatc batch
  1.  N DIC,DIE,DR,X,Y
  1.  S (DIC,DIE)="^GECS(2100,",DR=".1///@;.15///Y;.8////"_GECSBATC_";.9//3;"
  1.  D ^DIE I $D(Y) W !,"UNABLE TO SET BATCH NUMBER ",GECSBATC Q
  1.  W !,"CODE SHEET READY FOR TRANSMISSION IN BATCH ",GECSBATC
  1.  Q
  1.  ;
  1. KILLBATC(GECSBATC) ;  check if any code sheets are in batch, if no delete it
  1.  I '$L(GECSBATC) Q
  1.  I $D(^GECS(2100,"AB",GECSBATC)) Q
  1.  N DA
  1.  S DA=+$O(^GECS(2101.3,"B",GECSBATC,0)) I 'DA Q
  1.  W !!,"NO CODE SHEETS INCLUDED IN BATCH ",GECSBATC,".",!,"DELETING BATCH ",GECSBATC
  1.  D KILLBATC^GECSPUR1(DA)
  1.  Q