Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: GMVGGR2

GMVGGR2.m

Go to the documentation of this file.
  1. GMVGGR2 ;HOIFO/YH,FT-SET ^TMP($J) GLOBAL ;6/6/07
  1. ;;5.0;GEN. MED. REC. - VITALS;**3,23**;Oct 31, 2002;Build 25
  1. ;CONTINUTATION OF GMVGGR1
  1. ;
  1. ; This routine uses the following IAs:
  1. ; #10061 - ^VADPT calls (supported)
  1. ;
  1. GRAPH ;
  1. D:GMR=0 SETV
  1. I '$D(^TMP($J,"GMRVG")) S GN=GN+1,^TMP($J,GN)="NO DATA",RESULT=$NA(^TMP($J)) Q
  1. K GMRQUAL S GDT=0 F S GDT=$O(^TMP($J,"GMRVG",GDT)) Q:GDT'>0 D
  1. . S:GMR=0 GN=GN+1,^TMP($J,GN)="^^^^^^^^^^^^^^^^^^^^^" D DATE
  1. . S GI="" F S GI=$O(^TMP($J,"GMRVG",GDT,GI)) Q:GI="" D
  1. . . S GK="" F S GK=$O(^TMP($J,"GMRVG",GDT,GI,GK)) Q:GK="" D SETA
  1. D KVAR^VADPT K VA
  1. ;RETURN CALL ROUTINE WITH QUALIFIERS
  1. I GMR=1,$D(GMRQUAL) D
  1. . S (GQ,GQ(1))=""
  1. . F S GQ=$O(GMRQUAL(GQ)) Q:GQ="" D
  1. . . S I=0,GQ(1)=$S(GQ="T":"TEMPERATURE",GQ="P":"PULSE",GQ="R":"RESPIRATION",GQ="B":"BLOOD PRESSURE",GQ="H":"HEIGHT",GQ="W":"WEIGHT",GQ="CVP":"CVP",GQ="PO2":"PULSE OXIMETRY",GQ="CG":"CIRCUMFERENCE/GIRTH",1:"")
  1. . . Q:GQ(1)="" S GN=GN+1,^TMP($J,GN)=GQ(1)_"--- "
  1. . . S GQ(2)="" F S GQ(2)=$O(GMRQUAL(GQ,GQ(2))) Q:GQ(2)="" S I=I+1 S:I>1 ^TMP($J,GN)=^(GN)_"," S ^TMP($J,GN)=^TMP($J,GN)_" "_GQ(2)
  1. K GQ,GG,GI,GMRVJ,GSYNO,GHOLD,GLINE,GMRQUAL
  1. K ^TMP($J,"GMR"),^TMP($J,"GMRVG")
  1. S RESULT=$NA(^TMP($J))
  1. Q
  1. SETV ;Set patient data in ^TMP($J,"GMRK" global
  1. D DEM^VADPT,INP^VADPT
  1. S GN=1,^TMP($J,GN)=$S(VADM(1)'="":VADM(1),1:" ")_" "_$S(VADM(2)'="":$E($P(VADM(2),"^",2),8,11),1:" ")_" "_$S($D(VADM(3)):$P(VADM(3),"^",2),1:" ")_" "_$S($D(VADM(4)):VADM(4),1:" ")_" (Yrs)"
  1. S ^TMP($J,GN)=^(GN)_" "_$S($D(VADM(5)):$P(VADM(5),"^",2),1:" ")
  1. S GN=2,^TMP($J,GN)="Unit: "_$P($G(VAIN(4)),"^",2)_" Room: "_$P($G(VAIN(5)),"-",1,2)
  1. I '$D(GMRVHLOC) S GMRVHLOC=$$HOSPLOC^GMVUTL1(+$G(VAIN(4)))
  1. S GN=3,^TMP($J,GN)="Division: "_$$DIVISION^GMVUTL1(+GMRVHLOC)
  1. S GN=4,^TMP($J,GN)=GSTRFIN
  1. Q
  1. DATE ;
  1. S:GMR=0 $P(^TMP($J,GN),"^")=$E(GDT,4,5)_"-"_$E(GDT,6,7)_"-"_$E(GDT,2,3)
  1. S:GMR=0 Y=$E($P(GDT,".",2)_"000000",1,6),$P(^TMP($J,GN),"^",2)=$E(Y,1,2)_":"_$E(Y,3,4)_":"_$E(Y,5,6)
  1. Q
  1. SETA ;Store measurements in ^TMP($J, global
  1. N GMVNODE
  1. S GMVNODE=$G(^TMP($J,"GMRVG",GDT,GI,GK))
  1. S $P(^TMP($J,GN),"^",22)=$P(GMVNODE,U,5)
  1. S $P(^TMP($J,GN),"^",23)=$P(GMVNODE,U,6)
  1. S $P(^TMP($J,GN),"^",24)=$P(GMVNODE,U,7)
  1. S GK(1)=GK
  1. I GK(1)="Unavailable" S GK(1)="Unavail"
  1. I GI="I" S:GMR=0 $P(^TMP($J,GN),"^",17)=GK(1) Q
  1. I GI="O" S:GMR=0 $P(^TMP($J,GN),"^",18)=GK(1) Q
  1. I GI="PN" S:GMR=0 $P(^TMP($J,GN),"^",19)=GK(1) Q
  1. S (GMRSITE,GMRSITE(1),GINF,GMRVJ)=""
  1. I GK(1)'="" D Q:GMR=1
  1. . S GMRSITE(1)=$P(GMVNODE,U,1),GMRVJ=$P(GMVNODE,U,2),GINF=$P(GMVNODE,U,4)
  1. . I GMRSITE(1)'="" D SYNOARY^GMVLGQU
  1. I GI="R" S $P(^TMP($J,GN),"^",5)=GK(1)_$S(GMRVJ=1:"*",1:"")_"- "_GMRSITE Q
  1. I GI="H" D Q
  1. . S $P(^TMP($J,GN),"^",11)=GK(1)_"- "_GMRSITE,$P(^TMP($J,GN),"^",12)=$S(GK(1)>0:$J(GK(1)*2.54,0,2),1:"") S:GK(1)>0 GMRHT=(GK(1)*2.54)/100
  1. I GI="PO2" D Q
  1. . S (GINF(1),GINF(2))="" I GINF'="" D PO2^GMVLGQU(.GINF)
  1. . S $P(^TMP($J,GN),"^",6)=GK(1)_$S(GMRVJ=1:"*",1:"")_"- "_GMRSITE_"-"_GINF(1)_"-"_GINF(2)
  1. I GI="CVP" D Q
  1. . S $P(^TMP($J,GN),"^",15)=$S(GK(1)>0!(GK(1)<0):$J(GK(1),0,1),1:GK(1))_$S(GMRVJ=1:"*",1:"")
  1. . S $P(^TMP($J,GN),"^",16)=$S(GK(1)>0!(GK(1)<0)!($E(GK(1))="0"):$J(GK(1)/1.36,0,1),1:"")_$S(GMRVJ=1:"*",1:"")
  1. I GI="CG" D Q
  1. . S $P(^TMP($J,GN),"^",13)=GK(1)_"- "_GMRSITE,$P(^TMP($J,GN),"^",14)=$S(GK(1)>0:$J(GK(1)/.3937,0,2),1:"")
  1. I GI="B",GK(1)'="" S $P(^TMP($J,GN),"^",7)=GK(1)_$S(GMRVJ=1:"*",1:"")_"- "_GMRSITE
  1. I GI="W" S $P(^TMP($J,GN),"^",8)=GK(1)_"- "_GMRSITE,$P(^(GN),"^",9)=$S(GK(1)>0:$J(GK(1)*.45359237,0,2),1:"")
  1. I GK(1)>0,GI="W" D Q
  1. . S GHOLD=GI,GMRBMI="",GMRBMI(1)=GDT,GMRBMI(2)=GK(1) D CALBMI^GMVBMI(.GMRBMI) S GI=GHOLD
  1. . S $P(^TMP($J,GN),"^",10)=GMRBMI K GMRBMI
  1. I GI="T" S $P(^TMP($J,GN),"^",3)=GK(1)_$S(GMRVJ=1:"*",1:"")_"- "_GMRSITE Q
  1. I GI="P" S $P(^TMP($J,GN),"^",4)=GK(1)_$S(GMRVJ=1:"*",1:"")_"- "_GMRSITE
  1. Q