Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: GMVXPST

GMVXPST.m

Go to the documentation of this file. 
  1. GMVXPST ;HOIFO/FT-POST INSTALLATION FOR VITALS ;10/28/02  12:33
  1.  ;;5.0;GEN. MED. REC. - VITALS;;Oct 31, 2002
  1.  ;
  1.  ; This routine uses the following IAs:
  1.  ; #10141 - ^XPDUTL calls (supported)
  1.  ; #2263  - ^XPAR calls   (supported)
  1.  ;
  1.  ; This post-installation:
  1.  ; 1) deletes the data dictionary entries and data for File 120.5,
  1.  ;    Fields 1.1 and 1.3
  1.  ; 2) deletes the data dictionary entries and data for File 120.51,
  1.  ;    Fields 2 and 6
  1.  ; 3) updates the parameters for the required client version
  1.  ; 4) deletes some bogus data dictionary nodes in FILE 120.5
  1.  ;
  1. XPAR ; Setup preliminary parameters
  1.  ; This submodule is called during the KIDS installation
  1.  ; process.
  1.  ;
  1.  ; Variables:
  1.  ;  GMV:    [Private] Scratch
  1.  ;  GMVGUI: [Private] Current version of GUI being installed
  1.  ;  GMVLST: [Private] Scratch List
  1.  ;
  1.  ; New private variables
  1.  NEW GMV,GMVGUI,GMVLST
  1.  ; Announce my intentions
  1.  D BMES^XPDUTL("Updating system parameters.")
  1.  ; Set current client version
  1.  S GMVGUI="5.0.0.0"
  1.  ; Deactivate all previous versions from XPAR
  1.  D GETLST^XPAR(.GMVLST,"SYS","GMV GUI VERSION")
  1.  F GMV=0:0 S GMV=$O(GMVLST(GMV)) Q:'GMV  D
  1.  .D EN^XPAR("SYS","GMV GUI VERSION",$P(GMVLST(GMV),"^",1),0)
  1.  ; Add and/or activate current client versions
  1.  D EN^XPAR("SYS","GMV GUI VERSION","VITALS.EXE:"_GMVGUI,1)
  1.  D EN^XPAR("SYS","GMV GUI VERSION","VITALSMANAGER.EXE:"_GMVGUI,1)
  1.  ; Set latest Vital Home Page
  1.  D EN^XPAR("SYS","GMV WEBLINK",1,"http://vista.domain.ext/ClinicalSpecialties/vitals/")
  1.  ;
  1.  ; Kill bogus DD nodes
  1.  K ^DD(120.5,1,0)
  1.  K ^DD(120.5,1,21,0)
  1.  K ^DD(120.5,1,21,1,0)
  1.  K ^DD(120.5,1,21,2,0)
  1.  K ^DD(120.5,"B","SITE",1)
  1.  K ^DD(120.5,"GL",1,0,1)
  1.  K ^DD(120.5,"SB",120.505,1)
  1.  ;
  1. QUEUE ; Queue post-install
  1.  N GMVMSG,ZTDESC,ZTDTH,ZTIO,ZTRTN,ZTSK
  1.  I +$$VERSION^XPDUTL("GMRV")>4.9 Q  ;post-install was done before
  1.  D BMES^XPDUTL("Will queue data cleanup as a background job.")
  1.  S ZTDESC="V/M v5.0 Data Cleanup"
  1.  S ZTRTN="EN^GMVXPST",ZTIO="",ZTDTH=$H
  1.  D ^%ZTLOAD
  1.  S:ZTSK GMVMSG="Task #: "_ZTSK
  1.  S:'ZTSK GMVMSG="Could not task the data cleanup."
  1.  D MES^XPDUTL(GMVMSG)
  1.  Q
  1. EN ; Driver subroutine for post-installation
  1.  S:$D(ZTQUEUED) ZTREQ="@"
  1.  D DATA,DD
  1.  Q
  1. DD ; Delete obsolete data dictionary fields
  1.  ; delete *SITE (#2) and *QUALITY (#6) from File 120.51
  1.  N DA,DIK
  1.  S DIK="^DD(120.51,"
  1.  F DA=2,6 D
  1.  .S DA(1)=DA
  1.  .D ^DIK
  1.  .Q
  1.  ; delete *SITE (#1.1) and *QUALITY (#1.3) from File 120.5
  1.  S DIK="^DD(120.5,"
  1.  F DA=1.1,1.3 D
  1.  .S DA(1)=DA
  1.  .D ^DIK
  1.  .Q
  1.  Q
  1. DATA ; Delete data from obsolete fields
  1.  ; delete data from File 120.51, Fields 2 and 6
  1.  N DA,DIE,DR,GMVNODE
  1.  S DA=0
  1.  F  S DA=$O(^GMRD(120.51,DA)) Q:'DA  D
  1.  .S DIE="^GMRD(120.51,",DR="2///@;6///@"
  1.  .D ^DIE
  1.  .Q
  1.  ; delete data from File 120.5, Fields 1.1 and 1.3
  1.  S DA=0
  1.  F  S DA=$O(^GMR(120.5,DA)) Q:'DA  D
  1.  .S GMVNODE=$G(^GMR(120.5,DA,0))
  1.  .I $P(GMVNODE,U,7)="",$P(GMVNODE,U,9)="" Q  ;no data to delete
  1.  .S DIE="^GMR(120.5,",DR="1.1///@;1.3///@"
  1.  .D ^DIE
  1.  .Q
  1.  Q