Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: GMPLY47

GMPLY47.m

Go to the documentation of this file. 
  1. GMPLY47 ;ISL/TC - Post-install for GMPL*2.0*47 ;12/21/15  13:39
  1.  ;;2.0;Problem List;**47**;Aug 25,1994;Build 58
  1.  ;
  1.  ;===========================================
  1.  ; INDEXD^PXRMDIEV    ICR #6059
  1.  ;
  1. CACRMTA ;Create the auxillary cross-reference for Mapping Targets multiple.
  1.  N MSG,NAME,RESULT,XREF
  1.  D BMES^XPDUTL("Creating Problem List Mapping Targets auxillary cross-reference.")
  1.  S XREF("FILE")=9000011
  1.  S XREF("ROOT FILE")=9000011
  1.  S XREF("TYPE")="MU"
  1.  S XREF("SHORT DESCR")="Clinical Reminders Index for Mapping Targets code lookup."
  1.  S XREF("DESCR",1)="This cross-reference builds two indexes, one for finding"
  1.  S XREF("DESCR",2)="all patients with a particular Mapping Target code and one for"
  1.  S XREF("DESCR",3)="finding all the Mapping Target codes a patient has. The indexes are"
  1.  S XREF("DESCR",4)="stored in the Clinical Reminders Index global as:"
  1.  S XREF("DESCR",5)=" ^PXRMINDX(9000011,CODESYS,""ISPP"",CODE,STATUS,PRIORITY,DFN,DLM,DAS)"
  1.  S XREF("DESCR",6)=" ^PXRMINDX(9000011,CODESYS,""PSPI"",DFN,STATUS,PRIORITY,CODE,DLM,DAS)"
  1.  S XREF("DESCR",7)="respectively."
  1.  S XREF("DESCR",8)=" "
  1.  S XREF("DESCR",9)="CODESYS is the standard three-character abbreviation for the coding system."
  1.  S XREF("DESCR",10)="STATUS can be ""A"" for active or ""I"" for inactive. PRIORITY"
  1.  S XREF("DESCR",11)="can be ""A"" for acute or ""C"" for chronic. If PRIORITY is"
  1.  S XREF("DESCR",12)="missing, then a ""U"" will be stored in the Index. For"
  1.  S XREF("DESCR",13)="Problems whose PRIORITY is ""C"", Clinical Reminders uses"
  1.  S XREF("DESCR",14)="today's date for the date of the Problem. In all other"
  1.  S XREF("DESCR",15)="cases, Clinical Reminders uses DLM, where DLM is the Date"
  1.  S XREF("DESCR",16)="Last Modified. When Problems are ""removed"", then CONDITION"
  1.  S XREF("DESCR",17)="is set to ""H"" for hidden. Hidden Problems are not indexed."
  1.  S XREF("DESCR",18)="For complete details, see the Clinical Reminders Index"
  1.  S XREF("DESCR",19)="Technical Guide/Programmer's Manual."
  1.  S XREF("DESCR",20)=""
  1.  S XREF("DESCR",21)="This cross-reference is based on the fields DATE LAST"
  1.  S XREF("DESCR",22)="MODIFIED, STATUS, PRIORITY, and CONDITION because the first"
  1.  S XREF("DESCR",23)="three are Index subscripts Problems whose CONDITION equals"
  1.  S XREF("DESCR",24)="HIDDEN are not indexed."
  1.  ;
  1.  S XREF("EXECUTION")="R"
  1.  S XREF("ACTIVITY")="IR"
  1.  S XREF("VAL",1)=.03
  1.  S XREF("VAL",1,"SUBSCRIPT")=1
  1.  S XREF("VAL",2)=.12
  1.  S XREF("VAL",2,"SUBSCRIPT")=2
  1.  S XREF("VAL",3)=1.14
  1.  S XREF("VAL",4)=1.02
  1.  ;
  1.  S XREF("NAME")="ACRMTA"
  1.  S XREF("SET")="D SPROBMTA^GMPLPXRM(.X,.DA)"
  1.  S XREF("KILL")="D KPROBMTA^GMPLPXRM(.X,.DA)"
  1.  ;Remove any existing cross-references before creating the new one.
  1.  D DELIXN^DDMOD(9000011,"ACRMTA","","MSG")
  1.  K MSG
  1.  D CREIXN^DDMOD(.XREF,"",.RESULT,"","MSG")
  1.  Q
  1.  ;
  1. POST ; Post-install subroutine
  1.  ;Create the new cross-reference
  1.  D CACRMTA
  1.  ;Call Reminders reindexing API to clean up any ACRMT indexes that didn't get deleted appropriately.
  1.  D REINDEX
  1.  Q
  1.  ;
  1. REINDEX ;Rebuild the Problem List portion of the Clinical Reminders Index.
  1.  N TEXT,ZTDESC,ZTDTH,ZTIO,ZTRTN,ZTSK
  1.  S ZTRTN="INDEX^GMPLY47"
  1.  S ZTDESC="Problem List Clinical Reminders Index rebuild"
  1.  S ZTDTH=$H
  1.  S ZTIO=""
  1.  D ^%ZTLOAD
  1.  S TEXT(1)="Problem List Clinical Reminders Index rebuild queued."
  1.  S TEXT(2)="The task number is "_ZTSK_"."
  1.  D MES^XPDUTL(.TEXT)
  1.  Q
  1. INDEX ;Disable reminder evaluations prior to reindexing.
  1.  K ^PXRMINDX(9000011,"DATE BUILT")
  1.  D INDEXD^PXRMDIEV(9000011) ;disable/re-eanble evaluations
  1.  D INDEX^GMPLPXRM
  1.  Q