Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: GMTSUMX

GMTSUMX.m

Go to the documentation of this file.
  1. GMTSUMX ; SLC/KER - Convert Text to Mix Case ; 07/18/2000
  1. ;;2.7;Health Summary;**30,37**;Oct 20, 1995
  1. Q
  1. EN(X) ; Convert Case
  1. N Y,GMTSOK,GMTSOC,GMTSWORD,GMTSPC,GMTSLEAD,GMTSTLR,GMTSTR,GMTSCTR,GMTSPRE
  1. S (GMTSTR,GMTSWORD,GMTSPC)="",X=$$UP(X)
  1. ; Parse by Spaces
  1. F GMTSCTR=1:1:$L(X," ") D
  1. . S GMTSWORD=$P(X," ",GMTSCTR)
  1. . S (GMTSPC,GMTSLEAD,GMTSTLR)=""
  1. . I $E(GMTSWORD,1)="(" S GMTSWORD=$E(GMTSWORD,2,$L(GMTSWORD)),GMTSLEAD="("
  1. . I $E(GMTSWORD,$L(GMTSWORD))=")" S GMTSWORD=$E(GMTSWORD,1,($L(GMTSWORD)-1)),GMTSTLR=")"
  1. . ; String contains special characters
  1. . S GMTSOK=1 F GMTSOC="(",")","-","*","+","{","&","}","[","]","/","\","|",",","'" S:GMTSWORD[GMTSOC GMTSOK=0 Q:'GMTSOK
  1. . I 'GMTSOK D SP
  1. . I GMTSOK D GMTSWORD
  1. . S:GMTSLEAD'="" GMTSWORD=GMTSLEAD_GMTSWORD
  1. . S:GMTSTLR'="" GMTSWORD=GMTSWORD_GMTSTLR
  1. . S GMTSTR=GMTSTR_" "_GMTSWORD
  1. S X=$$TRIM(GMTSTR) Q X
  1. EN2(X) ; Convert Case 2
  1. S X=$$CK($$EN($G(X))) Q X
  1. SP ; Special Characters
  1. ; Special Cases of Special Characters
  1. I $$UP(GMTSWORD)="W/&W/O" S GMTSWORD="w/&w/o" Q
  1. I $$UP(GMTSWORD)="W&W/O" S GMTSWORD="w&w/o" Q
  1. I $$UP(GMTSWORD)="&/OR" S GMTSWORD="&/or" Q
  1. I GMTSWORD="W/O" S GMTSWORD="w/o" Q
  1. N GMTSOK,GMTSWD1,GMTSWD2,GMTSW,GMTSWCTR,GMTSCHR
  1. S GMTSWD1=GMTSWORD,GMTSWD2="",GMTSW=""
  1. F GMTSWCTR=1:1:$L(GMTSWD1) D
  1. . S GMTSCHR=$E(GMTSWD1,GMTSWCTR) I "()-*+{}'&[]/\|,"[GMTSCHR,$L(GMTSW) D Q
  1. . . S GMTSPRE=""
  1. . . S:$E(GMTSW,1,2)="ZZ"&($L(GMTSW)>2) GMTSPRE="ZZ",GMTSW=$E(GMTSW,3,$L(GMTSW))
  1. . . S GMTSW=GMTSPRE_$$CASE(GMTSW,GMTSCHR)
  1. . . S GMTSWD2=GMTSWD2_GMTSW_GMTSCHR,GMTSW=""
  1. . S GMTSW=GMTSW_GMTSCHR
  1. I $L(GMTSW) D
  1. . N GMTSPSN F GMTSPSN=1:1:$L(GMTSW) Q:"()-*+{}'&[]/\|,"'[$E(GMTSW,GMTSPSN)
  1. . N GMTSOW,GMTSLW S GMTSLW=$E(GMTSW,0,(GMTSPSN-1))
  1. . S GMTSOW=$E(GMTSW,GMTSPSN,$L(GMTSW))
  1. . S GMTSPRE="" S:$E(GMTSOW,1,2)="ZZ"&($L(GMTSOW)>2) GMTSPRE="ZZ",GMTSOW=$E(GMTSOW,3,$L(GMTSOW))
  1. . S GMTSOW=GMTSPRE_$$CASE(GMTSOW,$E($G(GMTSWD2),$L($G(GMTSWD2))))
  1. . S GMTSW=GMTSLW_GMTSOW
  1. . S GMTSWD2=GMTSWD2_GMTSW
  1. S GMTSWORD=GMTSWD2 S:GMTSCTR=1 GMTSWORD=$$LD(GMTSWORD)
  1. K GMTSWD1,GMTSWD2
  1. Q
  1. GMTSWORD ; Convert word
  1. S GMTSPRE="" S:$E(GMTSWORD,1,2)="ZZ"&($L(GMTSWORD)>2) GMTSPRE="ZZ",GMTSWORD=$E(GMTSWORD,3,$L(GMTSWORD))
  1. S GMTSWORD=GMTSPRE_$$CASE(GMTSWORD,"")
  1. Q
  1. CASE(X,J) ; Set to Mixed/lower/UPPER case
  1. N GMTSTAG,GMTSRTN,Y S X=$$UP($G(X)),Y="",GMTSTAG=$L(X),GMTSRTN="GMTSUMX2"
  1. S:+GMTSTAG>4 GMTSRTN="GMTSUMX3" S:+GMTSTAG>9 GMTSTAG="M"
  1. Q:+GMTSTAG=0&(GMTSTAG'="M") X
  1. S GMTSRTN=GMTSTAG_"^"_GMTSRTN D @GMTSRTN
  1. I $L(Y) S X=Y Q X
  1. S X=$$MX(X)
  1. Q X
  1. LO(X) Q $TR(X,"ABCDEFGHIJKLMNOPQRSTUVWXYZ","abcdefghijklmnopqrstuvwxyz")
  1. UP(X) Q $TR(X,"abcdefghijklmnopqrstuvwxyz","ABCDEFGHIJKLMNOPQRSTUVWXYZ")
  1. MX(X) Q $TR($E(X,1),"abcdefghijklmnopqrstuvwxyz","ABCDEFGHIJKLMNOPQRSTUVWXYZ")_$TR($E(X,2,$L(X)),"ABCDEFGHIJKLMNOPQRSTUVWXYZ","abcdefghijklmnopqrstuvwxyz")
  1. LD(X) Q $TR($E(X,1),"abcdefghijklmnopqrstuvwxyz","ABCDEFGHIJKLMNOPQRSTUVWXYZ")_$E(X,2,$L(X))
  1. TRIM(X) S X=$G(X) F Q:$E(X,1)'=" " S X=$E(X,2,$L(X))
  1. F Q:$E(X,$L(X))'=" " S X=$E(X,1,($L(X)-1))
  1. Q X
  1. CK(X) ;
  1. S X=$G(X)
  1. F Q:X'["(S)" S X=$P(X,"(S)",1)_"(s)"_$P(X,"(S)",2,299)
  1. F Q:X'[" A " S X=$P(X," A ",1)_" a "_$P(X," A ",2,229)
  1. I X["Class a" F Q:X'["Class a" S X=$P(X,"Class a",1)_"Class A"_$P(X,"Class a",2,229)
  1. I X["Type a" F Q:X'["Type a" S X=$P(X,"Type a",1)_"Type A"_$P(X,"Type a",2,229)
  1. F Q:X'["'S" S X=$P(X,"'S",1)_"'s"_$P(X,"'S",2,229)
  1. I X["mg Diet" F Q:X'["mg Diet" S X=$P(X,"mg Diet",1)_"MG Diet"_$P(X,"mg Diet",2,229)
  1. I X["LO-Fat" F Q:X'["LO-Fat" S X=$P(X,"LO-Fat",1)_"Lo-Fat"_$P(X,"LO-Fat",2,229)
  1. I $E(X,1)="'" S X="'"_$$LD($E(X,2,$L(X)))
  1. S X=$TR($E(X,1),"abcdefghijklmnopqrstuvwxyz","ABCDEFGHIJKLMNOPQRSTUVWXYZ")_$E(X,2,$L(X))
  1. Q X
  1. TYPES ;
  1. N GMTSIEN S GMTSIEN=0 F S GMTSIEN=$O(^GMT(142,GMTSIEN)) Q:+GMTSIEN=0 D
  1. . N GMTSTXT S GMTSTXT=$P($G(^GMT(142,GMTSIEN,0)),"^",1)
  1. . I $L(GMTSTXT) W !!,GMTSTXT,!,$$EN^GMTSUMX(GMTSTXT)
  1. Q