Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: IBEFUR

IBEFUR.m

Go to the documentation of this file. 
  1. IBEFUR ;ALB/ARH - UTILITY: FIND RELATED FIRST AND THIRD PARTY BILLS ; 3/7/00
  1.  ;;2.0;INTEGRATED BILLING;**130,459,728**;21-MAR-94;Build 14
  1.  ;;Per VHA Directive 10-93-142, this routine should not be modified.
  1.  ; 
  1.  ; Called by Accounts Receivable report option
  1.  ;
  1.  ; for a specific Third Party bill, return all related Third Party bills
  1.  ; matchs with the selected bill are based on:   (selected bill is included in list returned)
  1.  ; 1)  Event Date (399,.03), returns all bills with same Event Date
  1.  ; 
  1.  ; 2)  PTF # (399,.08), returns all bills with the same PTF number
  1.  ; 3)  PTF # (399,.08), returns all bills with Outpatient Visit Dates (399,43) within the admission date range
  1.  ; 
  1.  ; 4)  Opt Visit Dates (399,43), returns all bills with one or more matching Opt Visit Dates
  1.  ; 5)  Opt Visit Dates (399,43), returns all bills for any PTF (399,.08) stay covering any of the Opt Visit Dates
  1.  ;
  1.  ; 6)  Prescriptions (362.4): returns all bills with one or more matching Rx # and fill date
  1.  ;
  1.  ; ^TMP("IBRBT", $J, selected bill ifn) = PATIENT HAS ANY RX COVERAGE ON FROM DATE OF BILL (0/1)
  1.  ; ^TMP("IBRBT", $J, selected bill ifn, matching bill ifn) = 
  1.  ;                                        BILL FROM ^ BILL TO ^ CANCELLED (0/1) ^ AR BILL NUMBER ^ 
  1.  ;                                        PAYER SEQUENCE ^ PAYER IS MEDICARE SUPPLEMENTAL (0/1) ^ PAYER NAME
  1.  ;
  1. TPTP(IBIFN) ; given a specific Third Party bill, find all related Third Party Bills
  1.  N IB0,DFN,IBEVDT,IBPTF,IBADM,IBDIS,IBOPV,IBPTF1,IBXRF,IBRXN,IBRXDT,IBX Q:'$G(IBIFN)
  1.  S IB0=$G(^DGCR(399,+IBIFN,0)) Q:IB0=""  S DFN=$P(IB0,U,2),IBEVDT=$P(IB0,U,3),IBPTF=$P(IB0,U,8)
  1.  ;
  1.  K ^TMP("IBRBT",$J,IBIFN) S IBX=$$LN1^IBEFURT(IBIFN) D SAVELN1^IBEFURT(IBIFN,IBX)
  1.  ;
  1.  I +IBEVDT D TPEVDT^IBEFURT(DFN,IBEVDT,IBIFN) ; find all bills with the same Event Date (399,.03)
  1.  ;
  1. IT I +IBPTF D TPPTF^IBEFURT(IBPTF,IBIFN) ; find all bills with the same PTF number  (399,.08)
  1.  ;
  1.  ; find any bills with Outpatient Visit Dates within the date range of the admission (PTF)
  1.  I +IBPTF S IBADM=$P($G(^DGPT(+IBPTF,0)),U,2),IBDIS=+$G(^DGPT(+IBPTF,70)) S:'IBDIS IBDIS=DT D
  1.  . D TPOPV^IBEFURT(DFN,IBADM,IBDIS,IBIFN)
  1.  ;
  1. OT ; find all bills that have one or more of the same Opt Visit Dates (399,43)
  1.  S IBX=0 F  S IBX=$O(^DGCR(399,+IBIFN,"OP",IBX)) Q:'IBX  S IBOPV=+$G(^DGCR(399,+IBIFN,"OP",IBX,0)) D
  1.  . D TPOPV^IBEFURT(DFN,IBOPV,IBOPV,IBIFN)
  1.  ;
  1.  ; find any bills for inpatient admissions whose date range includes one or more of the Opt Visit Dates
  1.  S IBX=0 F  S IBX=$O(^DGCR(399,+IBIFN,"OP",IBX)) Q:'IBX  S IBOPV=+$G(^DGCR(399,+IBIFN,"OP",IBX,0)) D
  1.  . S IBADM=$$ADM^IBCU64(DFN,IBOPV) I +IBADM S IBPTF1=$P(IBADM,U,4) I +IBPTF1 D
  1.  .. D TPPTF^IBEFURT(IBPTF1,IBIFN)
  1.  ;
  1. RT ; find all bills that have one or more of the same Prescription: same Rx number and fill date (362.4,.01,.03)
  1.  S IBXRF="AIFN"_IBIFN,IBRXN="" F  S IBRXN=$O(^IBA(362.4,IBXRF,IBRXN))  Q:'IBRXN  D
  1.  . S IBX=0 F  S IBX=$O(^IBA(362.4,IBXRF,IBRXN,IBX)) Q:'IBX  S IBRXDT=$P($G(^IBA(362.4,IBX,0)),U,3) D
  1.  .. D TPRX^IBEFURT(DFN,IBRXN,IBRXDT,IBIFN)
  1.  Q
  1.  ;
  1.  ; ==============================================================================================================
  1.  ;
  1.  ; Called by Accounts Receivable report option
  1.  ;
  1.  ; for a specific Third Party bill, return all related First Party Charges
  1.  ; only a single record of a charge event is returned, defining the charges current status, although there may 
  1.  ; have been cancellations or updates to the original charge
  1.  ;    o Inpatient Events may have multiple charge events (Copay and Per Diem)
  1.  ;    o Opt and Rx Events have only a single charge event (Copay)
  1.  ; 
  1.  ; matchs with the selected bill are based on:
  1.  ; 1) Event Date (399,.03), returns Inpatient charges whose Parent Event (350,.16) has that Event Date (350,.17)
  1.  ; 2) PTF # (399,.08), returns Outpatient charge for Opt Visits Dates within timeframe of admission
  1.  ; 
  1.  ; 3) Opt Visit Date (399,43), returns the Outpatient charge for that Event Date (350,.17)
  1.  ; 4) Opt Visit Date (399,43), returns Inpatient charges for any admission that includes that Opt Visit Date
  1.  ; 
  1.  ; 5) Rx Record (362.4,.05) and Rx Date (362.4,.03) and Outpatient Pharmacy, returns the Rx charge for the fill
  1.  ; 6) Opt Visit Date (399,43) and Outpatient Pharmacy, returns any First Party Rx charge on one of the 
  1.  ;    selected bills Opt Visit Dates that is not billed on any Third Party bill
  1.  ;
  1.  ; ^TMP("IBRBF", $J , selected bill ifn ) = ""
  1.  ; ^TMP("IBRBF", $J , selected bill ifn , charge ifn) = 
  1.  ; BILL FROM ^ BILL TO ^ CANCELLED? (1/0)^ AR BILL NUMBER ^ TOTAL CHARGE ^ ACTION TYPE (SHORT) ^ # DAYS ON HOLD
  1.  ;
  1. TPFP(IBIFN) ; given a specific Third Party Bill, find all related First Party Bills
  1.  N IBX,IBY,IB0,DFN,IBEVDT,IBPTF,IBADM,IBOPV,IBXRF,IBRXN,IBRXIFN,IBRXDT,IBFROM,IBTO,IBU Q:'$G(IBIFN)
  1.  S IB0=$G(^DGCR(399,+IBIFN,0)) Q:IB0=""  S DFN=$P(IB0,U,2),IBEVDT=$P(IB0,U,3)
  1.  S IBU=$G(^DGCR(399,+IBIFN,"U")),IBFROM=$P(IBU,U),IBTO=$P(IBU,U,2)  ; IB*2.0*728
  1.  ;
  1.  K ^TMP("IBRBF",$J,IBIFN) D SAVELN1^IBEFURF(IBIFN)
  1.  ;
  1. IF ; find all First Party charges for the Inpatient Event Date (Admission Date) on the Third Party bill
  1.  D FPINPT1^IBEFURF(DFN,IBFROM,IBTO,IBIFN)  ; IB*2.0*728
  1.  ;
  1.  ; find any First Party Outpatient charges for Visit Dates within the date range of the admission (PTF)
  1.  S IBPTF=$P(IB0,U,8) I +IBPTF S IBADM=$$PTFADM^IBCU64(+IBPTF) I +IBADM S IBADM=$$AD^IBCU64(IBADM) D
  1.  . S IBX=$P(IBADM,U,2)\1 I 'IBX S IBX=DT
  1.  . D FPOPV^IBEFURF(DFN,+IBADM\1,IBX,IBIFN)
  1.  ;
  1. OF ; find First Party charges for the Opt Visit Dates on the Third Party Bill
  1.  S IBX=0 F  S IBX=$O(^DGCR(399,+IBIFN,"OP",IBX)) Q:'IBX  S IBOPV=+$G(^DGCR(399,+IBIFN,"OP",IBX,0)) D
  1.  . D FPOPV^IBEFURF(DFN,IBOPV,IBOPV,IBIFN)
  1.  ;
  1.  ; find any charges for inpatient admissions whose date range includes one or more of the Opt Visit Dates
  1.  S IBX=0 F  S IBX=$O(^DGCR(399,+IBIFN,"OP",IBX)) Q:'IBX  S IBOPV=+$G(^DGCR(399,+IBIFN,"OP",IBX,0)) D
  1.  . S IBADM=$$ADM^IBCU64(DFN,IBOPV) I 'IBADM Q
  1.  . D FPINPT^IBEFURF(DFN,+IBADM,IBIFN)
  1.  ;
  1. RF ; find First Party charges for any Rx's on the selected Third Party bill
  1.  ; based on Rx IFN (52), fill date and fill# (362.4,.05,.03,.1)
  1.  N IBRXFL
  1.  S IBXRF="AIFN"_IBIFN,IBRXN="" F  S IBRXN=$O(^IBA(362.4,IBXRF,IBRXN))  Q:'IBRXN  D
  1.  . S IBX=0 F  S IBX=$O(^IBA(362.4,IBXRF,IBRXN,IBX)) Q:'IBX  D
  1.  .. S IBY=$G(^IBA(362.4,IBX,0)),IBRXIFN=$P(IBY,U,5),IBRXDT=$P(IBY,U,3),IBRXFL=$P(IBY,U,10) Q:'IBRXIFN
  1.  .. D FPRX^IBEFURF(IBRXIFN,IBRXDT,IBIFN,IBRXFL)
  1.  ;
  1.  ; find First Party Charges for any RX filled on one of the Third Party bill's Opt Visit Dates
  1.  ; that is not billed on any Third Party bill
  1.  S IBFROM=$G(^DGCR(399,IBIFN,"U")),IBTO=$P(IBFROM,U,2),IBFROM=+IBFROM K IBX
  1.  D RXDISP^IBCSC5C(DFN,IBFROM,IBTO,.IBX,"","",1,1) ; get all Rx's for patient in date range
  1.  S IBRXN="" F  S IBRXN=$O(IBX(IBRXN)) Q:IBRXN=""  S IBRXDT=0 F  S IBRXDT=$O(IBX(IBRXN,IBRXDT)) Q:'IBRXDT  D
  1.  . I '$D(^DGCR(399,"AOPV",DFN,IBRXDT,IBIFN)) Q  ; rx not on bills opt visit date
  1.  . I +$$RXTP^IBEFURT(DFN,IBRXN,IBRXDT) Q  ; rx billed on a third party bill
  1.  . S IBRXIFN=$P(IBX(IBRXN,IBRXDT),U,1)
  1.  . D FPRX^IBEFURF(IBRXIFN,IBRXDT,IBIFN)
  1.  Q