Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: IBCIPAY

IBCIPAY.m

Go to the documentation of this file. 
  1. IBCIPAY ;DSI/ESG - Extract data and create Ingenix Payor File ;11-JAN-2001
  1.  ;;2.0;INTEGRATED BILLING;**161**;21-MAR-94
  1.  ;;Per VHA Directive 10-93-142, this routine should not be modified.
  1.  ;
  1. ENTRY ; Entry point for routine (or called from the top)
  1.  NEW IBCIRTN,STOP,IBCIPATH,IBCIFILE
  1.  D INIT
  1.  D INTRO
  1.  I STOP G EXIT
  1.  D GETPATH^IBCINPT     ; get the file location & Open the file
  1.  I STOP G EXIT
  1.  D OUTPUT              ; build the file & Close the file
  1. EXIT ;
  1.  ; Routine Exit
  1.  Q
  1.  ;
  1.  ;
  1. INIT ; Procedure to initialize some routine-wide variables
  1.  S IBCIRTN="IBCIPAY"              ; routine name, IO handle
  1.  S STOP=0                         ; stop flag
  1.  S IBCIFILE="IBCIPAY.DAT"         ; name of file that gets created
  1. INITX ;
  1.  Q
  1.  ;
  1.  ;
  1. INTRO ; This procedure displays introductory text and asks if the user
  1.  ; wants to proceed with the creation of the PAYOR file.
  1.  ;
  1.  W @IOF
  1.  NEW Y,IBCIMSG,DIR,X,DTOUT,DUOUT,DIRUT,DIROUT
  1.  ;
  1.  S IBCIMSG(1)=" This option is responsible for creating the Payor File"
  1.  S IBCIMSG(2)=" for the ClaimsManager application from Ingenix.  This"
  1.  S IBCIMSG(3)=" is a listing of the Insurance Companies that are currently"
  1.  S IBCIMSG(4)=" stored in VistA."
  1.  S IBCIMSG(5)=""
  1.  ;
  1.  DO EN^DDIOL(.IBCIMSG)
  1.  ;
  1.  ; Now for the user response
  1.  ;
  1.  S DIR(0)="Y"
  1.  S DIR("A")=" Do you wish to proceed"
  1.  S DIR("B")="NO"
  1.  DO ^DIR
  1.  I 'Y S STOP=1
  1. INTROX ;
  1.  Q
  1.  ;
  1.  ;
  1. OUTPUT ; This procedure displays a VistA "please wait" message to the user
  1.  ; while it loops through the "B" cross reference to the INSURANCE
  1.  ; COMPANY FILE (#36).  The file is closed here and a confirmation
  1.  ; message is shown to the user.
  1.  ;
  1.  NEW INSNAME,COUNT,IEN,IBCIMSG,POP,X,X1,X2,X3,X4,Y
  1.  DO WAIT^DICD
  1.  ;
  1.  ; Use the file for writing
  1.  U IO
  1.  ;
  1.  ; loop through and write the data
  1.  S INSNAME="",COUNT=0
  1.  F  S INSNAME=$O(^DIC(36,"B",INSNAME)) Q:INSNAME=""  D
  1.  . S IEN=0
  1.  . F  S IEN=$O(^DIC(36,"B",INSNAME,IEN)) Q:'IEN  D
  1.  .. I $P($G(^DIC(36,IEN,0)),U,5) Q     ; INACTIVE flag
  1.  .. I $P($G(^DIC(36,IEN,5)),U,1) Q     ; SCHEDULED FOR DELETION flag
  1.  .. S X=IEN,X1=20,X4="T" W $$FILL^IBCIUT2
  1.  .. S X=INSNAME,X1=40,X4="T" W $$FILL^IBCIUT2
  1.  .. W !
  1.  .. S COUNT=COUNT+1
  1.  .. Q
  1.  . Q
  1.  ;
  1.  ; The file has been created so close it and tell the user
  1.  DO CLOSE^%ZISH(IBCIRTN)
  1.  U IO(0)
  1.  S IBCIMSG(1)=" There are "_COUNT_" records in the Payor File."
  1.  S IBCIMSG(2)=" The Payor File creation process is complete!"
  1.  S IBCIMSG(3)=""
  1.  S IBCIMSG(1,"F")="!!"
  1.  DO EN^DDIOL(.IBCIMSG)
  1.  ;
  1. OUTPUTX ;
  1.  Q
  1.  ;