Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: GMVDCCNV

GMVDCCNV.m

Go to the documentation of this file.
  1. GMVDCCNV ;HOIFO/DAD,FT-VITALS COMPONENT: CONVERT UNITS ;9/29/00 09:15
  1. ;;5.0;GEN. MED. REC. - VITALS;;Oct 31, 2002
  1. ;
  1. ; This routine uses the following IAs:
  1. ; #10143 - XLFMSMT calls (supported)
  1. ;
  1. CNV(GMVALUE,GMVMSYS,GMVOPER,GMVTYPE) ;
  1. ; Unit conversion
  1. ; Input:
  1. ; GMVALUE = The value to be converted
  1. ; GMVMSYS = The desired Measurement system
  1. ; GMVOPER = The operation taking place (G - Get data, S - Save data)
  1. ; GMVTYPE = The Vital Type abbreviation
  1. ; Output:
  1. ; The measurement expressed in the desired units
  1. I $G(GMVALUE)]"",$G(GMVMSYS)]"",$G(GMVOPER)]"",$G(GMVTYPE)]"" D
  1. . I "^T^"[(U_GMVTYPE_U) S GMVALUE=$$TMP(GMVALUE,GMVMSYS,GMVOPER)
  1. . I "^WT^"[(U_GMVTYPE_U) S GMVALUE=$$WEI(GMVALUE,GMVMSYS,GMVOPER)
  1. . I "^CVP^"[(U_GMVTYPE_U) S GMVALUE=$$CVP(GMVALUE,GMVMSYS,GMVOPER)
  1. . I "^HT^AG^FH^HC^CG^"[(U_GMVTYPE_U) S GMVALUE=$$LEN(GMVALUE,GMVMSYS,GMVOPER)
  1. . Q
  1. Q $G(GMVALUE)
  1. ;
  1. TMP(GMVALUE,GMVMSYS,GMVOPER) ;
  1. ; Temperature conversion
  1. ; Input:
  1. ; GMVALUE = The value to be converted
  1. ; GMVMSYS = The desired Measurement system
  1. ; GMVOPER = The operation taking place (G - Get data, S - Save data)
  1. ; Output:
  1. ; The measurement expressed in the desired units
  1. I GMVMSYS="M" D
  1. . N GMVFR,GMVTO
  1. . I GMVOPER="G" S GMVFR="F",GMVTO="C"
  1. . I GMVOPER="S" S GMVFR="C",GMVTO="F"
  1. . S GMVALUE=$P($$TEMP^XLFMSMT(GMVALUE,GMVFR,GMVTO)," ")
  1. . Q
  1. Q GMVALUE
  1. ;
  1. LEN(GMVALUE,GMVMSYS,GMVOPER) ;
  1. ; Length conversion
  1. ; Input:
  1. ; GMVALUE = The value to be converted
  1. ; GMVMSYS = The desired Measurement system
  1. ; GMVOPER = The operation taking place (G - Get data, S - Save data)
  1. ; Output:
  1. ; The measurement expressed in the desired units
  1. I GMVMSYS="M" D
  1. . N GMVFR,GMVTO
  1. . I GMVOPER="G" S GMVFR="IN",GMVTO="CM"
  1. . I GMVOPER="S" S GMVFR="CM",GMVTO="IN"
  1. . S GMVALUE=$P($$LENGTH^XLFMSMT(GMVALUE,GMVFR,GMVTO)," ")
  1. . Q
  1. Q GMVALUE
  1. ;
  1. WEI(GMVALUE,GMVMSYS,GMVOPER) ;
  1. ; Weight conversion
  1. ; Input:
  1. ; GMVALUE = The value to be converted
  1. ; GMVMSYS = The desired Measurement system
  1. ; GMVOPER = The operation taking place (G - Get data, S - Save data)
  1. ; Output:
  1. ; The measurement expressed in the desired units
  1. I GMVMSYS="M" D
  1. . N GMVFR,GMVTO
  1. . I GMVOPER="G" S GMVFR="LB",GMVTO="KG"
  1. . I GMVOPER="S" S GMVFR="KG",GMVTO="LB"
  1. . S GMVALUE=$P($$WEIGHT^XLFMSMT(GMVALUE,GMVFR,GMVTO)," ")
  1. . Q
  1. Q GMVALUE
  1. ;
  1. CVP(GMVALUE,GMVMSYS,GMVOPER) ;
  1. ; Central Venous Pressure conversion
  1. ; Input:
  1. ; GMVALUE = The value to be converted
  1. ; GMVMSYS = The desired Measurement system
  1. ; GMVOPER = The operation taking place (G - Get data, S - Save data)
  1. ; Output:
  1. ; The measurement expressed in the desired units
  1. I GMVMSYS="M" D
  1. . I GMVOPER="G" S GMVALUE=$J(GMVALUE/1.36,0,3)
  1. . I GMVOPER="S" S GMVALUE=$J(GMVALUE*1.36,0,3)
  1. . Q
  1. Q GMVALUE