Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: IBCEMSR7

IBCEMSR7.m

Go to the documentation of this file. 
  1. IBCEMSR7 ;ALB/VAD - IB PRINTED CLAIMS REPORT - Print ;09-SEP-2015
  1.  ;;2.0;INTEGRATED BILLING;**547**;21-MAR-94;Build 119
  1.  ;;Per VA Directive 6402, this routine should not be modified.
  1.  ;
  1. REPORT ; - Entry point to print report
  1.  N EORMSG,IBPAG,IBDTRG,LOCCNT,TOTCNT,TOTLN,IBX,IBQUIT,IBOF,IBDIVN
  1.  S IBDIVN=$S($D(IBDIVS("ALL")):"ALL",1:"")
  1.  I IBDIVN="" S IBX="" F  S IBX=$O(IBDIVS(IBX)) Q:IBX=""!(IBX="ALL")  S IBDIVN=$S(IBDIVN="":$G(IBDIVS(IBX)),1:IBDIVN_", "_$G(IBDIVS(IBX)))
  1.  S IBDTRG=$$DAT3^IBOUTL($E(IBBDT,1,10))_" - "_$$DAT3^IBOUTL($E(IBEDT,1,10))
  1.  S LOCCNT=+$P($G(^TMP($J,"IBCEMSRP-DATA")),U,1),TOTCNT=+$P($G(^TMP($J,"IBCEMSRP-DATA")),U,2)
  1.  S IBPAG=0
  1.  D PRINT
  1.  S TOTLN="Total Claims:  "_TOTCNT
  1.  S TOTLN=TOTLN_"    Number of Transmittable Claims Printed:  "_LOCCNT
  1.  S TOTLN=TOTLN_"    % Of Total Claims Printed:  "_$S(TOTCNT=0:0,1:$J(((LOCCNT/TOTCNT)*100),6,2)_"%")
  1.  W !!!!,?10,TOTLN
  1.  K ^TMP($J,"IBCEMSRP-DATA")
  1.  S EORMSG="*** END OF REPORT ***"
  1.  W !!!,EORMSG
  1.  D PAUSE
  1.  ;
  1.  I $D(ZTQUEUED) S ZTREQ="@" Q
  1.  D END
  1.  Q
  1.  ;
  1. END  ; Close Device
  1.  K IBSORT,VARRAY,IBCOT,IBBDT,IBDIVS,IBEDT,INSADD,ZTREQ,ZTQUEUED
  1.  D ^%ZISC
  1.  Q
  1.  ;
  1. PRINT ; Print report
  1.  N SRTFLD,BILLNO,IBDATA,IBRVCDS,IBHDT
  1.  ; ^TMP($J,"IBCEMSRP-DATA",SRTFLD,BILLNO)=IBTYPE_U_IBRTYP_U_IBPTYP_U_IBDVN_U_IBBLLR_U_INSCO_U_INSADD
  1.  ; ^TMP($J,"IBCEMSRP-DATA",SRTFLD,BILLNO,"RVCDS")=IBRVCDS
  1.  S IBHDT=$$FMTE^XLFDT($$NOW^XLFDT,"M")
  1.  D HEADER
  1.  S SRTFLD=""
  1.  F  S SRTFLD=$O(^TMP($J,"IBCEMSRP-DATA",SRTFLD)) Q:SRTFLD=""  D  Q:$G(IBQUIT)=1
  1.  . I $Y>(IOSL-5) D PAUSE Q:$G(IBQUIT)=1  D HEADER
  1.  . ; if sorted by insurance company, add address to subheader
  1.  . I $P(IBSORT,U)="I" S INSADD=$G(^TMP($J,"IBCEMSRP-DATA",SRTFLD))
  1.  . D SUBHD
  1.  . S BILLNO=""
  1.  . F  S BILLNO=$O(^TMP($J,"IBCEMSRP-DATA",SRTFLD,BILLNO)) Q:BILLNO=""  D  Q:$G(IBQUIT)=1
  1.  . . S IBDATA=$G(^TMP($J,"IBCEMSRP-DATA",SRTFLD,BILLNO))
  1.  . . S IBRVCDS=$G(^TMP($J,"IBCEMSRP-DATA",SRTFLD,BILLNO,"RVCDS"))
  1.  . . ;
  1.  . . I $Y>(IOSL-5) D PAUSE Q:$G(IBQUIT)=1  D HEADER,SUBHD
  1.  . . ;
  1.  . . W !,BILLNO,?16,$P(IBDATA,U),?22,$E($P(IBDATA,U,2),1,20),?45,$E($P(IBDATA,U,3),1,25),?73,$E($P(IBDATA,U,4),1,15),?91,$E($P(IBDATA,U,5),1,15),?109,IBRVCDS     ; <=== IBRVCDS NEEDS ONLY PRINT 6 PER LINE.
  1.  . . W:$P(IBSORT,U)'="I" !?6,$P(IBDATA,U,6),"  ",$P(IBDATA,U,7)
  1.  . . ;
  1.  Q
  1.  ;
  1.  I $E(IOST,1,2)="C-"!(IBPAG) W @IOF
  1.  S IBPAG=IBPAG+1
  1.  W !,"Printed Claim Report"
  1.  W ?IOM-85,IBDTRG,?IOM-12,"Page: ",IBPAG
  1.  W !,"Run for: "_$S(IBCOT="C":"CPAC",1:"TRICARE/CHAMPVA")_", Divisions: "_IBDIVN,?IOM-12,$E(IBHDT,1,12)
  1.  W !,"Sorted by: "_$P(IBSORT,U,2)
  1.  Q
  1.  ;
  1. SUBHD ; Print sub-header
  1.  W !!,SRTFLD W:$P(IBSORT,U)="I" "  "_$G(INSADD)
  1.  W !," Claim #",?16,"Type",?22,"RateType",?45,"PlanType",?73,"Division",?91,"Biller",?109,"RevCode"
  1.  W:$P(IBSORT,U)'="I" !?6,"InsuranceCo"
  1.  W !,$TR($J("",131)," ","-")
  1.  Q
  1.  ;
  1. PAUSE ; Pause for screen output.
  1.  Q:$E(IOST,1,2)'["C-"
  1.  N IBJJ,DIR,DIRUT,DUOUT,DTOUT,DIROUT,X,Y
  1.  F IBJJ=$Y:1:(IOSL-7) W !
  1.  S DIR(0)="E" D ^DIR S:$D(DIRUT)!($D(DUOUT)) IBQUIT=1
  1.  Q