Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: GMRAGUI

GMRAGUI.m

Go to the documentation of this file. 
  1. GMRAGUI ; SLC/DAN - CPRS GUI support ;May 11, 2021@12:02:39
  1.  ;;4.0;Adverse Reaction Tracking;**21,63**;Mar 29, 1996;Build 34
  1.  ;
  1. GETREC(GMRAIEN,GMRARRAY) ;
  1.  ;GMRAIEN  = IEN of object record from file 120.8
  1.  ;GMRARRAY = array specifier ie.^TMP($J,"ART")
  1.  K @GMRARRAY
  1.  N ND,STRING,SSNODE,GMRA,GMRACA,GMRAT,GMRANOR,SSLIM,SSNUM,GMRASSI,GMRASS,GMRADT,Y,GMRAODUZ,COMFLAG,COMNUM,I
  1.  N COMMENTS,GMRACODT,GMRACDUZ,GMRACUS,PREFIX,COMLINE,IDMNOD,IDMLIM,IDMNUM,GMRAIDB,CHMNOD,CHMLIM,CHMNUM,GMRACHM,GMRAVDUZ,GMRAVYN,GMRAOBS,OBSIEN,USRNAM,USR,SEVCOD,SEVER
  1.  S ND=1
  1.  I '$D(GMRAIEN)!('+GMRAIEN) Q
  1.  S GMRA(0)=$G(^GMR(120.8,+GMRAIEN,0)) Q:'$L(GMRA(0))
  1.  S STRING="~CAUSATIVE AGENT" D NEXT
  1.  S GMRACA=$P(GMRA(0),U,2)
  1.  S STRING="d"_GMRACA D NEXT
  1.  S STRING="~ALLERGY TYPE" D NEXT
  1.  S GMRAT=$P(GMRA(0),U,20)
  1.  S STRING="d"_GMRAT_"^"_$TR($$OUTTYPE^GMRAUTL(GMRAT)," ","") D NEXT
  1.  S STRING="~NATURE OF REACTION" D NEXT
  1.  S GMRANOR=$P(GMRA(0),U,14)
  1.  S STRING="d"_GMRANOR_U_$S(GMRANOR="A":"ALLERGY",GMRANOR="R":"ADVERSE REACTION",GMRANOR="P":"PHARMACOLOGICAL",1:"UNKNOWN") D NEXT
  1.  S STRING="~SIGN/SYMPTOMS" D NEXT
  1.  S SSNODE=$G(^GMR(120.8,GMRAIEN,10,0)),SSLIM=$P(SSNODE,U,3),SSNUM=0
  1.  I SSLIM<1 G ORIG
  1. SSLOOP S SSNUM=$O(^GMR(120.8,GMRAIEN,10,SSNUM))
  1.  I SSNUM<1!(SSNUM>SSLIM) G ORIG
  1.  S GMRASSI=$P($G(^GMR(120.8,GMRAIEN,10,SSNUM,0)),U,1),GMRASS=$P($G(^GMRD(120.83,GMRASSI,0)),U,1),GMRADT=$P($G(^GMR(120.8,GMRAIEN,10,SSNUM,0)),U,4)
  1.  S Y=$$FMTE^XLFDT(GMRADT,"D")
  1.  S STRING="i"_GMRASSI_"^"_GMRASS_"^"_GMRADT_"^  "_Y D NEXT G SSLOOP
  1. ORIG S STRING="~ORIGINATOR" D NEXT
  1.  S GMRAODUZ=$P(GMRA(0),U,5)
  1.  S STRING="d"_GMRAODUZ_"^"_$S(GMRAODUZ:$$GET1^DIQ(200,GMRAODUZ_",",".01"),1:"") D NEXT
  1.  S STRING="~ORIGINATED" D NEXT
  1.  S STRING="d"_$P(GMRA(0),U,4) D NEXT
  1.  S COMFLAG=0,COMNUM=0
  1.  S STRING="~COMMENTS" D NEXT
  1.  S COMMENTS=$G(^GMR(120.8,GMRAIEN,26,0)) S:COMMENTS'="" COMFLAG=1
  1. CLOOP1 I COMFLAG D  ;
  1.  .S COMNUM=$O(^GMR(120.8,GMRAIEN,26,COMNUM))
  1.  .Q:COMNUM<1
  1.  .S GMRACODT=$P($G(^GMR(120.8,GMRAIEN,26,COMNUM,0)),U,1)
  1.  . S Y=$$FMTE^XLFDT(GMRACODT,"D")
  1.  . S STRING="tComment Date: "_Y
  1.  .D NEXT
  1.  .S GMRACDUZ=$P($G(^GMR(120.8,GMRAIEN,26,COMNUM,0)),U,2)  S GMRACUS=$S('GMRACDUZ:"",1:$$GET1^DIQ(200,GMRACDUZ_",",".01"))
  1.  .S STRING="tEntered By  : "_GMRACUS
  1.  .D NEXT
  1.  .S PREFIX="tComments    : "
  1.  .S COMLINE=$O(^GMR(120.8,GMRAIEN,26,COMNUM,2,0))
  1. CLOOP2 .D:COMLINE  ;
  1.  ..S STRING=PREFIX_$G(^GMR(120.8,GMRAIEN,26,COMNUM,2,COMLINE,0)) D NEXT
  1.  ..S PREFIX="t              "
  1.  .S COMLINE=$O(^GMR(120.8,GMRAIEN,26,COMNUM,2,COMLINE))
  1.  .I COMLINE>0 G CLOOP2
  1.  .S STRING="t"
  1.  .F I=1:1:60 S STRING=STRING_"-"
  1.  .D NEXT
  1.  I COMNUM>0 G CLOOP1
  1. IDBM S STRING="~ID BAND MARKED" D NEXT
  1.  S IDMNOD=$G(^GMR(120.8,GMRAIEN,14,0)),IDMLIM=$P(IDMNOD,U,3),IDMNUM=0
  1.  I IDMLIM<1 G CHM
  1. IDBLOOP S IDMNUM=$O(^GMR(120.8,GMRAIEN,14,IDMNUM))
  1.  I IDMNUM<1!(IDMNUM>IDMLIM) G CHM
  1.  S GMRAIDB=$P($G(^GMR(120.8,GMRAIEN,14,IDMNUM,0)),U,1)
  1.  S STRING="i"_GMRAIDB D NEXT G IDBLOOP
  1. CHM S STRING="~CHART MARKED" D NEXT
  1.  S CHMNOD=$G(^GMR(120.8,GMRAIEN,13,0)),CHMLIM=$P(CHMNOD,U,3),CHMNUM=0
  1.  I CHMLIM<1 G VER
  1. CHMLOOP S CHMNUM=$O(^GMR(120.8,GMRAIEN,13,CHMNUM))
  1.  I CHMNUM<1!(CHMNUM>CHMLIM) G VER
  1.  S GMRACHM=$P($G(^GMR(120.8,GMRAIEN,13,CHMNUM,0)),U,1)
  1.  S STRING="i"_GMRACHM D NEXT G CHMLOOP
  1. VER S STRING="~VERIFIER" D NEXT
  1.  S GMRAVDUZ=$P(GMRA(0),U,18) I GMRAVDUZ<1 G VFD
  1.  S STRING="d"_GMRAVDUZ_"^"_$$GET1^DIQ(200,GMRAVDUZ_",",".01") D NEXT
  1. VFD S STRING="~VERIFIED" D NEXT
  1.  S GMRAVYN=$P(GMRA(0),U,16)
  1.  S STRING="d"_$S(GMRAVYN=1:"YES",1:"NO")_"^"_$P(GMRA(0),U,17) D NEXT
  1. ERR S STRING="~ENTERED IN ERROR" D NEXT
  1.  S STRING="d"_$S(+$G(^GMR(120.8,GMRAIEN,"ER"))=1:"YES",1:"NO") D NEXT
  1. OBSHIST S STRING="~OBS/HIST" D NEXT
  1.  S GMRAOBS=$P(GMRA(0),U,6)
  1.  S STRING="d"_GMRAOBS_"^"_$S(GMRAOBS="o":"OBSERVED",GMRAOBS="h":"HISTORICAL",1:"") D NEXT
  1.  I GMRAOBS="o" D EN1^GMRAGUI1
  1.  I GMRAOBS="h",(($P(GMRA(0),U,8)'="")!($P(GMRA(0),U,9)'="")) D
  1.  .S STRING="~HISTORICAL" D NEXT
  1.  .S Y=$P(GMRA(0),U,9) X ^DD("DD")
  1.  .S STRING="tDate/Time of Event: "_Y D NEXT
  1.  .S SEVCOD=$P(GMRA(0),U,8)
  1.  .S SEVER=$S(SEVCOD=1:"MILD",SEVCOD=2:"MODERATE",SEVCOD=3:"SEVERE",1:"")
  1.  .S STRING="tSeverity          : "_SEVER D NEXT
  1. EXIT Q
  1. NEXT ;SET ARRAY NODE AND INCREMENT ARRAY COUNTER
  1.  S @GMRARRAY@(ND)=STRING,ND=ND+1,STRING=""
  1.  Q