Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: GMV23PST

GMV23PST.m

Go to the documentation of this file. 
  1. GMV23PST ;HOIFO/FT-POST INSTALLATION FOR GMRV*5*23 ; 03/24/09 16:01
  1.  ;;5.0;GEN. MED. REC. - VITALS;**23**;Oct 31, 2002;Build 25
  1.  ;
  1.  ; This routine uses the following IAs:
  1.  ; #2263  - XPAR calls                           (supported)
  1.  ; #4835  - Add RPCS to OR CPRS GUI CHART option (private)
  1.  ; #10141 - XPDUTL calls                         (supported)
  1.  ;
  1. EN ; Main entry point
  1.  D XPAR,DLL,ADDRPC
  1.  Q
  1. XPAR ; Setup preliminary parameters. This subroutine is called during the
  1.  ; KIDS installation process.
  1.  ;
  1.  ; Variables:
  1.  ;  GMV:    [Private] Scratch
  1.  ;  GMVGUI: [Private] Current version of GUI being installed
  1.  ;  GMVLST: [Private] Scratch List
  1.  ;
  1.  ; NEW private variables
  1.  N GMV,GMVGUI,GMVLST
  1.  ; Announce my intentions
  1.  D BMES^XPDUTL("Updating system parameters.")
  1.  ; Set current client version
  1.  S GMVGUI="5.0.23.8"
  1.  ; Deactivate all previous versions from XPAR
  1.  D GETLST^XPAR(.GMVLST,"SYS","GMV GUI VERSION")
  1.  F GMV=0:0 S GMV=$O(GMVLST(GMV)) Q:'GMV  D
  1.  .D EN^XPAR("SYS","GMV GUI VERSION",$P(GMVLST(GMV),"^",1),0)
  1.  .Q
  1.  ; Add and/or activate current client versions
  1.  D EN^XPAR("SYS","GMV GUI VERSION","VITALS.EXE:"_GMVGUI,1)
  1.  D EN^XPAR("SYS","GMV GUI VERSION","VITALSMANAGER.EXE:"_GMVGUI,1)
  1.  Q
  1. DLL ;
  1.  ; Variables:
  1.  ;  GMV:    [Private] Scratch
  1.  ;  GMVDLL: [Private] Current version of DLL being installed
  1.  ;  GMVLST: [Private] Scratch List
  1.  ;
  1.  ; New private variables
  1.  N GMV,GMVDLL,GMVLST
  1.  ; Announce my intentions
  1.  D BMES^XPDUTL("Updating DLL parameter.")
  1.  ; Deactivate all previous versions from XPAR
  1.  D GETLST^XPAR(.GMVLST,"SYS","GMV DLL VERSION")
  1.  F GMV=0:0 S GMV=$O(GMVLST(GMV)) Q:'GMV  D
  1.  .D EN^XPAR("SYS","GMV DLL VERSION",$P(GMVLST(GMV),"^",1),0)
  1.  ; Add and/or activate current client versions
  1.  S GMVDLL="GMV_VITALSVIEWENTER.DLL:v. 04/07/09 16:30" ;patch 23
  1.  D EN^XPAR("SYS","GMV DLL VERSION",GMVDLL,1)
  1.  S GMVDLL="GMV_VITALSVIEWENTER.DLL:v. 08/11/09 15:00" ;patch 23
  1.  D EN^XPAR("SYS","GMV DLL VERSION",GMVDLL,1)
  1.  Q
  1. ADDRPC ; Add GMV RPC(s) to CPRS option
  1.  N GMVDA,GMVDA1,GMVERR,GMVFDA,GMVIEN,GMVMSG,GMVNAME,GMVNODE,GMVTEST,GMVX
  1.  K ^TMP($J),^TMP("GMV 23PST",$J)
  1.  S GMVDA=$$FIND1^DIC(19,"","O","OR CPRS GUI CHART","B","","GMVERR")
  1.  I 'GMVDA D  Q
  1.  .S GMVMSG(1)="Cannot find the 'OR CPRS GUI CHART' option."
  1.  .S GMVMSG(2)="Cannot add the RPC(s) needed. Please log a Remedy Ticket."
  1.  .D EN^DDIOL(.GMVMSG,"","!?5")
  1.  .Q
  1.  ; Get list of existing RPC(s) for OR CPRS GUI CHART option
  1.  D GETS^DIQ(19,GMVDA,"320*","I","^TMP($J)","GMVERR")
  1.  S GMVX=""
  1.  F  S GMVX=$O(^TMP($J,19.05,GMVX)) Q:GMVX=""  D
  1.  .S GMVIEN=+$G(^TMP($J,19.05,GMVX,.01,"I"))
  1.  .Q:'GMVIEN
  1.  .S ^TMP("GMV 23PST",$J,GMVIEN)=""
  1.  .Q
  1.  K GMVERR,GMVX
  1.  ; get GMV rpc(s) from table
  1.  F GMVX=1:1 S GMVNODE=$T(RPCLIST+GMVX) Q:$P(GMVNODE,";",3)=""  D
  1.  .S GMVNAME=$P(GMVNODE,";",3)
  1.  .Q:GMVNAME=""
  1.  .K GMVERR
  1.  .S GMVDA1=$$FIND1^DIC(8994,"","O",GMVNAME,"B","","GMVERR")
  1.  .Q:'GMVDA1
  1.  .Q:$D(^TMP("GMV 23PST",$J,GMVDA1))  ;rpc is already there
  1.  .K GMVERR,GMVFDA,GMVIEN
  1.  .S GMVFDA(19.05,"+1,"_GMVDA_",",.01)=GMVDA1
  1.  .D UPDATE^DIE("","GMVFDA","GMVIEN","GMVERR")
  1.  .Q
  1.  K ^TMP($J),^TMP("GMV 23PST",$J)
  1.  Q
  1. RPCLIST ; List of GMV RPC(s) to add to OR CPRS GUI CHART option 
  1.  ;;GMV CLOSEST READING
  1.  Q