Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: IBCEMQC

IBCEMQC.m

Go to the documentation of this file. 
  1. IBCEMQC ;ALB/ESG - MRA EOB CRITERIA FOR AUTO-AUTHORIZE ; 11/1/06 10:34am
  1.  ;;2.0;INTEGRATED BILLING;**155,323,302,350,359,447,718**;21-MAR-94;Build 73
  1.  ;;Per VHA Directive 10-93-142, this routine should not be modified.
  1.  ;
  1.  Q   ; must be called at proper entry point
  1.  ;
  1. CRIT(IBEOB) ; Function to determine if EOB entry meets the criteria for
  1.  ; auto-authorization and secondary claim submission
  1.  ;
  1.  ; Input:  IBEOB - internal entry number for an entry in 361.1
  1.  ;
  1.  ; Output:  This function returns a pieced string
  1.  ;          [1] 0 or 1, EOB meets criteria
  1.  ;          [2] error message if the first piece is 0
  1.  ;
  1.  NEW IBM,IBM3,IBM5,IBIFN,PCE,REMC,Z,OK,REASON,STOP,IBPTRESP
  1.  ;
  1.  S OK=0,REASON="Unknown",IBEOB=+$G(IBEOB)
  1.  ;
  1.  S IBM=$G(^IBM(361.1,IBEOB,0)) I IBM="" S REASON="No EOB Data Found" G CRITX
  1.  I $D(^IBM(361.1,IBEOB,"ERR")) S REASON="Filing Errors" G CRITX
  1.  I $P(IBM,U,13)'=1 S REASON="Claim Status is "_$$GET1^DIQ(361.1,IBEOB_",",.13)_".  It must be PROCESSED." G CRITX
  1.  ;
  1.  I $P(IBM,U,4)'=1 S REASON="The EOB Type is not Medicare MRA" G CRITX
  1.  ;
  1.  ; If any other MRA's on file for this bill failed the auto-generation
  1.  ; check, then this MRA must also fail the check
  1.  S IBIFN=+IBM,Z=0,STOP=0
  1.  F  S Z=$O(^IBM(361.1,"B",IBIFN,Z)) Q:'Z  D  Q:STOP
  1.  . I Z=IBEOB Q             ; check different EOB records if they exist
  1.  . I $P($G(^IBM(361.1,Z,0)),U,4)'=1 Q     ; must be an MRA
  1.  . I $P($G(^IBM(361.1,Z,30)),U,1)="" Q    ; no problems recorded
  1.  . S REASON="Another MRA for this bill (ien="_Z_") failed the auto-generation criteria check."
  1.  . S STOP=1
  1.  . Q
  1.  I STOP G CRITX
  1.  ;
  1.  ; If this EOB is a split EOB, then don't allow it
  1.  ; WCJ;IB*2.0*718;added check for incomplete MRA so treat like a split
  1.  ;I $$SPLIT^IBCEMU1(IBEOB) S REASON="Claim level remark code MA15 received.  Multiple MRA's" G CRITX
  1.  I $$SPLIT^IBCEMU1(IBEOB) S REASON="Claim level remark code MA15 received or incomplete MRA detected.  Multiple MRA's" G CRITX
  1.  ;
  1.  ; Call the function that checks the claim level and/or line level
  1.  ; adjustments for this EOB
  1.  I '$$CAS(IBEOB,"B",.REASON) G CRITX      ; "B" for both
  1.  ;
  1.  ; Make sure the patient responsibility amount for this MRA is greater than $0
  1.  S IBPTRESP=$P($G(^IBM(361.1,IBEOB,1)),U,2)      ; Pt Resp Amt 1.02 field
  1.  I $$FT^IBCEF(IBIFN)=3 S IBPTRESP=$$PTRESPI^IBCECOB1(IBEOB)
  1.  ; IB*2.0*447 PR for supplemental plans can be different
  1.  S:$$MSEDT^IBCEMU4(IBIFN)'="" IBPTRESP=$$MSPRE^IBCEMU4(IBIFN)
  1.  I IBPTRESP'>0 S REASON="Patient responsibility dollar amount is less than or equal to $0" G CRITX
  1.  ;
  1.  ; Check the parameter values last of all
  1.  I '$P($G(^IBE(350.9,1,8)),U,11) S REASON="Automatic MRA Processing parameter is turned off.  File 350.9, Field 8.11." G CRITX
  1.  I '$P($G(^IBE(350.9,1,8)),U,12) S REASON="Allow MRA Processing parameter is turned off.  File 350.9, Field 8.12." G CRITX
  1.  ;
  1.  ; At this point, we're OK
  1.  S OK=1,REASON=""
  1.  ;
  1. CRITX ;
  1.  Q OK_U_REASON
  1.  ;
  1.  ;
  1. CAS(IBEOB,ADJFLAG,REASON) ; This function determines if the EOB
  1.  ; adjustment group codes and reason codes from file 361.1 (either
  1.  ; claim level or line level or both) meet the criteria for auto-
  1.  ; authorization and secondary claim submission.
  1.  ;
  1.  ; Input Parameters
  1.  ;        IBEOB    - ien of entry in file 361.1
  1.  ;      ADJFLAG    - adjustment flag
  1.  ;                   "C" - look at claim level adjustments only
  1.  ;                   "L" - look at line level adjustments only
  1.  ;                   "B" - look at both claim and line level adjustments
  1.  ; Output Parameter
  1.  ;       REASON    - error message describing why it failed
  1.  ;
  1.  ; Function Value is either 0 or 1, indicating if it passed the criteria
  1.  ;
  1.  NEW EOBADJ,OK,OKCOMBO,PATRESP,STOP,LNIEN
  1.  ;
  1.  S IBEOB=+$G(IBEOB)
  1.  S ADJFLAG=$G(ADJFLAG,"B")     ; default is "B" if not passed in
  1.  D BUILD           ; build the array of OK group/reason combinations
  1.  S PATRESP=0       ; patient responsibility flag (default false)
  1.  S STOP=0          ; Stop flag
  1.  S OK=0            ; OK flag (function value)
  1.  S REASON=""       ; error reason text
  1.  ;
  1.  ; claim level adjustments
  1.  I $F(".C.B.","."_ADJFLAG_".") D
  1.  . KILL EOBADJ
  1.  . M EOBADJ=^IBM(361.1,IBEOB,10)
  1.  . D ADJCHK
  1.  . Q
  1.  ;
  1.  ; Get out if the claim level adjustments failed
  1.  I STOP G CASX
  1.  ;
  1.  ; line level adjustments
  1.  I $F(".L.B.","."_ADJFLAG_".") D
  1.  . S LNIEN=0
  1.  . F  S LNIEN=$O(^IBM(361.1,IBEOB,15,LNIEN)) Q:'LNIEN  D  Q:STOP
  1.  .. KILL EOBADJ
  1.  .. M EOBADJ=^IBM(361.1,IBEOB,15,LNIEN,1)
  1.  .. D ADJCHK
  1.  .. Q
  1.  . Q
  1.  ;
  1.  ; Get out if the line level adjustments failed
  1.  I STOP G CASX
  1.  ;
  1.  ; Get out if there was no patient responsibility adjustments found
  1.  I 'PATRESP S REASON="No Patient Responsibility Adjustments found" G CASX
  1.  ;
  1.  ; At this point, we're OK
  1.  S OK=1,REASON=""
  1. CASX ;
  1.  Q OK
  1.  ;
  1.  ;
  1. ADJCHK ; This procedure checks the adjustments for this EOB.  The group codes
  1.  ; and reason codes are in the EOBADJ array structures from file 361.1.
  1.  ;
  1.  ;   Variables STOP and REASON will be returned on an error
  1.  ;   Variable PATRESP will be returned if a valid PR adjustment found
  1.  ;
  1.  NEW ADJIEN,GROUP,RSNIEN,RSNCODE
  1.  S ADJIEN=0
  1.  F  S ADJIEN=$O(EOBADJ(ADJIEN)) Q:'ADJIEN  D  Q:STOP
  1.  . S GROUP=$P($G(EOBADJ(ADJIEN,0)),U,1)
  1.  . I GROUP="LQ" Q      ; line level remark code kludge: 42 rec [3]
  1.  . I GROUP="" S GROUP="<Undefined>"
  1.  . I '$D(OKCOMBO(GROUP)) S STOP=1,REASON="Unacceptable Claim Adjustment Group Code: "_GROUP Q
  1.  . S RSNIEN=0
  1.  . F  S RSNIEN=$O(EOBADJ(ADJIEN,1,RSNIEN)) Q:'RSNIEN  D  Q:STOP
  1.  .. S RSNCODE=$P($G(EOBADJ(ADJIEN,1,RSNIEN,0)),U,1)
  1.  .. ;
  1.  .. ; Ignore some special adjustment data that is filed with the MRA
  1.  .. I GROUP="PR",RSNCODE="AAA" Q    ; Allowed Amount: 41 rec [3]
  1.  .. I GROUP="OA",RSNCODE="AB3" Q    ; Covered Amount: 15 rec [3]
  1.  .. ;
  1.  .. I RSNCODE="" S RSNCODE="<Undefined>"
  1.  .. I '$D(OKCOMBO(GROUP,RSNCODE)) S STOP=1,REASON="Unacceptable Reason Code ("_RSNCODE_") for Claim Adjustment Group Code ("_GROUP_")" Q
  1.  .. ;
  1.  .. ; Set the flag if the group is PR
  1.  .. I GROUP="PR" S PATRESP=1
  1.  .. Q
  1.  . Q
  1. ADJCHKX ;
  1.  Q
  1.  ;
  1.  ;
  1. BUILD ; This procedure builds the OKCOMBO array which identifies which
  1.  ; combinations of group codes and reason codes are acceptable
  1.  ;
  1.  NEW LN,LINE,GROUP,RSNLST,R,RSN
  1.  KILL OKCOMBO
  1.  F LN=1:1 D  Q:$P(LINE,";",4)=""&$D(OKCOMBO)
  1.  . S LINE=$T(OKCOMBO+LN)
  1.  . S GROUP=$P(LINE,";",3) Q:GROUP=""
  1.  . S RSNLST=$P(LINE,";",4) Q:RSNLST=""
  1.  . F R=1:1:$L(RSNLST,",") D
  1.  .. S RSN=$P(RSNLST,",",R) Q:RSN=""
  1.  .. S OKCOMBO(GROUP,RSN)=""
  1.  .. Q
  1.  . Q
  1. BUILDX ;
  1.  Q
  1.  ;
  1.  ;
  1. OKCOMBO ; This section lists OK combinations of adjustment category group codes
  1.  ; and associated reason codes.
  1.  ; The format is as follows - semi-colon delimiter
  1.  ;     [3] Adjustment category (group code)
  1.  ;     [4] List of acceptable reason codes - comma delimiter
  1.  ;
  1.  ; PR-AAA is created by VistA for the Allowed Amount
  1.  ; OA-AB3 is created by VistA for the Covered Amount
  1.  ; LQ-zzz is created by VistA for the Line Level remark
  1.  ;
  1.  ;;CO;A2,B6,42,45,172,94,194
  1.  ;;PR;1,2,66,122,AAA
  1.  ;;OA;AB3
  1.  ;