Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: IBCREQ

IBCREQ.m

Go to the documentation of this file. 
  1. IBCREQ ;ALB/ARH-RATES: CM FAST ENTER/EDIT OPTION ;22-MAY-1996
  1.  ;;2.0;INTEGRATED BILLING;**52,153,167,187**;21-MAR-94
  1.  ;;Per VHA Directive 10-93-142, this routine should not be modified.
  1.  ;
  1. ENTER ; OPTION:  fast enter Tort or Interagency rates - this option requires charge sets defined as released,
  1.  ; name not changed and a standard set of charges
  1.  N DIR,DIRUT,DTOUT,DUOUT,X,Y,IBARR,IBRATE,IBEFDT,IBRVCD
  1.  W @IOF W !!,?10,"Fast Enter of Tortiously Liable and Interagency Rates",!!
  1.  ;
  1.  S DIR(0)="SO^T:Tortiously Liable;I:Interagency",DIR("A")="Enter which rates" D ^DIR K DIR
  1.  S IBRATE=$S(Y="T":"1^TORTIOUSLY LIABLE",Y="I":"2^INTERAGENCY",1:"") Q:'IBRATE
  1.  ;
  1.  S IBEFDT=$$GETDT^IBCRU1() I IBEFDT'?7N Q
  1.  I +IBRATE=1 S IBRVCD=$$NPFRC Q:'IBRVCD  I '$$TORT(IBRATE,IBEFDT,.IBARR,IBRVCD) Q
  1.  I +IBRATE=2 I '$$IA(IBRATE,IBEFDT,.IBARR) Q
  1.  ;
  1.  D DISP(IBRATE,.IBARR) Q:$D(DIRUT)
  1.  I +IBRATE=2 D SET(IBRATE,.IBARR)
  1.  E  D SET(IBRATE,.IBARR):'$$MT
  1.  ;
  1.  I IBRATE=1 D ENR^IBEMTO K IBRUN ; bill MT OPT charges awaiting the new copay rate
  1.  ;
  1.  Q
  1.  ;
  1. TORT(IBRATE,EFDT,ARR,IBRVCD) ; find the standard charge sets for Tort rates
  1.  N IBCSN,IBX K ARR S ARR=$G(EFDT),IBRVCD=$G(IBRVCD),IBX=0
  1.  S ARR(1)="INPATIENT^INPT",ARR(2)="OUTPATIENT VISIT^OPT VISIT",ARR(3)="PRESCRIPTION REFILL^RX REFILL"
  1.  S ARR(4)="OUTPATIENT DENTAL^OPT DENTAL" ;ARR(5)="MT OUTPATIENT COPAYMENT^MT OPT COPAY"
  1.  S IBCSN="TL-INPT (INCLUSIVE)" I '$$CS(IBRATE,IBCSN,1,1,"","(All Inclusive)",.ARR) G TORTQ
  1.  S IBCSN="TL-INPT (NPF)" I '$$CS(IBRATE,IBCSN,1,2,$P(IBRVCD,U,1),"(Room,board)",.ARR) G TORTQ
  1.  S IBCSN="TL-INPT (NPF)" I '$$CS(IBRATE,IBCSN,1,3,$P(IBRVCD,U,2),"(Ancillary)",.ARR) G TORTQ
  1.  S IBCSN="TL-INPT (PF)" I '$$CS(IBRATE,IBCSN,1,4,"","(Physician)",.ARR) G TORTQ
  1.  S IBCSN="TL-OPT VST" I '$$CS(IBRATE,IBCSN,2,1,"","",.ARR) G TORTQ
  1.  S IBCSN="TL-RX FILL" I '$$CS(IBRATE,IBCSN,3,1,"","",.ARR) G TORTQ
  1.  S IBCSN="TL-OPT DENTAL" I '$$CS(IBRATE,IBCSN,4,1,"","",.ARR) G TORTQ
  1.  ;S IBCSN="TL-MT OPT COPAY" I '$$CS(IBRATE,IBCSN,5,1,"","",.ARR) G TORTQ
  1.  S IBX=1
  1. TORTQ I 'IBX W !!,"The Fast Enter of rates expects to find the standard rates and sets released",!,"nationally, if these are not found this option can not be used."
  1.  Q IBX
  1.  ;
  1. IA(IBRATE,EFDT,ARR) ; find the standard charge sets for Interagency rates
  1.  N IBCSN,IBX K ARR S ARR=$G(EFDT),IBX=0
  1.  S ARR(1)="INPATIENT",ARR(2)="OUTPATIENT VISIT",ARR(3)="PRESCRIPTION REFILL",ARR(4)="OUTPATIENT DENTAL"
  1.  S ARR(1)="INPATIENT^INPT",ARR(2)="OUTPATIENT VISIT^OPT VISIT",ARR(3)="PRESCRIPTION REFILL^RX REFILL",ARR(4)="OUTPATIENT DENTAL^OPT DENTAL"
  1.  S IBCSN="IA-INPT" I '$$CS(IBRATE,IBCSN,1,1,"","(All Inclusive)",.ARR) G IAQ
  1.  S IBCSN="IA-OPT VST" I '$$CS(IBRATE,IBCSN,2,1,"","",.ARR) G IAQ
  1.  S IBCSN="IA-RX FILL" I '$$CS(IBRATE,IBCSN,3,1,"","",.ARR) G IAQ
  1.  S IBCSN="IA-OPT DENTAL" I '$$CS(IBRATE,IBCSN,4,1,"","",.ARR) G IAQ
  1.  S IBX=1
  1. IAQ I 'IBX W !!,"The Fast Enter of rates expects to find the standard rates and sets released",!,"nationally, if these are not found this option can not be used."
  1.  Q IBX
  1.  ;
  1. CS(IBRATE,IBCSN,TYPE,ITEM,RVCD,DESC,ARR) ; accumulate standard charge sets for a rate
  1.  ; check the billing rate is correct and return all relevant info
  1.  ; Output:  ARR(event type) = event type name
  1.  ;          ARR(event type, X) = CS name ^ CS IFN ^ default rev code ^ rev code to store ^ description of charge
  1.  N IBX,IBCS,IBLN,IBERROR S (IBERROR,IBX)=""
  1.  S IBCS=$O(^IBE(363.1,"B",IBCSN,0)) I +IBCS  D
  1.  . S IBLN=$G(^IBE(363.1,IBCS,0)) Q:IBLN=""
  1.  . I $P(IBLN,U,2)'=+IBRATE S IBERROR="*** Error:  Charge Set "_IBCSN_" is not a "_$P(IBRATE,U,2)_" rate." Q
  1.  . S IBX=IBCS,ARR(TYPE,ITEM)=IBCSN_U_IBCS_U_$S($G(RVCD):RVCD,1:$P(IBLN,U,5))_U_$G(RVCD)_U_$G(DESC)
  1.  I 'IBX,IBERROR="" S IBERROR="*** Error:  The Charge Set "_IBCSN_" was not found."
  1.  I IBERROR'="" W !!!,IBERROR,!,"            Can not continue!"
  1.  Q IBX
  1.  ;
  1. SET(IBRATE,ARR) ; add/edit charges:  for each type of charge and each item, displays rev code and description
  1.  ; then askes the user for bedsection and charge
  1.  ;
  1.  N IBEFDT,IBTYP,IBBS,IBJ,IBIT,IBLN,IBCS,IBRVCD,IBCHG,IBOCHG,IBCI,IBX,IBDFTY,DIR,DIRUT,DTOUT,DUOUT,X,Y
  1.  S IBEFDT=+ARR
  1.  S IBTYP=0 F  S IBTYP=$O(ARR(IBTYP)) Q:'IBTYP  D  Q:IBBS<0
  1.  . W !!,"--------------------------------------------------------------------------------"
  1.  . W !,"Enter ",$P(ARR(IBTYP),U,1)," ",$P(IBRATE,U,2)," charges effective ",$$FMTE^XLFDT(IBEFDT),":"
  1.  . W !,"--------------------------------------------------------------------------------"
  1.  . S IBDFTY=IBTYP
  1.  . F IBJ=1:1 W ! S IBBS=$$GETBS(10,$P(ARR(IBTYP),U,2),IBDFTY) Q:IBBS<1  D  I IBTYP>1 S IBDFTY=""
  1.  .. S IBIT=0 F  S IBIT=$O(ARR(IBTYP,IBIT)) Q:'IBIT  D  I $D(DUOUT) Q
  1.  ... S IBLN=ARR(IBTYP,IBIT),IBCS=$P(IBLN,U,2),IBRVCD=$P(IBLN,U,4),IBOCHG=""
  1.  ... S IBX=$E($P(IBBS,U,2),1,28)
  1.  ... S IBX=IBX_$J("",(30-$L(IBX)))_$P(IBLN,U,5)
  1.  ... S IBX=IBX_$J("",(50-$L(IBX)))_$P($G(^DGCR(399.2,+$P(IBLN,U,3),0)),U,1)_"  $ = "
  1.  ... S IBCI=$$FINDCI^IBCRU4(IBCS,+IBBS,IBEFDT,"",IBRVCD)
  1.  ... I +IBCI S IBOCHG=$P($G(^IBA(363.2,+IBCI,0)),U,5),DIR("B")=$FN(IBOCHG,"",2)
  1.  ... S DIR("A")=IBX,DIR(0)="NAO^0:999999:2" D ^DIR K DIR S IBCHG=+Y I IBCHG<1!(IBCHG=IBOCHG) Q
  1.  ... I 'IBCI S IBCI=$$ADDCI^IBCREF(IBCS,+IBBS,IBEFDT,IBCHG,IBRVCD) I +IBCI W ?74,"added" Q
  1.  ... I +IBCI D EDITCI^IBCREF(+IBCI,+IBCHG) W ?74,"edited"
  1.  Q
  1.  ;
  1. NPFRC() ; get the default revenue codes for non-professional inpatient services
  1.  ;
  1.  N IBX,DIC,X,Y,DTOUT,DUOUT,IBY S IBX=0
  1.  W !!,"Enter the Revenue Code to use for all non-professional inpatient services:",!
  1.  S DIC("A")="Room, Board, Nursing Services: ",DIC("B")=101,DIC("S")="I +$P(^(0),U,3)"
  1.  S DIC="^DGCR(399.2,",DIC(0)="AEQ" D ^DIC I Y<1 G NPFRCQ
  1.  S IBY=+Y
  1.  ;
  1.  S DIC("A")="Ancillary Services: ",DIC("B")=240,DIC("S")="I +$P(^(0),U,3)"
  1.  S DIC="^DGCR(399.2,",DIC(0)="AEQ" D ^DIC I Y<1 G NPFRCQ
  1.  S IBX=IBY_U_+Y
  1.  ;
  1. NPFRCQ I 'IBX W !!,"Both of these revenue codes are required for the Inpatient Non-Professional",!,"charges to be added to bills.  Can Not Continue!",!
  1.  Q IBX
  1.  ;
  1. DISP(IBRATE,ARR) ;
  1.  N IBTYP,IBI,IBLN
  1.  W @IOF,!,$P(IBRATE,U,2)," charges effective ",$$FMTE^XLFDT(ARR)," will be added as follows:"
  1.  W !,"Charge Type",?30,"Charge Set",?55,"Rev Code",!,"--------------------------------------------------------------------------------",!
  1.  S IBTYP=0 F  S IBTYP=$O(ARR(IBTYP)) Q:'IBTYP  D
  1.  . W $P(ARR(IBTYP),U,1)
  1.  . S IBI=0 F  S IBI=$O(ARR(IBTYP,IBI)) Q:'IBI  D
  1.  .. S IBLN=ARR(IBTYP,IBI)
  1.  .. W ?30,$P(IBLN,U,1),?55,$P($G(^DGCR(399.2,+$P(IBLN,U,3),0)),U,1),?65,$P(IBLN,U,5),!
  1.  W !,"If any of the revenue codes are incorrect then change the Default Revenue for",!,"the Charge set." W:+IBRATE=1 " (except the non-prof inpt rev codes entered above)"
  1.  W !!,"If any of the Charge Sets are incorrect DO NOT USE this option."
  1.  W !,"This option may NOT be used to delete rates or add zero charges."
  1.  W !!,"The charges will be asked in sections based on the Charge Types listed above."
  1.  W !,"The first section is INPATIENT, enter all Inpatient Bedsections and their"
  1.  W !,"charges, then press return at the Select Bedsection prompt to move to the"
  1.  W !,"OUTPATIENT VISIT section and enter the Outpatient Visit Bedsection and charge..."
  1.  W ! S DIR(0)="E" D ^DIR K DIR
  1.  Q
  1.  ;
  1. GETBS(COL,PROMPT,TYPE) ; ask and return billable bedsection (399.1):  (-1 if ^, 0 if none)  IFN^.01
  1.  ; if type is inpatient then not PRESCRIPTION or OUTPATIENT bedsections can be selected
  1.  ; if type is not inpatient then default bedsections are provided
  1.  N IBX,DIC,DIE,DA,DR,X,Y,DTOUT,DUOUT S IBX=0
  1.  S DIC("S")="I +$P(^(0),U,5)=1"
  1.  I $G(TYPE)=1 S DIC("S")=DIC("S")_",$P(^(0),U,1)'[""OUTPATIENT"",$P(^(0),U,1)'[""PRESCRIPTION"""
  1.  I +$G(TYPE)>1 S DIC("B")=$S(TYPE=3:"PRESCRIPTION",TYPE=4:"OUTPATIENT DENTAL",1:"OUTPATIENT VISIT")
  1.  S DIC("A")=$J("",$G(COL))_"Select "_$G(PROMPT)_" BEDSECTION: "
  1.  S DIC="^DGCR(399.1,",DIC(0)="AENQ" D ^DIC K DIC
  1.  I $D(DTOUT)!($D(DUOUT)) S IBX=-1
  1.  I +Y>0 S IBX=Y
  1.  Q IBX
  1.  ;
  1. MT() ; do the new mt rate format (misc type) eff 12/6/01 ib*2*167
  1.  N IBCS,IBTYPE,IBITEM,IBCI,IBX,IBOCHG,DIR,X,Y,IBCHG,IBERROR
  1.  S IBCS=$$CSN^IBCRU3("TL-MT OPT COPAY"),(IBOCHG,IBERROR)=""
  1.  I 'IBCS W !,"*** Error:  Charge set TL-MT OPT COPAY not found" Q 1
  1.  W !!,"--------------------------------------------------------------------------------"
  1.  W !,"Enter MT OUTPATIENT COPAYMENT charges effective ",$$FMTE^XLFDT(IBEFDT),":"
  1.  W !,"--------------------------------------------------------------------------------"
  1.  F IBTYPE="BASIC CARE","SPECIALTY CARE" D  Q:$L(IBERROR)
  1.  . S IBITEM=+$$ADDBI^IBCREF("MISCELLANEOUS",IBTYPE)
  1.  . I 'IBITEM S IBERROR="*** Error:  Billable Item "_IBTYPE_" not found" Q
  1.  . S IBX=IBTYPE_$J("",(50-$L(IBTYPE)))_"$ ="
  1.  . S IBCI=$$FINDCI^IBCRU4(IBCS,+IBITEM,IBEFDT)
  1.  . I +IBCI S IBOCHG=$P($G(^IBA(363.2,+IBCI,0)),U,5),DIR("B")=$FN(IBOCHG,"",2)
  1.  . S DIR("A")=IBX,DIR(0)="NAO^0:999999:2" D ^DIR K DIR S IBCHG=+Y I IBCHG<1!(IBCHG=IBOCHG) Q
  1.  . I 'IBCI S IBCI=$$ADDCI^IBCREF(IBCS,+IBITEM,IBEFDT,IBCHG) I +IBCI W ?74,"added" Q
  1.  . I +IBCI D EDITCI^IBCREF(+IBCI,+IBCHG) W ?74,"edited"
  1.  W !,IBERROR
  1.  Q $L(IBERROR)