Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: GMVUTL7

GMVUTL7.m

Go to the documentation of this file. 
  1. GMVUTL7 ;HIOFO/DS,FT-RPC API TO RETURN ALL VITALS/CATEGORIES/QUALIFIERS ;7/17/02  14:52
  1.  ;;5.0;GEN. MED. REC. - VITALS;**3**;Oct 31, 2002
  1.  ;
  1.  ; This routine uses the following IAs:
  1.  ; #10035 - FILE 2 references      (supported)
  1.  ; #10103 - ^XLFDT calls           (supported)
  1.  ;
  1.  ; This routine supports the following IAs:
  1.  ; #4355 - GMV GET CURRENT TIME RPC is called at TIME  (private)
  1.  ; #4359 - GMV VITALS/CAT/QUAL RPC is called at GETVITAL (private)
  1.  ;
  1. GETVITAL(RESULT,GMVLIST)        ; GMV VITALS/CAT/QUAL [RPC entry point]
  1.  ; Returns all vital qual info in RESULT
  1.  ;GMVLIST is either "" for all vitals or a list of required eg 1^2^
  1.  N GMVNUM,GMVDATA,GMVDO,GMVLOOP
  1.  S GMVNUM=1
  1.  I GMVLIST'="" D
  1.  . F GMVLOOP=1:1:$L(GMVLIST,"^") D
  1.  .. S GMVDO=$P(GMVLIST,"^",GMVLOOP)
  1.  .. Q:GMVDO=""
  1.  .. S GMVDO=$$GETIEN(GMVDO)
  1.  .. Q:GMVDO=""
  1.  .. S RESULT(GMVNUM)=$$GETDATA(GMVDO)_"^"_$$ABBVAL(GMVDO)
  1.  .. D GETALL(GMVNUM,.RESULT)
  1.  .. S GMVNUM=GMVNUM+1
  1.  .. Q
  1.  . Q
  1.  E  D
  1.  . S GMVLOOP=0
  1.  . F  S GMVLOOP=$O(^GMRD(120.51,GMVLOOP)) Q:GMVLOOP'>0  D
  1.  .. S RESULT(GMVNUM)=$$GETDATA(GMVLOOP)_"^"_$$ABBVAL(GMVLOOP)
  1.  .. D GETALL(GMVNUM,.RESULT)
  1.  .. S GMVNUM=GMVNUM+1
  1.  .. Q
  1.  . Q
  1.  Q
  1. GETALL(GMVLOOP,RESULT)  ;
  1.  S GMVCNT=0
  1.  ;S GMVLOOP="" F  S GMVLOOP=$O(RESULT(GMVLOOP)) Q:GMVLOOP=""  D
  1.  Q:$G(RESULT(GMVLOOP))=""
  1.  Q:$P(RESULT(GMVLOOP),"^",1)'="V"
  1.  S GMVITTYP=$P(RESULT(GMVLOOP),"^",2)
  1.  S GMVD2=""
  1.  S GMVCNT=GMVLOOP+.001
  1.  F  S GMVD2=$O(^GMRD(120.53,"C",GMVITTYP,GMVD2)) Q:GMVD2'>0  D
  1.  . S GMVD1=0
  1.  . F  S GMVD1=$O(^GMRD(120.53,"C",GMVITTYP,GMVD2,GMVD1)) Q:GMVD1'>0  D
  1.  .. S GMVDATA=$P($G(^GMRD(120.53,GMVD2,0)),U)
  1.  .. I GMVDATA]"" D
  1.  ... S GMVITTYP(0)=$G(^GMRD(120.51,+GMVITTYP,0))
  1.  ... S GMVITTYP(1)=GMVITTYP,GMVITTYP(2)=$P(GMVITTYP(0),U,2)
  1.  ... S GMVITTYP(3)=$P(GMVITTYP(0),U)
  1.  ... S GMVDEFQ=$P($G(^GMRD(120.53,GMVD2,1,GMVD1,0)),U,7)
  1.  ... S GMVDEFQ(0)=$G(^GMRD(120.52,+GMVDEFQ,0))
  1.  ... S GMVDEFQ(1)=GMVDEFQ,GMVDEFQ(2)=$P(GMVDEFQ(0),U,2)
  1.  ... S GMVDEFQ(3)=$P(GMVDEFQ(0),U)
  1.  ... S RESULT(GMVCNT)="C"_U_GMVD2_U_GMVDATA
  1.  ... D GETCAT(GMVITTYP,GMVD2,.RESULT,.GMVCNT)
  1.  ... S GMVCNT=GMVCNT+.001
  1.  ... Q
  1.  .. Q
  1.  . Q
  1.  Q
  1. GETDATA(GMVVITAL)       ;
  1.  N GMVDATA,GMVD0,GMVD1
  1.  I $G(^GMRD(120.51,GMVVITAL,0))="" D   Q GMVRES
  1.  . S GMVRES="V^"_GMVVITAL_"^ERROR"
  1.  . Q
  1.  S GMVDATA=$G(^GMRD(120.51,GMVVITAL,0))
  1.  I GMVDATA]"" S GMVRES="V"_U_GMVVITAL_U_$P(GMVDATA,U)_U_$P(GMVDATA,U,2)_U_$P(GMVDATA,U,7)
  1.  Q GMVRES
  1. GETCAT(GMVVTP,GMVITCAT,RESULT,GMVNUM)        ;
  1.  N GMVD0,GMVD1,GMVCNT
  1.  S GMVD0=0,GMVCNT=0
  1.  F  S GMVD0=$O(^GMRD(120.52,"C",GMVITTYP,GMVD0)) Q:GMVD0'>0  D
  1.  . S GMVD1=0
  1.  . F  S GMVD1=$O(^GMRD(120.52,"C",GMVITTYP,GMVD0,GMVD1)) Q:GMVD1'>0  D
  1.  .. S GMVCATD0=$P($G(^GMRD(120.52,GMVD0,1,GMVD1,0)),U,2)
  1.  .. I $G(GMVITCAT)>0,GMVITCAT'=GMVCATD0 Q
  1.  .. S GMVDATA=$G(^GMRD(120.52,GMVD0,0))
  1.  .. I GMVDATA]"" D
  1.  ... S GMVITTYP(0)=$G(^GMRD(120.51,+GMVITTYP,0))
  1.  ... S GMVITTYP(1)=GMVITTYP,GMVITTYP(2)=$P(GMVITTYP(0),U,2)
  1.  ... S GMVITTYP(3)=$P(GMVITTYP(0),U)
  1.  ... S GMVITCAT(0)=$G(^GMRD(120.53,+GMVCATD0,0))
  1.  ... S GMVITCAT(1)=GMVCATD0,(GMVITCAT(2),GMVITCAT(3))=$P(GMVITCAT(0),U)
  1.  ... S GMVNUM=GMVNUM+.001
  1.  ... S RESULT(GMVNUM)="Q"_U_GMVD0_U_$P(GMVDATA,U)_U_$P(GMVDATA,U,2)
  1.  ... Q
  1.  .. Q
  1.  . Q
  1.  Q
  1. ABBVAL(VITALTYP)       ;
  1.  N RESULT,GMVDATA
  1.  ; Gets high low values if they exist
  1.  I $G(^GMRD(120.57,1,1))="" Q ""
  1.  S RESULT=""
  1.  S GMVDATA=$P($G(^GMRD(120.57,1,1)),U,1,13)
  1.  I VITALTYP=1 D
  1.  . ; BP
  1.  . S RESULT=$P(GMVDATA,U,7,10)
  1.  . Q
  1.  I VITALTYP=2 D
  1.  . ; Temprature
  1.  . S RESULT=$P(GMVDATA,U,1,2)
  1.  . Q
  1.  I VITALTYP=5 D
  1.  . ; Pulse
  1.  . S RESULT=$P(GMVDATA,U,3,4)
  1.  . Q
  1.  I VITALTYP=3 D
  1.  . ;Respirations
  1.  . S RESULT=$P(GMVDATA,U,5,6)
  1.  . Q
  1.  I VITALTYP=19 D
  1.  . ;CVP
  1.  . S RESULT=$P(GMVDATA,U,11,13)
  1.  . Q
  1.  Q RESULT
  1. GETIEN(GMVABB) ; Gets IEN from the Abbreviation code.
  1.  Q $O(^GMRD(120.51,"C",GMVABB,""))
  1. ROOMPT(RESULTS,GMVWRD,GMVRLST) ; GMV WARD/ROOM PATIENTS [RPC entry point]
  1.  ; Returns a list of patients in the ward and rooms specified
  1.  ; Input:
  1.  ; RESULTS - name of the array to hold the patient list
  1.  ; GMVWRD  - name of the ward (e.g., 2EAST)
  1.  ; GMVRLST - the room numbers of the ward separated by comma
  1.  ;           (e.g., 200,210,220)
  1.  ; Output:
  1.  ; RESULT(n)=patient name^DFN^DOB (external)^SSN (no hyphens)
  1.  ; 
  1.  ; n is a sequential number beginning with 0 (zero)
  1.  N GMRVROOM,GMRVLST,GMRVCNT,GMVT,GMVDF
  1.  K RESULTS
  1.  S GMVWARD(1)=GMVWRD
  1.  I GMVRLST["," D
  1.  . F GMVA=1:1:$L(GMVRLST)+1 D
  1.  . . Q:$P(GMVRLST,",",GMVA)=""
  1.  . . S GMVROOM($P($P(GMVRLST,",",GMVA),"-"))=""
  1.  . . Q
  1.  . Q
  1.  E  D
  1.  . S GMVROOM($P(GMVRLST,"-"))=""
  1.  . Q
  1.  S GMVEDB="S"
  1.  K ^TMP($J)
  1.  D WARD^GMVDS1
  1.  S GMVT="",GMVCNT=0
  1.  F  S GMVT=$O(^TMP($J,GMVT)) Q:GMVT=""  D
  1.  . S GMVN=""
  1.  . F  S GMVN=$O(^TMP($J,GMVT,GMVN)) Q:GMVN=""  D
  1.  . . S GMVDF=""
  1.  . . F  S GMVDF=$O(^TMP($J,GMVT,GMVN,GMVDF)) Q:GMVDF=""  D
  1.  . . . S GMVDOB=$$FMTE^XLFDT($P(^DPT(GMVDF,0),"^",3))
  1.  . . . S GMVSSN=$P(^DPT(GMVDF,0),"^",9)
  1.  . . . S RESULTS(GMVCNT)=GMVN_"^"_GMVDF_"^"_GMVDOB_"^"_GMVSSN
  1.  . . . S GMVCNT=GMVCNT+1
  1.  . . . Q
  1.  . . Q
  1.  . Q
  1.  Q
  1. TIME(RESULT,P2) ;Gets current time
  1.  S RESULT=$$NOW^XLFDT()
  1.  Q