Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: IB20P337

IB20P337.m

Go to the documentation of this file. 
  1. IB20P337 ;ALB/CXW-FY06 DSS CLINIC STOP CODES IB*2.0*337 POST INIT ;15-FEB-06
  1.  ;;2.0;INTEGRATED BILLING;**337**;21-MAR-94
  1.  ;;Per VHA Directive 10-93-142, this routine should not be modified.
  1.  ;
  1. POST ;
  1.  N IBEFFDT,U
  1.  S U="^",IBEFFDT=3051001 ;effective date OCT 1st, 2005 
  1.  D START,ADD(IBEFFDT),UPDATE(IBEFFDT),FINISH
  1.  Q
  1.  ;
  1. START D MES^XPDUTL("")
  1.  D MES^XPDUTL("FY06 DSS Clinic Stop Codes, Post-Install Starting")
  1.  Q
  1.  ;
  1. FINISH ;
  1.  D MES^XPDUTL("")
  1.  D MES^XPDUTL("FY06 DSS Clinic Stop Codes, Post-Install Complete")
  1.  Q
  1.  ;
  1. MESS(IBSTR) ;
  1.  N IBA
  1.  S IBA(2)=IBSTR
  1.  S (IBA(1),IBA(3))=""
  1.  D MES^XPDUTL(.IBA)
  1.  Q
  1.  ;
  1. ADD(IBEFFDT) ;
  1.  ;add a new code
  1.  N Y,IBC,IBT,IBX,IBCODE,IBTYPE,IBDES,IBOVER
  1.  D MESS("  Adding new codes to file 352.5")
  1.  S IBC=0
  1.  F IBX=1:1 S IBT=$P($T(NCODE+IBX),";",3) Q:'$L(IBT)  D
  1.  . S IBCODE=+$P(IBT,U)
  1.  . I $D(^IBE(352.5,"AEFFDT",IBCODE,-IBEFFDT)) D  Q
  1.  . . D BMES^XPDUTL("  Duplication of non-billable type code "_IBCODE)
  1.  . S IBTYPE=$P(IBT,U,2)
  1.  . S IBDES=$E($P(IBT,U,3),1,30)
  1.  . S IBOVER=$P(IBT,U,4)
  1.  . S Y=+$$ADD3525(IBCODE,IBEFFDT,IBTYPE,IBDES,IBOVER) S:Y>0 IBC=IBC+1
  1.  D MESS("     "_IBC_$S(IBC<2:" entry",1:" entries")_" added to 352.5")
  1.  Q
  1.  ;
  1. UPDATE(IBEFFDT) ;
  1.  ;update an old code
  1.  N Y,IB1,IBC,IBT,IBX,IBCODE,IBTYPE,IBDES,IBOVER,IBLSTDT
  1.  D MESS("  Updating description and override flag in file 352.5")
  1.  S IBC=0
  1.  F IBX=1:1 S IBT=$P($T(OCODE+IBX),";",3) Q:'$L(IBT)  D
  1.  . S IBCODE=+$P(IBT,U)
  1.  . I $D(^IBE(352.5,"AEFFDT",IBCODE,-IBEFFDT)) D  Q
  1.  . . D BMES^XPDUTL("  Duplication of non-billable type code "_IBCODE)
  1.  . S IBLSTDT=$O(^IBE(352.5,"AEFFDT",IBCODE,-9999999))
  1.  . I +IBLSTDT=0 D  Q
  1.  . . D BMES^XPDUTL("  Code "_IBCODE_" not found for non-billable update")
  1.  . S IB1=$O(^IBE(352.5,"AEFFDT",IBCODE,IBLSTDT,0))
  1.  . S IBTYPE=$P($G(^IBE(352.5,IB1,0)),U,3)
  1.  . S IBDES=$E($P(IBT,U,2),1,30)
  1.  . S IBOVER=$P(IBT,U,3)
  1.  . S Y=+$$ADD3525(IBCODE,IBEFFDT,IBTYPE,IBDES,IBOVER) S:Y>0 IBC=IBC+1
  1.  D MES^XPDUTL("")
  1.  D MES^XPDUTL("     "_IBC_$S(IBC<2:" update",1:" updates")_" added to file 352.5")
  1.  Q
  1.  ;
  1. ADD3525(IBCODE,IBEFFDT,IBTYPE,IBDES,IBOVER) ;
  1.  ;add a new entry
  1.  D BMES^XPDUTL("   "_IBCODE_"  "_IBDES)
  1.  N IBIENS,IBFDA,IBER,IBRET
  1.  S IBRET=""
  1.  S IBIENS="+1,"
  1.  S IBFDA(352.5,IBIENS,.01)=IBCODE
  1.  S IBFDA(352.5,IBIENS,.02)=IBEFFDT
  1.  S IBFDA(352.5,IBIENS,.03)=IBTYPE
  1.  S IBFDA(352.5,IBIENS,.04)=IBDES
  1.  S:IBOVER IBFDA(352.5,IBIENS,.05)=1
  1.  D UPDATE^DIE("","IBFDA","IBRET","IBER")
  1.  I $D(IBER) D BMES^XPDUTL(IBER("DIERR",1,"TEXT",1))
  1.  Q $G(IBRET(1))
  1.  ;
  1.  ;new non-billable type data
  1. NCODE ;;code^billable type^description^override flag
  1.  ;;142^0^ENTEROSTOMAL TX, WOUND OR SKIN CARE^1
  1.  ;;143^0^SLEEP STUDY^1
  1.  ;;191^0^COMMUNITY ADULT DAY HEALTH CARE FOLLOW-UP^1
  1.  ;;229^0^TELEPHONE/BLIND REHAB PROGRAM^1
  1.  ;;437^0^VISUAL IMPAIRMENT CENTER TO OPTIMIZE REMAINING SIGHT (VICTORS)^1
  1.  ;;439^0^LOW VISION CARE^1
  1.  ;;694^0^STORE-AND-FORWARD TELEHEALTH^1
  1.  ;;695^0^STORE-AND-FORWARD TELEHEALTH SAME STATION^1
  1.  ;;696^0^STORE-AND-FORWARD TELEHEALTH NOT SAME STATION^1
  1.  ;
  1.  ;description and override flag updates
  1. OCODE ;;code^description^override flag
  1.  ;;683^NON-VIDEO MONITORING ONLY^1
  1.  ;