Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: IBAUTL8B

IBAUTL8B.m

Go to the documentation of this file. 
  1. IBAUTL8B ;ALB/MGD - DUPLICATE COPAY TRANSACTION UTILITIES CONT.; Sep 30, 2020@15:16:44
  1.  ;;2.0;INTEGRATED BILLING;**630**;21-MAR-94;Build 39
  1.  ;;Per VA Directive 6402, this routine should not be modified.
  1.  ;
  1.  ; ****************************************************************************
  1.  ; This routine is designed to implement a series of final checks immediately *
  1.  ; prior to IB releasing a charge over to Accounts Receivable (AR).           *
  1.  ; IBAUTL9 handles the storing of associated information related to any       *
  1.  ; duplicate copays found by IBAUTL8.                                         *                                                              *
  1.  ; These updates are part being released in IB*2.0*630.                       *
  1.  ; ****************************************************************************
  1.  ;
  1. LTCNEW(IBN,IBEVDT,IBACTION,IBINTACT) ;
  1.  ; Perform checks for a new Long Term Care Copay charge to determine if this charge should be passed over to AR.
  1.  ;   Input:     
  1.  ;          IBN = Pointer to Long Term Care Copay charge currently being reviewed in the INTEGRATED BILLING ACTION (#350) file
  1.  ;       IBEVDT = Event Date for the charge currently being reviewed in the INTEGRATED BILLING ACTION (#350) file
  1.  ;     IBACTION = Passed by reference. Passed in as 0:Pass to AR
  1.  ;     IBINTACT = Optional - Flag to indicate when the call is being made from an interactive option.
  1.  ;                1:Interactive        
  1.  ;                0:Non-Interactive
  1.  ;                For more info see COPAYCHK^IBAUTL8
  1.  ;                    
  1.  ; Output: IBACTION = 0 if the current charge being reviewed should be passed over to AR
  1.  ;                    # The IEN of the existing Copay charge for the Patient/Date of interest.
  1.  ;                      The charge being reviewed should NOT be passed over to AR.
  1.  ;
  1.  ; Verify incoming value of IBACTION and default to 0 if not defined
  1.  S IBACTION=$S(IBACTION'="":IBACTION,1:0)
  1.  ; Quit if necessary data was not passed in
  1.  I +IBN<=0!(+IBEVDT'?7N) Q
  1.  ; If IBINTACT was not passed in, default it to 0:Non-Interactive
  1.  S IBINTACT=$S(IBINTACT'="":IBINTACT,1:0)
  1.  N IBBFI,IBBFO,IBDFN,IBIEN,IBBOB,IBBPD,IBLTC,IBRSN
  1.  ; Load Patient IEN from IBN passed in
  1.  S IBDFN=+$P($G(^IB(IBN,0)),U,2)
  1.  ; Quit if no IEN in record
  1.  I IBDFN<1 Q
  1.  ; Determine if the Patient has an Inpatient Copay for the Event Date
  1.  S IBBFI=$$BFI^IBAUTL8C(IBDFN,IBEVDT,IBN)
  1.  ; Determine if the Patient has an Per Diem Copay for the Event Date
  1.  S IBBPD=$$BFPD^IBAUTL8A(IBDFN,IBEVDT,IBN)
  1.  ; Determine if the Patient has an Observation Copay for the Event Date
  1.  S IBBOB=$$BFOB^IBAUTL8A(IBDFN,IBEVDT,IBN)
  1.  ; If the Patient has already been charged an Inpatient Copay charge OR an Inpatient Per Diem charge OR
  1.  ; an Outpatient Observation Copay charge for the Event Date, Don't pass Outpatient Copay to AR
  1.  I IBBFI!IBBPD!IBBOB D  Q
  1.  . ; Set return value to NOT pass the charge over to AR
  1.  . S IBACTION=$S(IBBFI:IBBFI,IBBPD:IBBPD,IBBOB:IBBOB,1:0)
  1.  . ; Quit if interactive
  1.  . Q:IBINTACT
  1.  . ; Cancel the Outpatient Copay charge being reviewed with CANCELLATION REASON = 42 - BILLED AT HIGHER TIER RATE
  1.  . ; ### Uncomment for Phase 2 D CNCLCHRG^IBAUTL8A(IBN,42)
  1.  . ; Determine which Cancellation Reason to include in MailMan message
  1.  . I IBBFI>0 S IBIEN=IBBFI,IBRSN="EXISTING INPATIENT COPAY CHARGE WHICH HAS HIGHER PRECEDENCE"
  1.  . I IBBPD>0 S IBIEN=IBBPD,IBRSN="EXISTING INPATIENT PER DIEM CHARGE WHICH HAS HIGHER PRECEDENCE"
  1.  . I IBBOB>0 S IBIEN=IBBOB,IBRSN="EXISTING OBSERVATION COPAY CHARGE WHICH HAS HIGHER PRECEDENCE"
  1.  . ; Record related info into ^XTMP for MailMan message
  1.  . I 'IBINTACT D STORE1^IBAUTL9(IBN,IBIEN,IBRSN)
  1.  . Q
  1.  ;
  1.  ; Determine if the Patient has an Outpatient Copay for the Event Date
  1.  S IBBFO=$$BFO^IBAUTL8A(IBDFN,IBEVDT,IBN)
  1.  ; If the Patient has already been charged an Outpatient Copay for the Event Date, compare current charge being
  1.  ; reviewed to the existing Outpatient Copay charge and determine what action to take.
  1.  I IBBFO D  Q
  1.  . ; Set IBACTION = IEN of Outpatient Copay
  1.  . S IBACTION=IBBFO
  1.  . ; Quit if interactive
  1.  . Q:IBINTACT
  1.  . ; Record related info into ^XTMP for MailMan message 
  1.  . S IBRSN="EXISTING OUTPATIENT COPAY CHARGE WHICH HAS HIGHER PRECEDENCE"
  1.  . D STORE1^IBAUTL9(IBN,IBBFO,IBRSN)
  1.  ;
  1.  ; Determine if the Patient has an Long Term Care Copay for the Event Date
  1.  S IBLTC=$$LTC^IBAUTL8B(IBDFN,IBEVDT,IBN)
  1.  ; If the patient has been charged a Long Term Care Copay for the Event Date, set IBACTION and quit
  1.  I IBLTC D  Q
  1.  . ; Set IBACTION = IEN of Outpatient Copay
  1.  . S IBACTION=IBLTC
  1.  . ; Quit if interactive
  1.  . Q:IBINTACT
  1.  . N IBCTOT,IBETOT
  1.  . ; Load dollar amounts from the 2 charges. IBCTOT = Current Charge Being Reviewed Total, IBETOT = Existing Total
  1.  . S IBCTOT=+$P($G(^IB(IBN,0)),U,7),IBETOT=+$P($G(^IB(+IBLTC,0)),U,7)
  1.  . ; If the current charge being processed is <= to the existing LTC Copay charge
  1.  . I IBCTOT<=IBETOT D  Q
  1.  . . ; Cancel current charge being reviewed with CANCELLATION REASON = 4 - ENTERED IN ERROR
  1.  . . ; ### Uncomment for Phase 2 D CNCLCHRG^IBAUTL8A(IBN,4)
  1.  . . ; Record related info into ^XTMP for MailMan message
  1.  . . S IBRSN="EXISTING LTC COPAY CHARGE AT SAME OR HIGHER TIER RATE"
  1.  . . D STORE1^IBAUTL9(IBN,IBLTC,IBRSN)
  1.  . ; If the current charge being processed is > than the existing LTC Copay charge
  1.  . I IBCTOT>IBETOT D  Q
  1.  . . ; ### Uncomment for Phase 2
  1.  . . ; IBND has to be set to 0 node for call to CANC^IBECEAU4
  1.  . . ; ### N IBND S IBND=$G(^IB(IBN,0))
  1.  . . ; IBFAC and IBSITE needed by Cancel operation below
  1.  . . ; ### N IBFAC,IBSITE
  1.  . . ; Calculate site from site parameters
  1.  . . ; ### D SITE^IBAUTL
  1.  . . ; If not interactive Cancel existing charge with Reason = 42 - BILLED AT HIGHER TIER RATE
  1.  . . ; UNCOMMENT THIS AND TEST MORE ON WHAT HAPPENS IN THE CANCELLATION PROCESS
  1.  . . ; ### I 'IBINTACT D CANC^IBECEAU4(IBBFO,42,1)
  1.  . . ; Record related info into ^XTMP for MailMan message
  1.  . . S IBRSN="ANOTHER LTC COPAY CHARGE BILLED AT HIGHER TIER RATE"
  1.  . . D STORE2^IBAUTL9(IBN,IBLTC,IBRSN)
  1.  . . Q
  1.  . Q
  1.  Q
  1.  ;
  1. LTC(DFN,IBDATE,IBNEW) ; Patient Billed For Long Term Care Copay on a specified date?
  1.  ; Input:    DFN - Pointer to the patient in file #2
  1.  ;        IBDATE - Date of the Inpatient Visit
  1.  ;         IBNEW - IEN of new charge in File #350
  1.  ; Output:     0 - Not billed the LTC copay on the visit date
  1.  ;            >0 - Pointer to charge in file #350 that was billed
  1.  ;
  1.  ; Long Term Care Copays charges will be in Billing Group 8 and have Action Types:
  1.  ; Action Types =  89 - DG LTC OPT ADHC NEW          92 - DG LTC OPT GEM NEW
  1.  ;                 95 - DG LTC OPT RESPITE NEW      105 - DG LTC FEE OPT ADHC NEW
  1.  ;                108 - DG LTC FEE OPT RESPITE NEW
  1.  ;
  1.  N IBAMT,IBATYP,IBATYPN,IBCHRG,IBDATA0,IBN,IBSTOPDT
  1.  S (IBATYP,IBATYPN)="",IBAMT=0
  1.  ; Initialize the return variable to 0 - Not billed the Outpatient copay on the visit date
  1.  S IBCHRG=0
  1.  I '$G(DFN)!('$G(IBDATE)) Q +$G(IBCHRG)
  1.  ; Set stop date for loop
  1.  S IBSTOPDT=$P(IBDATE,".",1)
  1.  ; Strip off time portion of DATA and reset IBDATE for looping by subtracting .000001
  1.  S IBDATE=$P(IBDATE,".",1)-.000001
  1.  ; Loop through Date/Time entries (earliest to latest) for the single date being checked
  1.  F  S IBDATE=$O(^IB("ACHDT",DFN,IBDATE)) Q:'IBDATE!($P(IBDATE,".",1)>IBSTOPDT)  D
  1.  . ; Loop through the individual charges
  1.  . S IBN=0
  1.  . F  S IBN=$O(^IB("ACHDT",DFN,IBDATE,IBN)) Q:'IBN  D
  1.  . . ; Quit if entry found in ACHDT is the entry we are currently processing
  1.  . . Q:IBN=IBNEW
  1.  . . ; Load 0 node in File #350 for this record
  1.  . . S IBDATA0=$G(^IB(IBN,0))
  1.  . . ; Quit if ACTION TYPE is not a Long Term Care Copay
  1.  . . Q:"^89^92^95^105^108^"'[("^"_$P(IBDATA0,U,3)_"^")
  1.  . . ; using the ACTION TYPE (#.03) field of the INTEGRATED BILLING ACTION file (#350) set IBATYP = 0 Node of the IB ACTION TYPE file (#350.1)
  1.  . . S IBATYP=$G(^IBE(350.1,+$P(IBDATA0,"^",3),0))
  1.  . . ; Using IBATYP set IBATYPN = NEW ACTION TYPE (#.09)
  1.  . . S IBATYPN=$G(^IBE(350.1,+$P(IBATYP,"^",9),0))
  1.  . . ; Quit if any of the key data for the checks is missing
  1.  . . I IBDATA0=""!(IBATYP="")!(IBATYPN="") Q
  1.  . . ; Check if the BILLING GROUP field (#.11) and the ACTION TYPE (#.03) matches to the
  1.  . . ; specific combinations provided by the SMEs.
  1.  . . ; Check for Billing Group = 8:LTC OPT & charge type = a LTC Copay (89^92^95^105^108)
  1.  . . I $P(IBATYPN,"^",11)=8,("^89^92^95^105^108^"[("^"_$P(IBDATA0,U,3)_"^")) D
  1.  . . . ; IF 1:NEW or 3:UPDATE is contained in the SEQUENCE NUMBER field (#.05) in the IB ACTION TYPE file (#350.1)
  1.  . . . ; AND the STATUS field (#.05) in the INTEGRATED BILLING ACTION file (#350) is one of the following:
  1.  . . . ;    1:INCOMPLETE, 2:COMPLETE, 3:BILLED, 4:UPDATED, 8:ON HOLD, 20:HOLD - RATE 
  1.  . . . ; THEN set IBCHRG = IEN of the duplicate Outpatient Copay
  1.  . . . I "^1^3^"[("^"_$P(IBATYP,"^",5)_"^"),"^1^2^3^4^8^20^"[("^"_+$P(IBDATA0,"^",5)_"^") D
  1.  . . . . ; Compare the TOTAL CHARGE of this LTC Copay charge to any previously identified
  1.  . . . . ; LTC Copay for the same date and save the IEN of the highest charge
  1.  . . . . I +$P(IBDATA0,U,7)>IBAMT S IBAMT=+$P(IBDATA0,U,7),IBCHRG=IBN
  1.  . . . . Q
  1.  . . . Q
  1.  . . Q
  1.  . Q
  1.  Q +$G(IBCHRG)