Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: HLEVAPI0

HLEVAPI0.m

Go to the documentation of this file.
  1. HLEVAPI0 ;O-OIFO/LJA - Event Monitor APIs ;02/04/2004 14:42
  1. ;;1.6;HEALTH LEVEL SEVEN;**109**;Oct 13, 1995
  1. ;
  1. ONOFFM(HLEVIENE,STATUS) ;Turn on/off event monitor...
  1. D DEBUG^HLEVAPI2("ONOFFM") ; Debug data created conditionally
  1. ;
  1. ; Stop all event monitoring to enable on-site debugging...
  1. QUIT:$G(^TMP("HLEVFLAG",$J))["STOP" ;->
  1. ;
  1. QUIT $$ONOFF(776.1,+HLEVIENE,STATUS)
  1. ;
  1. ONOFFS(HLEVIEN,STATUS) ; Turn on/off system...
  1. QUIT $$ONOFF(776.999,+HLEVIEN,STATUS)
  1. ;
  1. ONOFF(FILE,HLEVIENE,STATUS) ; Turn on/off event monitor or system...
  1. ; FILE can = 776.1 or 776.999
  1. ; Actually, HLEVIENE can be the IEN of the monitor, or the system.
  1. ; If STATUS="A", sets status to ACTIVE.
  1. ; If STATUS="I", sets status to INACTIVE.
  1. ; If STATUS=null or undefined (not passed), present status returned...
  1. ;
  1. N DA,DATA,DIE,DR,STAT,X,Y
  1. ;
  1. ; Find entry and IEN and zero node data...
  1. S FILE=+$G(FILE) I FILE'=776.1&(FILE'=776.999) QUIT "^Invalid file number" ;->
  1. S HLEVIENE=$G(HLEVIENE)
  1. S:FILE=776.999 HLEVIENE=1 ; Just overwrite anything passed by user...
  1. I $L($G(STATUS))>1 QUIT "^Invalid STATUS passed" ;->
  1. S STATUS=$$UP^XLFSTR($E($G(STATUS)_" "))
  1. I " AI"'[STATUS QUIT "^Invalid STATUS passed" ;->
  1. ;
  1. ; If they passed the name of the entry...
  1. I HLEVIENE'=+HLEVIENE D QUIT:HLEVIENE'>0 "^Couldn't find entry" ;->
  1. . I $TR(HLEVIENE," ","")']"" QUIT ;->
  1. . S HLEVIENE(1)=$O(^HLEV(FILE,"B",HLEVIENE,0)) ; Must have passed in name
  1. . I HLEVIENE(1)'>0 D
  1. . . S HLEVIENE(1)=$O(^HLEV(FILE,"B",$$UP^XLFSTR(HLEVIENE),0))
  1. . S HLEVIENE=HLEVIENE(1)
  1. ;
  1. ; Get zero node...
  1. S DATA=$G(^HLEV(FILE,+HLEVIENE,0)) QUIT:DATA']"" "^Couldn't find entry" ;->
  1. ;
  1. ; Get current status...
  1. S STAT=$E($P(DATA,U,2)_" ")
  1. ;
  1. ; If current status not yet entered in field...
  1. I " AI"'[STAT D QUIT STAT ;->
  1. . ; Passed-in STATUS not A or I, so just tell them value of status...
  1. . I "AI"'[STATUS S STAT="^Status not entered yet" QUIT ;->
  1. . ; User passed in a value to set the status to, so set it for them...
  1. . S DA=+HLEVIENE,DIE=FILE,DR="2///"_STATUS
  1. . D ^DIE
  1. . S STAT=STATUS
  1. ;
  1. ; If all they want is the status...
  1. I STATUS=" " QUIT STAT ;->
  1. ;
  1. ; Status entered in field before call...
  1. ;
  1. ; If passed-in status is the same as the current status in entry...
  1. I STAT=STATUS QUIT STATUS ;-> Already set...
  1. ;
  1. ; Change status of field to passed-in value...
  1. S DA=+HLEVIENE,DIE=FILE,DR="2///"_STATUS
  1. D ^DIE
  1. ;
  1. Q STATUS
  1. ;
  1. ONOFFEV ; Turn on/off event monitor
  1. N CHG
  1. ;
  1. N DATA,DIC,IEN,IENR
  1. D HDR^HLEVREP("Turn on/off Event Monitors")
  1. ;
  1. S7761 KILL DATA,DIC,IEN,IENR
  1. W !
  1. S IEN=$$ASKIEN^HLEVREP(776.1) QUIT:IEN'>0 ;->
  1. D HDR^HLEVREP("Turn on/off Event Monitors",IEN)
  1. D VIEW7761(+IEN)
  1. D RUNS7761^HLEVREP(+IEN)
  1. I $D(^TMP($J,"HLRUNS")) D
  1. . W !!,"Recent Checks of the Monitor by Master Job"
  1. . W !,$$REPEAT^XLFSTR("-",IOM)
  1. . W !,"Check-time",?18,"Results"
  1. . W !,$$REPEAT^XLFSTR("-",IOM)
  1. . S IENR=0
  1. . F S IENR=$O(^TMP($J,"HLRUNS",IENR)) Q:IENR'>0 D
  1. . . S DATA=$G(^TMP($J,"HLRUNS",IENR)) QUIT:DATA']"" ;->
  1. . . W !,$$SDT^HLEVX001($P(DATA,U,2)),?18,$$STAT2M^HLEVX001($P(DATA,U))
  1. W !
  1. S CHG=$$ACTINACT(776.1,+IEN,2,"Event monitor status")
  1. I CHG D
  1. . D HDR^HLEVREP("Turn on/off Event Monitors",IEN)
  1. . D VIEW7761(+IEN)
  1. F Q:(IOSL-$Y)<4 W !
  1. ;S X=$$BTE^HLCSMON("Press RETURN to continue... ")
  1. G S7761 ;->
  1. ;
  1. VIEW7761(IEN) ; Actual display code for entry...
  1. N NODE,P1,P2,P3,P4,P5,P6,PAR,PCE
  1. ;
  1. S NODE=$G(^HLEV(776.1,+IEN,0))
  1. F PCE=1:1:6 S @("P"_PCE)=$P(NODE,U,PCE)
  1. ;
  1. ; Store under field number...
  1. F PCE=1:1:8 S PAR(PCE)=$P($G(^HLEV(776.1,+IEN,40)),U,PCE)
  1. ;
  1. D SH7761("Description",$S(P3]"":P3,1:"---"))
  1. D SH7761("Status",$S(P2="A":"ACTIVE",1:"INACTIVE"))
  1. D SH7761("Requeue minutes",$S(P4:P4_"min",P4=0:"0 [Immediate Run]",1:"---"))
  1. D SH7761("Notification mail group",$S(P5:$P($G(^XMB(3.8,+P5,0)),U),1:"---"))
  1. D SH7761("M startup",$S(P6]"":P6,1:"---"))
  1. W !,$$CJ^XLFSTR(" Parameter ""Variable"" Descriptors ",IOM,"-")
  1. F PCE=1:1:8 I PAR(PCE)]"" D
  1. . W !,?25,"Parameter - "_PCE_" = ",PAR(PCE)
  1. ;
  1. Q
  1. ;
  1. SH7761(TAG,VAL) ;
  1. W !,?(35-$L(TAG)-2),TAG,":",?45,VAL
  1. Q
  1. ;
  1. ONOFFPAR ; Turn on/off parameters...
  1. N CHG
  1. ;
  1. D VIEW7769^HLEVREP(0)
  1. ;
  1. W !
  1. ;
  1. S CHG=0
  1. S X=$$ACTINACT(776.999,1,2,"STATUS-MASTER JOB") I X=1 S CHG=1
  1. S X=$$ACTINACT(776.999,1,6,"STATUS-EVENT MONITORING") I X=1 S CHG=1
  1. ;
  1. I CHG D VIEW7769^HLEVREP(0)
  1. ;
  1. W !
  1. F Q:(IOSL-$Y)<3 W !
  1. S X=$$BTE^HLCSMON("Press RETURN to exit... ")
  1. ;
  1. Q
  1. ;
  1. ACTINACT(FILE,IEN,FLD,TAG) ; Turn on/off status fields...
  1. N DA,DIE,DR,STAT,X,Y
  1. S STAT=$P($G(^HLEV(FILE,IEN,0)),U,+FLD)
  1. S X=$$YN^HLCSRPT4("Change '"_TAG_"' to "_$S(STAT="A":"INACTIVE",1:"ACTIVE"),"No") I X'=1 D QUIT "" ;->
  1. . W " ... nothing changed ..."
  1. S DA=IEN,DIE=FILE,DR=FLD_"///"_$S(STAT="A":"I",1:"A")
  1. D ^DIE
  1. W " changed!"
  1. Q 1
  1. ;
  1. EVENTCHK(HLEVIENM) ; Loop thru all MONITORs...
  1. ; NOEVCHK,ZTSKMST -- req
  1. N HLEVIENE,HLEVNM
  1. ;
  1. ; Check STATUS-EVENT...
  1. S NO=$O(^HLEV(776.999,":"),-1) QUIT:$P($G(^HLEV(776.999,+NO,0)),U,6)'="A" ;->
  1. ;
  1. S HLEVNM=0
  1. F S HLEVNM=$O(^HLEV(776.1,"B",HLEVNM)) Q:HLEVNM']"" D
  1. . S HLEVIENE=0
  1. . F S HLEVIENE=$O(^HLEV(776.1,"B",HLEVNM,HLEVIENE)) Q:'HLEVIENE D
  1. . . D EVENTONE^HLEVAPI3(HLEVIENM,HLEVNM,HLEVIENE)
  1. . . S NOEVCHK=$G(NOEVCHK)+1
  1. ;
  1. Q
  1. ;
  1. EVRES(HLEVIENM,HLEVIENE,RES,HLEVIENJ) ; Record result of queued task...
  1. ; ZTSK -- req
  1. N MIEN,NODE,STATUS
  1. ;
  1. ; Initial sets...
  1. S STATUS=$P($G(^HLEV(776,+$G(HLEVIENJ),0)),U,4)
  1. S RES=$E($$UP^XLFSTR($G(RES)))
  1. ;
  1. ; If any call made here, the job is running by definition...
  1. I $G(^HLEV(776,+$G(HLEVIENJ),0))]"" D
  1. . ; ABORT^HLEVAPI might have set status to ERROR. Don't override!
  1. . S $P(^HLEV(776,+$G(HLEVIENJ),0),U,4)=$S(STATUS="E":"E",RES="X":"E",RES="F":"F",1:"R")
  1. ;
  1. ; If no master job, or RUNNING, quit...
  1. I HLEVIENM=9999999!(RES="R") QUIT ;->
  1. ;
  1. ; Store results in 776.2...
  1. S MIEN=$O(^HLEV(776.2,+HLEVIENM,51,"B",+HLEVIENE,0)) QUIT:MIEN'>0 ;->
  1. S NODE=$G(^HLEV(776.2,+HLEVIENM,51,+MIEN,0)) QUIT:NODE']"" ;->
  1. ; Various jobs will set... QUIT:$P(NODE,U,4)'=$G(ZTSK) ;->
  1. S $P(NODE,U,5)=$G(RES),$P(NODE,U,6)=$$NOW^XLFDT
  1. S ^HLEV(776.2,+HLEVIENM,51,+MIEN,0)=NODE
  1. ;
  1. Q
  1. ;
  1. RUNEV(LASTRUN,LAPSE) ; Is LASTRUN (FM) LAPSE(min) before NOW?
  1. N WHENRUN
  1. QUIT:LASTRUN']"" "" ;->
  1. S WHENRUN=$$FMADD^XLFDT($$NOW^XLFDT,0,0,-LAPSE)
  1. Q $S(WHENRUN>LASTRUN:1,1:"")
  1. ;
  1. OKMCODE(MREF) ; Is this a valid M subrtn^rtn reference?
  1. N TXT
  1. QUIT:MREF'?1.8E1"^"1.8E "" ;->
  1. S TXT=$T(@MREF)
  1. Q $S(TXT]"":1,1:"")
  1. ;
  1. Q1TIME(HLEVIENE,OVERRIDE,QTIME,XTMP) ; Start a one-time run of event monitor (w/no master job)
  1. N DATA,HLEVIENJ,HLEVNM,ZTDESC,ZTDTH,ZTIO,ZTRTN,ZTSAVE,ZTSK
  1. ;
  1. ; Override inactive entry?
  1. S OVERRIDE=$S($G(OVERRIDE):1,1:0)
  1. ;
  1. ; Queue to future time?
  1. S QTIME=$G(QTIME)
  1. ;
  1. ; Is event active?
  1. S DATA=$G(^HLEV(776.1,+$G(HLEVIENE),0)) QUIT:DATA']"" "^Entry not found" ;->
  1. I $P(DATA,U,2)'="A",'OVERRIDE QUIT "^Event not active" ;->
  1. ;
  1. ; More variable sets...
  1. S HLEVNM=$P(DATA,U)
  1. S HLEVIENM=9999999 ; A one-time, no master job, run...
  1. ;
  1. ; Create a monitor stub entry...
  1. S HLEVIENJ=$$NEWEVENT^HLEVAPI(HLEVIENE,QTIME)
  1. I HLEVIENJ'>0 QUIT "^Entry creation failure" ;->
  1. ;
  1. ; Queue a new job w/stub entry's IEN...
  1. S ZTIO="",ZTDTH=$S(QTIME?7N1"."1.N:$$FMTH^XLFDT(QTIME),1:$H)
  1. S ZTDESC="HL Event Monitor - #"_HLEVIENE
  1. S ZTRTN="QUEUEV^HLEVAPI3"
  1. S ZTSAVE("HLEVIENJ")="",ZTSAVE("HLEVIENE")=""
  1. S ZTSAVE("HLEVNM")="",ZTSAVE("HLEVIENM")=""
  1. I $G(XTMP)]"" S ZTSAVE("XTMP")=""
  1. D ^%ZTLOAD
  1. ;
  1. I $G(^HLEV(776,+$G(HLEVIENJ),0))]"",$G(ZTSK)>0 D
  1. . N DA,DIE,DR
  1. . S DA=+HLEVIENJ,DIE=776,DR="8///"_ZTSK
  1. . D ^DIE
  1. ;
  1. Q $G(ZTSK)_U_$G(HLEVIENJ)
  1. ;
  1. EOR ;HLEVAPI0 - Event Monitor APIs ;5/16/03 14:42