Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: HLOSTAT

HLOSTAT.m

Go to the documentation of this file.
  1. HLOSTAT ;ALB/CJM- HLO STATISTICS- 10/4/94 1pm ;01/05/2007
  1. ;;1.6;HEALTH LEVEL SEVEN;**130,131,134**;Oct 13, 1995;Build 30
  1. ;Per VHA Directive 2004-038, this routine should not be modified.
  1. ;
  1. ;
  1. COUNT(HLCSTATE,RAP,SAP,TYPE) ;
  1. S:RAP="" RAP="UNKNOWN"
  1. S:SAP="" SAP="UNKNOWN"
  1. S:$L(TYPE)<2 TYPE="UNKNOWN"
  1. S HLCSTATE("COUNTS")=$G(HLCSTATE("COUNTS"))+1,HLCSTATE("COUNTS",SAP,RAP,TYPE)=1+$G(HLCSTATE("COUNTS",SAP,RAP,TYPE))
  1. Q
  1. SAVECNTS(HLCSTATE) ;
  1. N TIME,DIR,RAP,SAP,TYPE,COUNT
  1. Q:'$G(HLCSTATE("COUNTS"))
  1. S TIME=$E($$NOW^XLFDT,1,10)
  1. S DIR=$S(+$G(HLCSTATE("SERVER")):"IN",1:"OUT")
  1. I $G(HLCSTATE("COUNTS","ACKS")) D
  1. .I $$INC^HLOSITE($NA(^HLSTATS($S(DIR="IN":"OUT",1:"IN"),"HOURLY",+TIME,"ACCEPT ACK")),HLCSTATE("COUNTS","ACKS"))
  1. S SAP=""
  1. F S SAP=$O(HLCSTATE("COUNTS",SAP)) Q:SAP="" D
  1. .S RAP=""
  1. .F S RAP=$O(HLCSTATE("COUNTS",SAP,RAP)) Q:RAP="" D
  1. ..S TYPE=""
  1. ..F S TYPE=$O(HLCSTATE("COUNTS",SAP,RAP,TYPE)) Q:TYPE="" D
  1. ...S COUNT=HLCSTATE("COUNTS",SAP,RAP,TYPE)
  1. ...I $$INC^HLOSITE($NA(^HLSTATS(DIR,"HOURLY",+TIME,SAP,RAP,TYPE)),COUNT)
  1. K HLCSTATE("COUNTS") S HLCSTATE("COUNTS")=0
  1. Q
  1. ;
  1. TOTAL(WORK) ;totals hours into days and days into months
  1. ;
  1. N RAP,SAP,TIME,LIMIT,DIR,COUNT,MONTH,START,END
  1. ;
  1. ;start totaling the next day after last date totaled
  1. S START=$G(^HLSTATS("END DATE"))
  1. S:START START=$$FMADD^XLFDT(START,1)
  1. ;
  1. ;end totaling in the last hour of yesterday and save it so that the next run knows where to start
  1. S END=$$FMADD^XLFDT($$DT^XLFDT,-1)
  1. S ^HLSTATS("END DATE")=END
  1. S END=END+.24
  1. ;
  1. ;total hours into days
  1. S LIMIT=$$FMADD^XLFDT($$DT^XLFDT,,-48) ;save ~48 hours of hourly data
  1. F DIR="IN","OUT","EIN","EOUT" D
  1. .S TIME=0
  1. .F S TIME=$O(^HLSTATS(DIR,"HOURLY",TIME)) Q:'TIME Q:(TIME>END) D
  1. ..D:'(TIME<START)
  1. ...S:(DIR="IN")!(DIR="OUT") ^HLSTATS(DIR,"DAILY",$P(TIME,"."),"ACCEPT ACK")=$G(^HLSTATS(DIR,"DAILY",$P(TIME,"."),"ACCEPT ACK"))+$G(^HLSTATS(DIR,"HOURLY",TIME,"ACCEPT ACK"))
  1. ...S SAP=""
  1. ...F S SAP=$O(^HLSTATS(DIR,"HOURLY",TIME,SAP)) Q:SAP="" D
  1. ....S RAP=""
  1. ....F S RAP=$O(^HLSTATS(DIR,"HOURLY",TIME,SAP,RAP)) Q:RAP="" D
  1. .....S TYPE=""
  1. .....F S TYPE=$O(^HLSTATS(DIR,"HOURLY",TIME,SAP,RAP,TYPE)) Q:TYPE="" D
  1. ......S COUNT=$G(^HLSTATS(DIR,"HOURLY",TIME,SAP,RAP,TYPE))
  1. ......S ^HLSTATS(DIR,"DAILY",$P(TIME,"."),SAP,RAP,TYPE)=$G(^HLSTATS(DIR,"DAILY",$P(TIME,"."),SAP,RAP,TYPE))+COUNT
  1. ..;get rid of old hourly stats
  1. ..K:(TIME<LIMIT) ^HLSTATS(DIR,"HOURLY",TIME)
  1. ;
  1. ;total days into months
  1. S LIMIT=$$FMADD^XLFDT($$DT^XLFDT,-30) ;save ~30 days of daily data
  1. F DIR="IN","OUT","EIN","EOUT" D
  1. .S TIME=0
  1. .F S TIME=$O(^HLSTATS(DIR,"DAILY",TIME)) Q:'TIME Q:(TIME>END) D
  1. ..D:'(TIME<START)
  1. ...S MONTH=$E(TIME,1,5)
  1. ...S:(DIR="IN")!(DIR="OUT") ^HLSTATS(DIR,"MONTHLY",MONTH,"ACCEPT ACK")=$G(^HLSTATS(DIR,"MONTHLY",MONTH,"ACCEPT ACK"))+$G(^HLSTATS(DIR,"DAILY",TIME,"ACCEPT ACK"))
  1. ...S SAP=""
  1. ...F S SAP=$O(^HLSTATS(DIR,"DAILY",TIME,SAP)) Q:SAP="" D
  1. ....S RAP=""
  1. ....F S RAP=$O(^HLSTATS(DIR,"DAILY",TIME,SAP,RAP)) Q:RAP="" D
  1. .....S TYPE=""
  1. .....F S TYPE=$O(^HLSTATS(DIR,"DAILY",TIME,SAP,RAP,TYPE)) Q:TYPE="" D
  1. ......S COUNT=$G(^HLSTATS(DIR,"DAILY",TIME,SAP,RAP,TYPE))
  1. ......S ^HLSTATS(DIR,"MONTHLY",MONTH,SAP,RAP,TYPE)=$G(^HLSTATS(DIR,"MONTHLY",MONTH,SAP,RAP,TYPE))+COUNT
  1. ..K:(TIME<LIMIT) ^HLSTATS(DIR,"DAILY",TIME)
  1. Q
  1. REPORT ;Interactive option for printing the message statistics report
  1. N DIR,TYPE,START,END
  1. W !,"Hourly, daily, and monthly statistics are maintained."
  1. W !,"Hourly statistics are available for approximately the last 24 hours."
  1. W !,"Daily statistics are available for approximately the last 30 days."
  1. W !,"Monthly statistics are kept indefinitely"
  1. S DIR(0)="S^h:HOURLY;d:DAILY;m:MONTHLY"
  1. S DIR("A")="Which type of statistics should be reported"
  1. S DIR("B")="MONTHLY"
  1. D ^DIR
  1. Q:$D(DIRUT)
  1. I Y'="h",Y'="d",Y'="m" Q
  1. S TYPE=$S(Y="h":"HOURLY",Y="d":"DAILY",1:"MONTHLY")
  1. S START=$S(TYPE="HOURLY":$E($$FMADD^XLFDT($$NOW^XLFDT,,-24),1,10),TYPE="DAILY":$$FMADD^XLFDT(DT,-7),1:$E($$FMADD^XLFDT(DT,-30),1,5)_"01")
  1. S START=$$ASKBEGIN^HLOUSR2(START)
  1. Q:'START
  1. S END=$$ASKEND^HLOUSR2(START)
  1. Q:'END
  1. S:TYPE="MONTHLY" START=$E(START,1,5)_"00"
  1. S:TYPE="DAILY" START=$E(START,1,7)
  1. S:TYPE="HOURLY" START=$E(START,1,10)
  1. D:$$DEVICE() PRINT(TYPE,START,END)
  1. Q
  1. ;
  1. QUE ;entry point for queuing the message statistics report
  1. D PRINT($G(HLOPARMS("STATISTICS TYPE")),$G(HLOPARMS("START DT/TM")),$G(HLOPARMS("END DT/TM")))
  1. Q
  1. ;
  1. PRINT(STATTYPE,START,END) ;
  1. ;
  1. N RAP,SAP,TIME,DIR,COUNT,PAGE,CRT,QUIT
  1. S QUIT=0
  1. S CRT=$S($E(IOST,1,2)="C-":1,1:0)
  1. ;
  1. U IO
  1. W:CRT @IOF
  1. W "HLO MESSAGING STATISTICS REPORT ",$$FMTE^XLFDT($$NOW^XLFDT),?70,"Page 1"
  1. D LINE($$LJ("Type:",15)_STATTYPE)
  1. D LINE($$LJ("Beginning:",15)_$S(STATTYPE="MONTHLY":$$FMTE^XLFDT(START),1:$$FMTE^XLFDT(START)))
  1. D LINE($$LJ("Ending:",15)_$$FMTE^XLFDT(END))
  1. S PAGE=1
  1. ;
  1. ;
  1. F DIR="IN","OUT" D Q:QUIT
  1. .N TOTAL
  1. .S TOTAL=0
  1. .D LINE(" ")
  1. .S TIME=START
  1. .S:STATTYPE="MONTHLY" TIME=$E(TIME,1,5)
  1. .S TIME=TIME-.0001
  1. .D LINE($S(DIR="IN":"Incoming Messages:",1:"Outgoing Messages:"))
  1. .Q:QUIT
  1. .F S TIME=$O(^HLSTATS(DIR,STATTYPE,TIME)) Q:((TIME>$G(END))&$G(END)) Q:'TIME D Q:QUIT
  1. ..N SUBTOTAL
  1. ..S SUBTOTAL=0
  1. ..D LINE(" ")
  1. ..Q:QUIT
  1. ..D LINE(" Time Period: "_$S(STATTYPE="MONTHLY":$$FMTE^XLFDT(TIME_"00"),1:$$FMTE^XLFDT(TIME)))
  1. ..Q:QUIT
  1. ..S COUNT=$G(^HLSTATS(DIR,STATTYPE,TIME,"ACCEPT ACK"))
  1. ..I COUNT D Q:QUIT
  1. ...D LINE(" ")
  1. ...Q:QUIT
  1. ...D LINE(" Accept Acknowledgments by All Applications Count:"_$$RJ(COUNT,10))
  1. ...Q:QUIT
  1. ...D LINE(" ")
  1. ..S SAP=""
  1. ..F S SAP=$O(^HLSTATS(DIR,STATTYPE,TIME,SAP)) Q:SAP="" D Q:QUIT
  1. ...Q:SAP="ACCEPT ACK"
  1. ...D LINE(" Sending Application: "_SAP)
  1. ...Q:QUIT
  1. ...S RAP=""
  1. ...F S RAP=$O(^HLSTATS(DIR,STATTYPE,TIME,SAP,RAP)) Q:RAP="" D Q:QUIT
  1. ....D LINE(" Receiving Application: "_RAP)
  1. ....Q:QUIT
  1. ....S TYPE=""
  1. ....F S TYPE=$O(^HLSTATS(DIR,STATTYPE,TIME,SAP,RAP,TYPE)) Q:TYPE="" D Q:QUIT
  1. .....S COUNT=$G(^HLSTATS(DIR,STATTYPE,TIME,SAP,RAP,TYPE))
  1. .....S SUBTOTAL=SUBTOTAL+COUNT
  1. .....D LINE(" Message Type: "_$$LJ(TYPE,25)_" Count:"_$$RJ(COUNT,10))
  1. .....Q:QUIT
  1. ..I 'QUIT D
  1. ...S TOTAL=TOTAL+SUBTOTAL
  1. ...D LINE(" "),LINE($$RJ("**"_STATTYPE_" SUBTOTAL ** (excluding commit acks):",68)_$$RJ(SUBTOTAL,10))
  1. .D:'QUIT LINE(" "),LINE($$RJ("** TOTAL "_$S(DIR="IN":"INCOMING",1:"OUTGOING")_" MESSAGES ** (excluding commit acks):",68)_$$RJ(TOTAL,10))
  1. I CRT,'QUIT D PAUSE2
  1. I $D(ZTQUEUED) S ZTREQ="@"
  1. D ^%ZISC
  1. Q
  1. ;
  1. DEVICE() ;
  1. ;Description: allows the user to select a device.
  1. ;Input: none
  1. ;
  1. ;Output:
  1. ; Function Value - Returns 0 if the user decides not to print or to
  1. ; queue the report, 1 otherwise.
  1. ;
  1. N OK,HLOPARMS
  1. S OK=1
  1. S %ZIS="MQ"
  1. D ^%ZIS
  1. S:POP OK=0
  1. D:OK&$D(IO("Q"))
  1. .S HLOPARMS("STATISTICS TYPE")=TYPE,HLOPARMS("START DT/TM")=START,HLOPARMS("END DT/TM")=END
  1. .S ZTRTN="QUE^HLOSTAT",ZTDESC="HLO MESSAGE STATISTICS REPORT",ZTSAVE("HLOPARMS(")=""
  1. .D ^%ZTLOAD
  1. .W !,$S($D(ZTSK):"REQUEST QUEUED TASK="_ZTSK,1:"REQUEST CANCELLED")
  1. .D HOME^%ZIS
  1. .S OK=0
  1. Q OK
  1. ;
  1. PAUSE ;
  1. ;First scrolls to the bottome of the page, then does a screen pause. Sets QUIT=1 if user decides to quit.
  1. ;
  1. N DIR,X,Y
  1. F Q:$Y>(IOSL-3) W !
  1. S DIR(0)="E"
  1. D ^DIR
  1. I ('(+Y))!$D(DIRUT) S QUIT=1
  1. Q
  1. PAUSE2 ;
  1. ;Screen pause without scrolling. Sets QUIT=1 if user decides to quit.
  1. ;
  1. N DIR,X,Y
  1. S DIR(0)="E"
  1. D ^DIR
  1. I ('(+Y))!$D(DIRUT) S QUIT=1
  1. Q
  1. ;
  1. LINE(LINE) ;Prints a line.
  1. ;
  1. I CRT,($Y>(IOSL-4)) D
  1. .D PAUSE
  1. .Q:QUIT
  1. .W @IOF
  1. .W LINE
  1. ;
  1. E I ('CRT),($Y>(IOSL-2)) D
  1. .W @IOF
  1. .W ?70,"Page: ",PAGE
  1. .S PAGE=PAGE+1
  1. .W LINE
  1. ;
  1. E W !,LINE
  1. Q
  1. ;
  1. LJ(STRING,LEN) ;
  1. Q $$LJ^XLFSTR($E(STRING,1,LEN),LEN)
  1. RJ(STRING,LEN) ;
  1. Q $$RJ^XLFSTR($E(STRING,1,LEN),LEN)