GMRADSP1 ;HIRMFO/WAA-DISPLAY ALLERGY ;11/13/07 08:07
;;4.0;Adverse Reaction Tracking;**41**;Mar 29, 1996;Build 8
DISBLD(IEN,ARRAY) ; This subroutine will bulid the array that will
; be displayed for each reactant. The IEN for each reactant in
; stored in GMRAPA.
N CNT,X,NODE
S NODE=$G(^GMR(120.8,IEN,0)) Q:NODE="" S CNT=1
I $L(GMRANAME)>50 S ARRAY(CNT)=$E(GMRANAME,1,50),CNT=CNT+1,ARRAY(CNT)=$E(GMRANAME,51,999)
E S ARRAY(CNT)=GMRANAME
ING ;Find all the ingredents for a reactant.
I $O(^GMR(120.8,IEN,2,0))>0 D
.N GMRAFST,GMRAGBAL,GMRAING,GMRAINGR,GMRALLEG,GMRALST
.S GMRAINGR=0,GMRALLEG=0
.F S GMRAINGR=$O(^GMR(120.8,IEN,2,GMRAINGR)) Q:GMRAINGR'>0 S GMRAGBAL=^GMR(120.8,IEN,2,GMRAINGR,0) D
..;--41-1
..D ZERO^PSN50P41(GMRAGBAL,"","","ENCAP")
..I '$D(^TMP($J,"ENCAP",GMRAGBAL)) K ^TMP($J,"ENCAP") Q
..;--41-1
..;--41-2
..I $P(NODE,U,2)=$P(^TMP($J,"ENCAP",GMRAGBAL,.01),U) Q
..;--41-2
..;--41-3
..S GMRALLEG(IEN,$P(^TMP($J,"ENCAP",GMRAGBAL,.01),U))="",GMRALLEG=GMRALLEG+1
..K ^TMP($J,"ENCAP")
..;--41-3
..Q
.I GMRALLEG S (GMRAINGR,GMRAING)="",CNT=CNT+1,ARRAY(CNT)="",GMRAFST=1,GMRALST=0 F S GMRAINGR=$O(GMRALLEG(IEN,GMRAINGR)) Q:GMRAINGR="" D
..I $O(GMRALLEG(IEN,GMRAINGR))="" S GMRALST=1
..S GMRAING=GMRAINGR
..I GMRAFST S GMRAING=" ("_GMRAING,GMRAFST=0
..I 'GMRALST S GMRAING=GMRAING_", "
..I GMRALST S GMRAING=GMRAING_")"
..I $L(ARRAY(CNT)_GMRAING)>52 S CNT=CNT+1,ARRAY(CNT)=" "_GMRAING
..E S ARRAY(CNT)=ARRAY(CNT)_GMRAING
..Q
.Q
SIGN ;Get all the patient Sign/Symptoms
I $O(^GMR(120.8,IEN,10,0))>0 D
.N GMRAFST,GMRALST,GMRAOTH,GMRAREAC,GMRAREAN,GMRATONS
.S GMRAOTH=$O(^GMRD(120.83,"B","OTHER REACTION",0))
.S GMRAFST=1,GMRALST=0,CNT=CNT+1,ARRAY(CNT)=" Reactions:"
.S GMRAREAC=0 F S GMRAREAC=$O(^GMR(120.8,IEN,10,GMRAREAC)) Q:GMRAREAC'>0 S GMRAREAN=$P($G(^GMR(120.8,IEN,10,GMRAREAC,0)),U) I GMRAREAN'="" D
..N GMRAREC
..I '$O(^GMR(120.8,IEN,10,GMRAREAC)) S GMRALST=1
..S GMRATONS=$S(GMRAREAN'=GMRAOTH:$P(^GMRD(120.83,GMRAREAN,0),U),1:$P(^GMR(120.8,IEN,10,GMRAREAC,0),U,2))
..S GMRAREC=GMRATONS
..I GMRAFST S GMRAREC=" "_GMRAREC,GMRAFST=0
..I 'GMRALST S GMRAREC=GMRAREC_", "
..I $L(ARRAY(CNT)_GMRAREC)>52 S CNT=CNT+1,ARRAY(CNT)=" "_GMRAREC
..E S ARRAY(CNT)=ARRAY(CNT)_GMRAREC
..Q
.Q
S %=$S($P(NODE,U,16):"YES",1:" NO") I $P(NODE,U,16),$P(NODE,U,18)="" S %="AUTO"
S ARRAY(1)=ARRAY(1)_$J(" ",(53-$L(ARRAY(1))))_%
S %=$P(NODE,U,14),%=$S(%="P":"PHARM ",%="A":"ALLERGY",%="U":"UNKNOWN ",1:""),ARRAY(1)=ARRAY(1)_$J(" ",(59-$L(ARRAY(1))))_%
S %=$P(NODE,U,6),%=$S(%="o":"OBS",%="h":"HIST",1:""),ARRAY(1)=ARRAY(1)_$J(" ",(68-$L(ARRAY(1))))_%
TYPE S %="" F X=1:1:($L(GMRATYPE)) D
.S %=$P("^FOOD^DRUG^OTHER",U,$F("FDO",$E(GMRATYPE,X)))
.S ARRAY(X)=$G(ARRAY(X))
.S ARRAY(X)=ARRAY(X)_$J(" ",(74-$L(ARRAY(X))))_%
.Q
Q
--- Routine Detail --- with STRUCTURED ROUTINE LISTING ---[H[J[2J[HGMRADSP1 2856 printed Dec 13, 2024@01:38:52 Page 2
GMRADSP1 ;HIRMFO/WAA-DISPLAY ALLERGY ;11/13/07 08:07
+1 ;;4.0;Adverse Reaction Tracking;**41**;Mar 29, 1996;Build 8
DISBLD(IEN,ARRAY) ; This subroutine will bulid the array that will
+1 ; be displayed for each reactant. The IEN for each reactant in
+2 ; stored in GMRAPA.
+3 NEW CNT,X,NODE
+4 SET NODE=$GET(^GMR(120.8,IEN,0))
if NODE=""
QUIT
SET CNT=1
+5 IF $LENGTH(GMRANAME)>50
SET ARRAY(CNT)=$EXTRACT(GMRANAME,1,50)
SET CNT=CNT+1
SET ARRAY(CNT)=$EXTRACT(GMRANAME,51,999)
+6 IF '$TEST
SET ARRAY(CNT)=GMRANAME
ING ;Find all the ingredents for a reactant.
+1 IF $ORDER(^GMR(120.8,IEN,2,0))>0
Begin DoDot:1
+2 NEW GMRAFST,GMRAGBAL,GMRAING,GMRAINGR,GMRALLEG,GMRALST
+3 SET GMRAINGR=0
SET GMRALLEG=0
+4 FOR
SET GMRAINGR=$ORDER(^GMR(120.8,IEN,2,GMRAINGR))
if GMRAINGR'>0
QUIT
SET GMRAGBAL=^GMR(120.8,IEN,2,GMRAINGR,0)
Begin DoDot:2
+5 ;--41-1
+6 DO ZERO^PSN50P41(GMRAGBAL,"","","ENCAP")
+7 IF '$DATA(^TMP($JOB,"ENCAP",GMRAGBAL))
KILL ^TMP($JOB,"ENCAP")
QUIT
+8 ;--41-1
+9 ;--41-2
+10 IF $PIECE(NODE,U,2)=$PIECE(^TMP($JOB,"ENCAP",GMRAGBAL,.01),U)
QUIT
+11 ;--41-2
+12 ;--41-3
+13 SET GMRALLEG(IEN,$PIECE(^TMP($JOB,"ENCAP",GMRAGBAL,.01),U))=""
SET GMRALLEG=GMRALLEG+1
+14 KILL ^TMP($JOB,"ENCAP")
+15 ;--41-3
+16 QUIT
End DoDot:2
+17 IF GMRALLEG
SET (GMRAINGR,GMRAING)=""
SET CNT=CNT+1
SET ARRAY(CNT)=""
SET GMRAFST=1
SET GMRALST=0
FOR
SET GMRAINGR=$ORDER(GMRALLEG(IEN,GMRAINGR))
if GMRAINGR=""
QUIT
Begin DoDot:2
+18 IF $ORDER(GMRALLEG(IEN,GMRAINGR))=""
SET GMRALST=1
+19 SET GMRAING=GMRAINGR
+20 IF GMRAFST
SET GMRAING=" ("_GMRAING
SET GMRAFST=0
+21 IF 'GMRALST
SET GMRAING=GMRAING_", "
+22 IF GMRALST
SET GMRAING=GMRAING_")"
+23 IF $LENGTH(ARRAY(CNT)_GMRAING)>52
SET CNT=CNT+1
SET ARRAY(CNT)=" "_GMRAING
+24 IF '$TEST
SET ARRAY(CNT)=ARRAY(CNT)_GMRAING
+25 QUIT
End DoDot:2
+26 QUIT
End DoDot:1
SIGN ;Get all the patient Sign/Symptoms
+1 IF $ORDER(^GMR(120.8,IEN,10,0))>0
Begin DoDot:1
+2 NEW GMRAFST,GMRALST,GMRAOTH,GMRAREAC,GMRAREAN,GMRATONS
+3 SET GMRAOTH=$ORDER(^GMRD(120.83,"B","OTHER REACTION",0))
+4 SET GMRAFST=1
SET GMRALST=0
SET CNT=CNT+1
SET ARRAY(CNT)=" Reactions:"
+5 SET GMRAREAC=0
FOR
SET GMRAREAC=$ORDER(^GMR(120.8,IEN,10,GMRAREAC))
if GMRAREAC'>0
QUIT
SET GMRAREAN=$PIECE($GET(^GMR(120.8,IEN,10,GMRAREAC,0)),U)
IF GMRAREAN'=""
Begin DoDot:2
+6 NEW GMRAREC
+7 IF '$ORDER(^GMR(120.8,IEN,10,GMRAREAC))
SET GMRALST=1
+8 SET GMRATONS=$SELECT(GMRAREAN'=GMRAOTH:$PIECE(^GMRD(120.83,GMRAREAN,0),U),1:$PIECE(^GMR(120.8,IEN,10,GMRAREAC,0),U,2))
+9 SET GMRAREC=GMRATONS
+10 IF GMRAFST
SET GMRAREC=" "_GMRAREC
SET GMRAFST=0
+11 IF 'GMRALST
SET GMRAREC=GMRAREC_", "
+12 IF $LENGTH(ARRAY(CNT)_GMRAREC)>52
SET CNT=CNT+1
SET ARRAY(CNT)=" "_GMRAREC
+13 IF '$TEST
SET ARRAY(CNT)=ARRAY(CNT)_GMRAREC
+14 QUIT
End DoDot:2
+15 QUIT
End DoDot:1
+16 SET %=$SELECT($PIECE(NODE,U,16):"YES",1:" NO")
IF $PIECE(NODE,U,16)
IF $PIECE(NODE,U,18)=""
SET %="AUTO"
+17 SET ARRAY(1)=ARRAY(1)_$JUSTIFY(" ",(53-$LENGTH(ARRAY(1))))_%
+18 SET %=$PIECE(NODE,U,14)
SET %=$SELECT(%="P":"PHARM ",%="A":"ALLERGY",%="U":"UNKNOWN ",1:"")
SET ARRAY(1)=ARRAY(1)_$JUSTIFY(" ",(59-$LENGTH(ARRAY(1))))_%
+19 SET %=$PIECE(NODE,U,6)
SET %=$SELECT(%="o":"OBS",%="h":"HIST",1:"")
SET ARRAY(1)=ARRAY(1)_$JUSTIFY(" ",(68-$LENGTH(ARRAY(1))))_%
TYPE SET %=""
FOR X=1:1:($LENGTH(GMRATYPE))
Begin DoDot:1
+1 SET %=$PIECE("^FOOD^DRUG^OTHER",U,$FIND("FDO",$EXTRACT(GMRATYPE,X)))
+2 SET ARRAY(X)=$GET(ARRAY(X))
+3 SET ARRAY(X)=ARRAY(X)_$JUSTIFY(" ",(74-$LENGTH(ARRAY(X))))_%
+4 QUIT
End DoDot:1
+5 QUIT
