Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: HLEVUTI3

HLEVUTI3.m

Go to the documentation of this file. 
  1. HLEVUTI3 ;O-OIFO/LJA - Event Monitor UTILITIES ;02/04/2004 14:42
  1.  ;;1.6;HEALTH LEVEL SEVEN;**109**;Oct 13, 1995
  1.  ;
  1. MOVETMP(FILE,IEN,GBLSV) ; Move ^UTILITY data into ^TMP and prep it...
  1.  N DATA,FLD,FLDLEN,FLDNM,GBL,MNO,NO,NUM,STR
  1.  ;
  1.  KILL ^TMP($J,"HLTMP")
  1.  ;
  1.  S GBL=$NA(^UTILITY("DIQ1",$J))
  1.  ;
  1.  D ADDLN(GBLSV,$$CJ^XLFSTR(" "_FILE_"#: "_IEN_" ",74,"="))
  1.  ;
  1.  S FLD=0
  1.  F  S FLD=$O(@GBL@(FILE,IEN,FLD)) Q:FLD'>0  D
  1.  .  S FLDNM="["_$P($G(^DD(+FILE,+FLD,0)),U)
  1.  .  S DATA=$G(@GBL@(FILE,IEN,+FLD,"E"))
  1.  .  I DATA]"" D  QUIT  ;->
  1.  .  .  S NO=$O(^TMP($J,"HLTMP",":"),-1)+1
  1.  .  .  S ^TMP($J,"HLTMP",+NO)=FLDNM_U_FLD_U_DATA_"]"
  1.  .  S MNO=0,FLD(1)=FLD
  1.  .  F  S MNO=$O(@GBL@(FILE,IEN,FLD,"E",MNO)) Q:MNO'>0  D
  1.  .  .  S DATA=$G(@GBL@(FILE,IEN,FLD,"E",+MNO))
  1.  .  .  S NO=$O(^TMP($J,"HLTMP",":"),-1)+1
  1.  .  .  S ^TMP($J,"HLTMP",+NO)=FLDNM_U_FLD(1)_U_DATA_"]"
  1.  ;
  1.  S NO=0,STR=""
  1.  F  S NO=$O(^TMP($J,"HLTMP",NO)) Q:NO'>0  D
  1.  .  S DATA=^TMP($J,"HLTMP",NO) QUIT:DATA']""  ;->
  1.  .  S FLDNM=$P(DATA,U),FLD=$P(DATA,U,2),DATA=$P(DATA,U,3,999)
  1.  .  I FILE=772,FLD=200 S FLDNM="MSG"
  1.  .  S FLDNM=$S(FLDNM]"":FLDNM_": ",1:""),FLDLEN=$L(FLDNM)
  1.  .  S DATA=$$LOW^XLFSTR(FLDNM)_DATA
  1.  .  I FLD']"" D  QUIT  ;-> standalone line...
  1.  .  .  I STR]"" D ADDLN(GBLSV,STR)
  1.  .  .  D ADDLN(GBLSV,"     "_DATA)
  1.  .  I ($L(STR)+$L(DATA)+3)>74 D
  1.  .  .  I STR]"" D ADDLN(GBLSV,STR)
  1.  .  .  S STR=""
  1.  .  S STR=STR_$$PAD(STR,$L(DATA))_DATA QUIT:$L(STR)<74  ;->
  1.  .  F  D  QUIT:STR']""
  1.  .  .  D ADDLN(GBLSV,$E(STR,1,74))
  1.  .  .  S STR=$E(STR,75,999) QUIT:STR']""  ;->
  1.  .  .  S STR="     "_STR
  1.  I STR]"" D ADDLN(GBLSV,STR)
  1.  ;
  1.  KILL ^TMP($J,"HLTMP")
  1.  ;
  1.  Q
  1.  ;
  1. PAD(STR,LEN) ; Add spaces to right justify...
  1.  QUIT:STR']"" "" ;->
  1.  I ($L(STR)+LEN)<40 QUIT "   " ;->
  1.  Q $$REPEAT^XLFSTR(" ",74-$L(STR)-LEN)
  1.  ;
  1. ADDLN(GBLSV,DATA) ; Add one line of text...
  1.  N NUM
  1.  S NUM=$O(^TMP($J,GBLSV,":"),-1)+1
  1.  S ^TMP($J,GBLSV,+NUM)=DATA
  1.  Q
  1.  ;
  1. LASTIEN ; Display last IEN of files 772 & 773 every 15 seconds...
  1.  N B,CT,DIFF,DIR,DIROUT,DIRUT,DTOUT,DUOUT,IEN772,IEN773
  1.  N LAST772,LAST773,STOP,TIMEOUT,X,Y
  1.  ;
  1.  W @IOF,$$CJ^XLFSTR("File 772 & 773 IEN Display",IOM)
  1.  W !,$$REPEAT^XLFSTR("=",IOM)
  1.  ;
  1.  W !!,"This API displays the last internal entry number (IEN) in the following files:"
  1.  W !!,"  * HL Message Text file (#772)."
  1.  W !,"  * HL Message Administration file (#773)."
  1.  W !!,"The last IEN in these files are recollected and redisplayed every 15 seconds."
  1.  W !,"After every display of these IENs, you may take the following actions:"
  1.  W !!,"  * Do nothing, & the information will be redisplayed in 15 seconds."
  1.  W !,"    (You may change the refresh seconds by entering a number of seconds"
  1.  W !,"    and pressing RETURN.)"
  1.  W !!,"  * Hit return to force information redisplay."
  1.  W !!,"  * Enter an uparrow ('^') and press RETURN to exit."
  1.  ;
  1.  F  QUIT:($Y+3)>IOSL  W !
  1.  QUIT:$$BTE^HLCSMON("Press RETURN to start, or '^' to exit... ")  ;->
  1.  ;
  1.  W @IOF
  1.  S X=$$SITE^VASITE W $$CJ^XLFSTR(" "_$P(X,U,2)_" ["_$P(X,U,3)_"] ",IOM,"=")
  1.  D HDRIEN
  1.  ;
  1.  S CT=0,TIMEOUT=15,B="|"
  1.  S (IEN772,IEN773,LAST772,LAST773)=""
  1.  ;
  1.  F  D  QUIT:STOP
  1.  .  S CT=CT+1
  1.  .  S IEN772=$O(^HL(772,":"),-1),IEN773=$O(^HLMA(":"),-1)
  1.  .  I '(CT#22) W !! D HDRIEN
  1.  .  W !,$$SDT($$NOW^XLFDT),?19,B
  1.  .  W ?21,IEN772,?36,$$DIFFIEN(IEN772,LAST772),?45,B
  1.  .  W ?47,IEN773,?61,$$DIFFIEN(IEN773,LAST773),?73,B
  1.  .  S LAST772=IEN772,LAST773=IEN773
  1.  .  S STOP=1
  1.  .  R " ",X:TIMEOUT
  1.  .  QUIT:X[U  ;->
  1.  .  S STOP=0
  1.  .  QUIT:'$T  ;-> Timed out...
  1.  .  I X=+X,X>0 S TIMEOUT=X D  QUIT  ;->
  1.  .  .  W """"
  1.  .  ; User pressed RETURN...
  1.  .  W "<ret>"
  1.  ;
  1.  Q
  1.  ;
  1. DIFFIEN(LAST,BEFORE) ; Return number new entries right justified in 3 col's
  1.  N DIFF
  1.  QUIT:LAST'>0!(BEFORE'>0) "" ;->
  1.  S DIFF=LAST-BEFORE QUIT:DIFF'>0 "" ;->
  1.  QUIT $J(DIFF,3)
  1.  ;
  1. HDRIEN ;
  1.  N B
  1.  S B="|"
  1.  W:$X>0 !
  1.  W "Time",?19,B,?21,"LAST-772-IEN",?36,"#772",?45,B
  1.  W ?47,"LAST-773-IEN",?61,"#773",?73,B
  1.  W !,$$REPEAT^XLFSTR("=",IOM)
  1.  Q
  1.  ;
  1. SDT(FMTIME) ; Return DD/MM/YY@HH:MM:SS
  1.  N DATE,TIME
  1.  QUIT:$G(FMTIME)'?7N.E "" ;->
  1.  S TIME=$S(FMTIME?7N1"."1.N:"@"_$E($P($$FMTE^XLFDT(FMTIME),"@",2)_":00:00",1,8),1:"")
  1.  S DATE=$E(FMTIME,4,5)_"/"_$E(FMTIME,6,7)_"/"_$E(FMTIME,2,3)
  1.  Q DATE_TIME
  1.  ;
  1. EOR ;HLEVUTI3 - Event Monitor UTILITIES ;5/16/03 14:42