GMV23PST ;HOIFO/FT-POST INSTALLATION FOR GMRV*5*23 ; 03/24/09 16:01
;;5.0;GEN. MED. REC. - VITALS;**23**;Oct 31, 2002;Build 25
;
; This routine uses the following IAs:
; #2263 - XPAR calls (supported)
; #4835 - Add RPCS to OR CPRS GUI CHART option (private)
; #10141 - XPDUTL calls (supported)
;
EN ; Main entry point
D XPAR,DLL,ADDRPC
Q
XPAR ; Setup preliminary parameters. This subroutine is called during the
; KIDS installation process.
;
; Variables:
; GMV: [Private] Scratch
; GMVGUI: [Private] Current version of GUI being installed
; GMVLST: [Private] Scratch List
;
; NEW private variables
N GMV,GMVGUI,GMVLST
; Announce my intentions
D BMES^XPDUTL("Updating system parameters.")
; Set current client version
S GMVGUI="5.0.23.8"
; Deactivate all previous versions from XPAR
D GETLST^XPAR(.GMVLST,"SYS","GMV GUI VERSION")
F GMV=0:0 S GMV=$O(GMVLST(GMV)) Q:'GMV D
.D EN^XPAR("SYS","GMV GUI VERSION",$P(GMVLST(GMV),"^",1),0)
.Q
; Add and/or activate current client versions
D EN^XPAR("SYS","GMV GUI VERSION","VITALS.EXE:"_GMVGUI,1)
D EN^XPAR("SYS","GMV GUI VERSION","VITALSMANAGER.EXE:"_GMVGUI,1)
Q
DLL ;
; Variables:
; GMV: [Private] Scratch
; GMVDLL: [Private] Current version of DLL being installed
; GMVLST: [Private] Scratch List
;
; New private variables
N GMV,GMVDLL,GMVLST
; Announce my intentions
D BMES^XPDUTL("Updating DLL parameter.")
; Deactivate all previous versions from XPAR
D GETLST^XPAR(.GMVLST,"SYS","GMV DLL VERSION")
F GMV=0:0 S GMV=$O(GMVLST(GMV)) Q:'GMV D
.D EN^XPAR("SYS","GMV DLL VERSION",$P(GMVLST(GMV),"^",1),0)
; Add and/or activate current client versions
S GMVDLL="GMV_VITALSVIEWENTER.DLL:v. 04/07/09 16:30" ;patch 23
D EN^XPAR("SYS","GMV DLL VERSION",GMVDLL,1)
S GMVDLL="GMV_VITALSVIEWENTER.DLL:v. 08/11/09 15:00" ;patch 23
D EN^XPAR("SYS","GMV DLL VERSION",GMVDLL,1)
Q
ADDRPC ; Add GMV RPC(s) to CPRS option
N GMVDA,GMVDA1,GMVERR,GMVFDA,GMVIEN,GMVMSG,GMVNAME,GMVNODE,GMVTEST,GMVX
K ^TMP($J),^TMP("GMV 23PST",$J)
S GMVDA=$$FIND1^DIC(19,"","O","OR CPRS GUI CHART","B","","GMVERR")
I 'GMVDA D Q
.S GMVMSG(1)="Cannot find the 'OR CPRS GUI CHART' option."
.S GMVMSG(2)="Cannot add the RPC(s) needed. Please log a Remedy Ticket."
.D EN^DDIOL(.GMVMSG,"","!?5")
.Q
; Get list of existing RPC(s) for OR CPRS GUI CHART option
D GETS^DIQ(19,GMVDA,"320*","I","^TMP($J)","GMVERR")
S GMVX=""
F S GMVX=$O(^TMP($J,19.05,GMVX)) Q:GMVX="" D
.S GMVIEN=+$G(^TMP($J,19.05,GMVX,.01,"I"))
.Q:'GMVIEN
.S ^TMP("GMV 23PST",$J,GMVIEN)=""
.Q
K GMVERR,GMVX
; get GMV rpc(s) from table
F GMVX=1:1 S GMVNODE=$T(RPCLIST+GMVX) Q:$P(GMVNODE,";",3)="" D
.S GMVNAME=$P(GMVNODE,";",3)
.Q:GMVNAME=""
.K GMVERR
.S GMVDA1=$$FIND1^DIC(8994,"","O",GMVNAME,"B","","GMVERR")
.Q:'GMVDA1
.Q:$D(^TMP("GMV 23PST",$J,GMVDA1)) ;rpc is already there
.K GMVERR,GMVFDA,GMVIEN
.S GMVFDA(19.05,"+1,"_GMVDA_",",.01)=GMVDA1
.D UPDATE^DIE("","GMVFDA","GMVIEN","GMVERR")
.Q
K ^TMP($J),^TMP("GMV 23PST",$J)
Q
RPCLIST ; List of GMV RPC(s) to add to OR CPRS GUI CHART option
;;GMV CLOSEST READING
Q
--- Routine Detail --- with STRUCTURED ROUTINE LISTING ---[H[J[2J[HGMV23PST 3220 printed Dec 13, 2024@01:58:05 Page 2
GMV23PST ;HOIFO/FT-POST INSTALLATION FOR GMRV*5*23 ; 03/24/09 16:01
+1 ;;5.0;GEN. MED. REC. - VITALS;**23**;Oct 31, 2002;Build 25
+2 ;
+3 ; This routine uses the following IAs:
+4 ; #2263 - XPAR calls (supported)
+5 ; #4835 - Add RPCS to OR CPRS GUI CHART option (private)
+6 ; #10141 - XPDUTL calls (supported)
+7 ;
EN ; Main entry point
+1 DO XPAR
DO DLL
DO ADDRPC
+2 QUIT
XPAR ; Setup preliminary parameters. This subroutine is called during the
+1 ; KIDS installation process.
+2 ;
+3 ; Variables:
+4 ; GMV: [Private] Scratch
+5 ; GMVGUI: [Private] Current version of GUI being installed
+6 ; GMVLST: [Private] Scratch List
+7 ;
+8 ; NEW private variables
+9 NEW GMV,GMVGUI,GMVLST
+10 ; Announce my intentions
+11 DO BMES^XPDUTL("Updating system parameters.")
+12 ; Set current client version
+13 SET GMVGUI="5.0.23.8"
+14 ; Deactivate all previous versions from XPAR
+15 DO GETLST^XPAR(.GMVLST,"SYS","GMV GUI VERSION")
+16 FOR GMV=0:0
SET GMV=$ORDER(GMVLST(GMV))
if 'GMV
QUIT
Begin DoDot:1
+17 DO EN^XPAR("SYS","GMV GUI VERSION",$PIECE(GMVLST(GMV),"^",1),0)
+18 QUIT
End DoDot:1
+19 ; Add and/or activate current client versions
+20 DO EN^XPAR("SYS","GMV GUI VERSION","VITALS.EXE:"_GMVGUI,1)
+21 DO EN^XPAR("SYS","GMV GUI VERSION","VITALSMANAGER.EXE:"_GMVGUI,1)
+22 QUIT
DLL ;
+1 ; Variables:
+2 ; GMV: [Private] Scratch
+3 ; GMVDLL: [Private] Current version of DLL being installed
+4 ; GMVLST: [Private] Scratch List
+5 ;
+6 ; New private variables
+7 NEW GMV,GMVDLL,GMVLST
+8 ; Announce my intentions
+9 DO BMES^XPDUTL("Updating DLL parameter.")
+10 ; Deactivate all previous versions from XPAR
+11 DO GETLST^XPAR(.GMVLST,"SYS","GMV DLL VERSION")
+12 FOR GMV=0:0
SET GMV=$ORDER(GMVLST(GMV))
if 'GMV
QUIT
Begin DoDot:1
+13 DO EN^XPAR("SYS","GMV DLL VERSION",$PIECE(GMVLST(GMV),"^",1),0)
End DoDot:1
+14 ; Add and/or activate current client versions
+15 ;patch 23
SET GMVDLL="GMV_VITALSVIEWENTER.DLL:v. 04/07/09 16:30"
+16 DO EN^XPAR("SYS","GMV DLL VERSION",GMVDLL,1)
+17 ;patch 23
SET GMVDLL="GMV_VITALSVIEWENTER.DLL:v. 08/11/09 15:00"
+18 DO EN^XPAR("SYS","GMV DLL VERSION",GMVDLL,1)
+19 QUIT
ADDRPC ; Add GMV RPC(s) to CPRS option
+1 NEW GMVDA,GMVDA1,GMVERR,GMVFDA,GMVIEN,GMVMSG,GMVNAME,GMVNODE,GMVTEST,GMVX
+2 KILL ^TMP($JOB),^TMP("GMV 23PST",$JOB)
+3 SET GMVDA=$$FIND1^DIC(19,"","O","OR CPRS GUI CHART","B","","GMVERR")
+4 IF 'GMVDA
Begin DoDot:1
+5 SET GMVMSG(1)="Cannot find the 'OR CPRS GUI CHART' option."
+6 SET GMVMSG(2)="Cannot add the RPC(s) needed. Please log a Remedy Ticket."
+7 DO EN^DDIOL(.GMVMSG,"","!?5")
+8 QUIT
End DoDot:1
QUIT
+9 ; Get list of existing RPC(s) for OR CPRS GUI CHART option
+10 DO GETS^DIQ(19,GMVDA,"320*","I","^TMP($J)","GMVERR")
+11 SET GMVX=""
+12 FOR
SET GMVX=$ORDER(^TMP($JOB,19.05,GMVX))
if GMVX=""
QUIT
Begin DoDot:1
+13 SET GMVIEN=+$GET(^TMP($JOB,19.05,GMVX,.01,"I"))
+14 if 'GMVIEN
QUIT
+15 SET ^TMP("GMV 23PST",$JOB,GMVIEN)=""
+16 QUIT
End DoDot:1
+17 KILL GMVERR,GMVX
+18 ; get GMV rpc(s) from table
+19 FOR GMVX=1:1
SET GMVNODE=$TEXT(RPCLIST+GMVX)
if $PIECE(GMVNODE,";",3)=""
QUIT
Begin DoDot:1
+20 SET GMVNAME=$PIECE(GMVNODE,";",3)
+21 if GMVNAME=""
QUIT
+22 KILL GMVERR
+23 SET GMVDA1=$$FIND1^DIC(8994,"","O",GMVNAME,"B","","GMVERR")
+24 if 'GMVDA1
QUIT
+25 ;rpc is already there
if $DATA(^TMP("GMV 23PST",$JOB,GMVDA1))
QUIT
+26 KILL GMVERR,GMVFDA,GMVIEN
+27 SET GMVFDA(19.05,"+1,"_GMVDA_",",.01)=GMVDA1
+28 DO UPDATE^DIE("","GMVFDA","GMVIEN","GMVERR")
+29 QUIT
End DoDot:1
+30 KILL ^TMP($JOB),^TMP("GMV 23PST",$JOB)
+31 QUIT
RPCLIST ; List of GMV RPC(s) to add to OR CPRS GUI CHART option
+1 ;;GMV CLOSEST READING
+2 QUIT
