Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: GMVER1

GMVER1.m

Go to the documentation of this file. 
  1. GMVER1 ;HOIFO/RM,YH,FT-ENTERED IN ERROR FOR A PATIENT & DATE RANGE ;12/12/01  12:36
  1.  ;;5.0;GEN. MED. REC. - VITALS;;Oct 31, 2002
  1.  ;
  1.  ; This routine uses the following IAs:
  1.  ; #10104 - ^XLFSTR calls          (supported)
  1.  ; #10103 - ^XLFDT calls           (supported)
  1.  ;
  1. EN1(RESULT,GMVDFN,GMVBEG,GMVEND) ; [RPC entry point]
  1.  ; Returns Entered in Error records for a date range
  1.  ; Input:
  1.  ;  RESULT   = Where data is returned (closed array reference) (Required)
  1.  ;  GMVDFN   = A pointer to the Patient file (#2) (Required)
  1.  ;  GMVBEG   = Beginning date for all vitals
  1.  ;  GMVEND   = Ending    date for all vitals
  1.  ;
  1.  ; Output:
  1.  ;  RESULT() = TMP global address with the nodes of report text
  1.  ;  The TMP global nodes are:
  1.  ;  ^TMP($J,GMRDATE,GMRVITY,GMRVDA,1)=date/time of the error, Vital
  1.  ;                                    type, name of user
  1.  ;  ^TMP($J,GMRDATE,GMRVITY,GMRVDA,2)=error reason
  1.  ;  ^TMP($J,GMRDATE,GMRVITY,GMRVDA,3)=revised data, if any (optional)
  1.  ;  ^TMP($J,GMRDATE,GMRVITY,GMRVDA,4)=the incorrect data
  1.  ;
  1.  S GMRVITY=0
  1.  K ^TMP($J,"LIST"),^TMP($J,"ERRORS")
  1.  F  S GMRVITY=$O(^GMR(120.5,"AA",GMVDFN,GMRVITY)) Q:GMRVITY'>0  F GMRVDT=0:0 S GMRVDT=$O(^GMR(120.5,"AA",GMVDFN,GMRVITY,GMRVDT)) Q:GMRVDT'>0  S GMRVDATE=9999999-GMRVDT I GMRVDATE'<GMVBEG,GMRVDATE'>GMVEND D SORT
  1.  S GMRDATE=0
  1.  F  S GMRDATE=$O(^TMP($J,"LIST",GMRDATE)) Q:GMRDATE'>0  F GMRVITY=0:0 S GMRVITY=$O(^TMP($J,"LIST",GMRDATE,GMRVITY)) Q:GMRVITY'>0  F GMRVDA=0:0 S GMRVDA=$O(^TMP($J,"LIST",GMRDATE,GMRVITY,GMRVDA)) Q:GMRVDA'>0  D WRT
  1. Q ; KILL VARIABLES
  1.  K BADRATE,GOODRATE,GMRDAT,GMRDATE,GMRPR,GMRVDA,GMRVDATE,GMRVDT,GMRVERR,GMVEND,GMRVITY,GMVBEG,GMRVX,GMRP,GMRTYPE
  1.  K GREASON,GMRZZ,GMRVARY,GMRQUAL,GMRVPO,GMVNODE,GMVSPACE,^TMP($J,"LIST")
  1.  I '$D(^TMP($J,"ERRORS")) S ^TMP($J,"ERRORS",0)="No data for the time period indicated."
  1.  S RESULT=$NA(^TMP($J,"ERRORS"))
  1.  Q
  1. SORT ; loop through the AA x-ref and find patient entries marked as
  1.  ; entered in error (i.e., node 2 exists).
  1.  S GMRVERR=0
  1.  F  S GMRVERR=$O(^GMR(120.5,"AA",GMVDFN,GMRVITY,GMRVDT,GMRVERR)) Q:GMRVERR'>0  I '$D(^GMR(120.5,GMRVERR,2)) Q
  1.  S GMRVDA=0
  1.  F  S GMRVDA=$O(^GMR(120.5,"AA",GMVDFN,GMRVITY,GMRVDT,GMRVDA)) Q:GMRVDA'>0  I $D(^GMR(120.5,GMRVDA,2)) S ^TMP($J,"LIST",GMRVDATE,GMRVITY,GMRVDA)=GMRVERR
  1.  Q
  1. WRT ;
  1.  S GMRVERR=^TMP($J,"LIST",GMRDATE,GMRVITY,GMRVDA)
  1.  S GMRDAT("GOOD")=$S($D(^GMR(120.5,+GMRVERR,0)):^(0),1:"")
  1.  I $D(^GMR(120.5,+GMRVERR,0)) D
  1.  .K GMRVX
  1.  .S GMRVX=$P(^GMRD(120.51,GMRVITY,0),"^",2)
  1.  .S GMRVX(0)=$P(GMRDAT("GOOD"),"^",8)
  1.  .D:GMRVX(0)>0!(GMRVX(0)=0) EN1^GMVSAS0
  1.  .S GMRVX(1)=$S('$D(GMRVX(1)):"",'GMRVX(1):"",1:"*")
  1.  .S GMRVX(0)=$$WRTDAT(GMRVX,GMRVX(0))
  1.  .S GMRZZ=""
  1.  .I $P($G(^GMR(120.5,GMRVERR,5,0)),"^",4)>0 D
  1.  ..K GMRVARY
  1.  ..S GMRVARY=""
  1.  ..D CHAR^GMVCHAR(GMRVERR,.GMRVARY,GMRVITY)
  1.  ..S GMRZZ=$$WRITECH^GMVCHAR(GMRVERR,.GMRVARY,9)
  1.  ..S:GMRZZ'=""&(GMRVX'="PO2") GMRZZ=" ("_GMRZZ_")"
  1.  ..Q
  1.  . I GMRVX="P" D
  1.  ..I GMRZZ'="",GMRVX(0)=1 S:$F(GMRZZ,"DORSALIS PEDIS")>0 GMRVX(1)=""
  1.  ..I GMRZZ'="",GMRVX(0)=0 S:$F(GMRZZ,"DORSALIS PEDIS")>0 GMRVX(1)="*"
  1.  ..Q
  1.  .S GMRVPO=$P(^GMR(120.5,GMRVERR,0),"^",10)
  1.  .S $P(GMRDAT("GOOD"),"^",8)=GMRVX(0)_GMRVX(1)_$S(GMRVPO'="":" with supplemental O2 "_$S(GMRVPO["l/min":$P(GMRVPO," l/min")_"L/min",1:"")_$S(GMRVPO["l/min":$P(GMRVPO," l/min",2),1:GMRVPO),1:"")_$S(GMRZZ'=""&(GMRVX="PO2"):" via ",1:"")_GMRZZ
  1.  .Q
  1.  I $D(^GMR(120.5,+GMRVDA,0)) D
  1.  .S GMRDAT("BAD")=$S($D(^GMR(120.5,+GMRVDA,0)):^(0),1:"")
  1.  .K GMRVX,GMRVX(0),GMRVX(1)
  1.  .S GMRVX=$P(^GMRD(120.51,GMRVITY,0),"^",2)
  1.  .S GMRVX(0)=$P(GMRDAT("BAD"),"^",8)
  1.  .D:GMRVX(0)>0 EN1^GMVSAS0
  1.  .S GMRVX(1)=$S('$D(GMRVX(1)):"",'GMRVX(1):"",1:"*")
  1.  .S GMRVX(0)=$$WRTDAT(GMRVX,GMRVX(0))
  1.  .S GMRZZ=""
  1.  .I $P($G(^GMR(120.5,GMRVDA,5,0)),"^",4)>0 D
  1.  ..K GMRVARY
  1.  ..S GMRVARY=""
  1.  ..D CHAR^GMVCHAR(GMRVDA,.GMRVARY,GMRVITY)
  1.  ..S GMRZZ=$$WRITECH^GMVCHAR(GMRVDA,.GMRVARY,9)
  1.  ..S:GMRZZ'=""&(GMRVX'="PO2") GMRZZ=" ("_GMRZZ_")"
  1.  ..Q
  1.  .I GMRVX="P" D
  1.  ..I GMRZZ'="",GMRVX(0)=1 S:$F(GMRZZ,"DORSALIS PEDIS")>0 GMRVX(1)=""
  1.  ..I GMRZZ'="",GMRVX(0)=0 S:$F(GMRZZ,"DORSALIS PEDIS")>0 GMRVX(1)="*"
  1.  ..Q
  1.  .S GMRVPO=$P(^GMR(120.5,GMRVDA,0),"^",10)
  1.  .S $P(GMRDAT("BAD"),"^",8)=GMRVX(0)_GMRVX(1)_$S(GMRVPO'="":" with supplemental O2 "_$S(GMRVPO["l/min":$P(GMRVPO," l/min")_"L/min",1:"")_$S(GMRVPO["l/min":$P(GMRVPO," l/min",2),1:GMRVPO),1:"")_$S(GMRZZ'=""&(GMRVX="PO2"):" via ",1:"")_GMRZZ
  1.  .S GREASON="" D ERREASON
  1.  S GMRPR("VSDT")=$$FMTE^XLFDT(GMRDATE)
  1.  S GMRPR("ENUS")=$E($$PERSON^GMVUTL1(+$P(GMRDAT("BAD"),U,6)),1,21)
  1.  S GMRPR("TYPE")=$S(GMRVITY="":"",$D(^GMRD(120.51,GMRVITY,0)):$P(^(0),"^"),1:"")
  1.  S GMVNODE=""
  1.  S GMVSPACE=$$REPEAT^XLFSTR(" ",79) ;line of spaces
  1.  S GMVNODE=GMRPR("VSDT")
  1.  S GMVNODE=GMVNODE_$$FILLER^GMVUTL1(21,$L(GMVNODE),GMVSPACE)_GMRPR("TYPE")
  1.  S GMVNODE=GMVNODE_$$FILLER^GMVUTL1(58,$L(GMVNODE),GMVSPACE)_GMRPR("ENUS")
  1.  S ^TMP($J,"ERRORS",GMRDATE,GMRVITY,GMRVDA,1)=GMVNODE
  1.  S ^TMP($J,"ERRORS",GMRDATE,GMRVITY,GMRVDA,2)="   Reason: "_GREASON
  1.  S GMVNODE=""
  1.  I $G(GMRVERR)>0 S GMVNODE="   (Revised)  "_$P(GMRDAT("GOOD"),"^",8) D
  1.  .I GMRVX="PN" D
  1.  ..S GOODRATE=$P(GMRDAT("GOOD"),U,8)
  1.  ..S GMVNODE=GMVNODE_$S(GOODRATE=0:" No pain",GOODRATE=10:" Worst imaginable pain",GOODRATE=99:" Unable to respond",1:"")
  1.  ..Q
  1.  .Q
  1.  I $L(GMVNODE)>0 D
  1.  .S ^TMP($J,"ERRORS",GMRDATE,GMRVITY,GMRVDA,3)=GMVNODE
  1.  .Q
  1.  S GMVNODE=""
  1.  I GMRVDA>0 S GMVNODE="   (Bad data)  "_$P(GMRDAT("BAD"),"^",8) D
  1.  .I GMRVX="PN" D
  1.  ..S BADRATE=$P(GMRDAT("BAD"),U,8)
  1.  ..S GMVNODE=GMVNODE_$S(BADRATE=0:" No pain",BADRATE=10:" Worst imaginable pain",BADRATE=99:" Unable to respond",1:"")
  1.  ..Q
  1.  .Q
  1.  I $L(GMVNODE)>0 D
  1.  .S ^TMP($J,"ERRORS",GMRDATE,GMRVITY,GMRVDA,4)=GMVNODE
  1.  .Q
  1.  Q
  1. ERREASON ;ERROR REASON
  1.  Q:'$D(^GMR(120.5,+GMRVDA,2.1))
  1.  S GER=0
  1.  F  S GER=$O(^GMR(120.5,+GMRVDA,2.1,GER)) Q:GER'>0  S GER(1)=+$G(^GMR(120.5,+GMRVDA,2.1,GER,0)) D
  1.  .S GER(2)=$S(GER(1)=1:"incorrect date/time",GER(1)=2:"incorrect reading",GER(1)=3:"incorrect patient",GER(1)=4:"invalid record",1:"")
  1.  .I GER(2)'="" S GREASON=GREASON_$S(GREASON'="":", ",1:"")_GER(2)
  1.  .Q
  1.  K GER
  1.  Q
  1. WRTDAT(TYPE,DATA) ;
  1.  I '((TYPE="BP")!(TYPE="P")!(TYPE="R")),DATA>0 D @($$UP^XLFSTR(TYPE))
  1.  Q DATA
  1. T S DATA=DATA_" F  ("_$J(+DATA-32*5/9,0,1)_" C)" Q
  1. WT S DATA=DATA_" lb  ("_$J(DATA/2.2,0,2)_" kg)" Q
  1. HT S DATA=$S(DATA\12:DATA\12_" ft ",1:"")_$S(DATA#12:DATA#12_" in",1:"")_" ("_$J(DATA*2.54,0,2)_" cm)" Q
  1. CG S DATA=DATA_" in ("_$J(+DATA/.3937,0,2)_" cm)" Q
  1. CVP S DATA=DATA_" cmH2O ("_$J(DATA/1.36,0,1)_" mmHg)" Q
  1. PO2 S DATA=DATA_"%" Q
  1. PN I DATA=0 S DATA=DATA_" No pain " Q
  1.  I DATA=99 S DATA=DATA_" Unable to respond " Q
  1.  I DATA=10 S DATA=DATA_" Worst imaginable pain " Q
  1.  Q