Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: IBJDB11

IBJDB11.m

Go to the documentation of this file. 
  1. IBJDB11 ;ALB/CPM - BILLING LAG TIME REPORT (COMPILE) ; 27-DEC-96
  1.  ;;2.0;INTEGRATED BILLING;**69,100,118,165**;21-MAR-94
  1.  ;
  1. EN ; - Entry point from IBJDB1.
  1.  ;
  1.  ; - 
  1.  I IBRPT="D" F X=2,3,4,6,7,8 S:IBSEL[X IBSEL=IBSEL_X_"I,"
  1.  I 'IBSORT D INIT(0) G REV
  1.  S X=0 F  S X=$S('VAUTD:$O(VAUTD(X)),1:$O(^DG(40.8,X))) Q:'X  D INIT(X)
  1.  ;
  1. REV ; - Review all claims in file #399.
  1.  S IBN=0 F  S IBN=$O(^DGCR(399,IBN)) Q:'IBN  S IBN0=$G(^(IBN,0)) D  Q:IBQ
  1.  .I IBN#100=0 S IBQ=$$STOP^IBOUTL("Billing Lag Time Report") Q:IBQ
  1.  .;
  1.  .I $P($G(^PRCA(430,IBN,0)),U,2)'=9 Q  ;              Not an RI claim.
  1.  .I $P(IBN0,U,13)<3 Q  ;                              Not authorized.
  1.  .I $P(IBN0,U,13)=7 Q  ;                              Cancelled in IB.
  1.  .S X=$P($G(^PRCA(430,IBN,0)),U,8) I X=26!(X=39) Q  ; Cancelled in AR.
  1.  .;
  1.  .; - Does claim meet report criteria?
  1.  .S IBAUTH=$$AUTH(IBN) I 'IBAUTH Q
  1.  .;
  1.  .; - Get division, if necessary.
  1.  .I 'IBSORT S IBDIV=0
  1.  .E  S IBDIV=$$DIV^IBJDF2(IBN) I 'IBDIV S IBDIV=+$$PRIM^VASITE()
  1.  .I IBSORT,'VAUTD,'$D(VAUTD(IBDIV)) Q  ;  Not a selected division.
  1.  .;
  1.  .S IBTY=$S($P(IBN0,U,5)<3:"IN",1:"OP") ; Inpatient or outpatient claim?
  1.  .;
  1.  .;- Get date PTF transmitted.
  1.  .S IBPTF="" I IBTY="IN" S IBPTF=$$PTF($P(IBN0,U,8)) Q:'IBPTF
  1.  .;
  1.  .; - Get other claim info and build date line.
  1.  .S IBDAT=$P(IBAUTH,U,2,5),DFN=+$P(IBN0,U,2),IBDFN=$G(^DPT(DFN,0))
  1.  .S IBPOL=+$G(^DPT(DFN,.312,+$P($G(^DGCR(399,IBN,"MP")),U,2),1))
  1.  .;
  1.  .; - Get care dates; quit if there are none.
  1.  .K IBDR S IBNU=$G(^DGCR(399,IBN,"U")) D
  1.  ..I IBTY="IN" S X=+$P(IBNU,U,2) S:'X X=+IBNU S:X IBDR(X)="" Q
  1.  ..I '$D(^DGCR(399,IBN,"OP")) D  Q
  1.  ...S X=+$P(IBNU,U,2) S:X IBDR(X)="" S:+IBNU&(+IBNU'=X) IBDR(+IBNU)=""
  1.  ..S X=0 F  S X=$O(^DGCR(399,IBN,"OP",X)) Q:'X  S IBDR(X)=""
  1.  .I '$D(IBDR) Q
  1.  .;
  1.  .; - Calculate statistics for each care date.
  1.  .S IBX=0 F  S IBX=$O(IBDR(IBX)) Q:'IBX  D
  1.  ..;
  1.  ..; - Get discharge date.
  1.  ..I IBTY="IN" D
  1.  ...S IBX1=+$G(^DGPT(+$P(IBN0,U,8),70))\1 I IBX1 Q
  1.  ...S IBX1=+$O(^DGPM("APTT3",DFN,(IBX-.0001)))\1 I 'IBX1 S IBX1=IBX
  1.  ..;
  1.  ..; - Get most recent check out date that has not been marked as non
  1.  ..;   billable by Claims Tracking; quit if there isn't one.
  1.  ..I IBTY="OP" D  K IBCL,IBCL1 Q:'IBCHK
  1.  ...D CL(IBN) ;GET LIST OF CLINICS FOR THIS BILL
  1.  ...S IBCHK=0,IBX1=IBX-.0001
  1.  ...F  S IBX1=$O(^SCE("ADFN",DFN,IBX1)) Q:'IBX1!((IBX1\1)>IBX)  D
  1.  ....S IBX2=0 F  S IBX2=$O(^SCE("ADFN",DFN,IBX1,IBX2)) Q:'IBX2  D
  1.  .....;
  1.  .....;CHECK TO SEE IF CLINICS MATCH
  1.  .....S IBCL1=+$P($G(^SCE(IBX2,0)),U,4) Q:'$D(IBCL(IBCL1))
  1.  .....I $P($G(^IBT(356,+$O(^IBT(356,"ASCE",IBX2,0)),0)),U,19) Q
  1.  .....S IBX3=$P($G(^SCE(IBX2,0)),U,7)\1 I IBX3,IBX3'>$P(IBAUTH,U,2)  D
  1.  ...... S:IBX3>IBCHK IBCHK=IBX3 Q
  1.  ..;
  1.  ..S X=$S(IBTY="IN":IBX1_U_+IBPTF,1:IBX_U_IBCHK)_U_IBDAT
  1.  ..S IBPOL1=$S(IBPOL>+X:1,1:0) ; Policy found after treatment.
  1.  ..;
  1.  ..; - Check date line for at least one date within the user specified
  1.  ..;   range; quit if there isn't any.
  1.  ..S IBDCHK=0 F Y=2:1:6 I $$DL(0,$P(X,U,Y)) S IBDCHK=1 Q
  1.  ..I 'IBDCHK Q
  1.  ..;
  1.  ..K D,Y,Z S IBSEL1=""
  1.  ..F Y=1:1:5 S Z(1)=$P(X,U,Y),Z(2)=$P(X,U,Y+1) D
  1.  ...;
  1.  ...; - Check out date/PTF transmission date.
  1.  ...I Y=1 D:Z(2)  Q
  1.  ....S D(0)=$$FMDIFF^XLFDT(Z(2),Z(1)),Z=$S(IBTY="IN":5,1:1)
  1.  ....I $$DL(Z,Z(2)) S IBSEL1=IBSEL1_Z_",",Y(Z)=$S(IBRPT="D":Z(1)_U_Z(2)_U_D(0),1:D(0))
  1.  ...;
  1.  ...; - Date authorized.
  1.  ...I Y=2 D:Z(1)  Q
  1.  ....S D(1)=$$FMDIFF^XLFDT(Z(2),Z(1)),Z=$S(IBTY="IN":6,1:2)
  1.  ....I $$DL(Z,Z(2)) D
  1.  .....S Z1=$S(IBPOL1:Z_"I",1:Z),IBSEL1=IBSEL1_Z1_",",Y(Z1)=$S(IBRPT="D":Z(1)_U_Z(2)_U_D(1),1:D(1))
  1.  .....I Z1=Z D
  1.  ......S Z2=Z_"I",IBSEL1=IBSEL1_Z2_",",Y(Z2)=$S(IBRPT="D":Z(1)_U_Z(2)_U_D(1),1:D(1))
  1.  ...;
  1.  ...; - Date activated.
  1.  ...I Y=3 D:Z(2)  Q
  1.  ....S D(2)=$$FMDIFF^XLFDT(Z(2),Z(1)) I $$DL(9,Z(2)) S IBSEL1=IBSEL1_"9,",Y(9)=$S(IBRPT="D":Z(1)_U_Z(2)_U_D(2),1:D(2))
  1.  ...;
  1.  ...; - Payment date.
  1.  ...I Y=4 D:Z(2)  Q
  1.  ....S D(3)=$$FMDIFF^XLFDT(Z(2),Z(1)),D(6)=$$FMDIFF^XLFDT(Z(2),+X)
  1.  ....F Z=$S(IBTY="IN":7,1:3),10 I $$DL(Z,Z(2)) D
  1.  .....S Z1=$S(IBPOL1&(Z<10):Z_"I",1:Z),Z2=$S(Z<10:6,1:3)
  1.  .....S IBSEL1=IBSEL1_Z1_",",Y(Z1)=$S(IBRPT="D":$S(Z2=3:Z(1),1:+X)_U_Z(2)_U_D(Z2),1:D(Z2))
  1.  .....I Z1=Z,Z<10 S Z3=Z_"I",IBSEL1=IBSEL1_Z3_",",Y(Z3)=$S(IBRPT="D":$S(Z2=3:Z(1),1:+X)_U_Z(2)_U_D(Z2),1:D(Z2))
  1.  ...;
  1.  ...; - Date closed.
  1.  ...I Z(2) D
  1.  ....S D(4)=$$FMDIFF^XLFDT(Z(2),Z(1)),D(5)=$$FMDIFF^XLFDT(Z(2),+X)
  1.  ....F Z=$S(IBTY="IN":8,1:4),11 I $$DL(Z,Z(2)) D
  1.  .....S Z1=$S(IBPOL1&(Z<11):Z_"I",1:Z),Z2=$S(Z<11:5,1:4)
  1.  .....S IBSEL1=IBSEL1_Z1_",",Y(Z1)=$S(IBRPT="D":$S(Z2=4:Z(1),1:+X)_U_Z(2)_U_D(Z2),1:D(Z2))
  1.  .....I Z1=Z,Z<11 S Z3=Z_"I",IBSEL1=IBSEL1_Z3_",",Y(Z3)=$S(IBRPT="D":$S(Z2=4:Z(1),1:+X)_U_Z(2)_U_D(Z2),1:D(Z2))
  1.  ..;
  1.  ..; - Save data for detail or summary report(s).
  1.  ..F Y=1:1 S Z=$P(IBSEL1,",",Y) Q:'Z  D
  1.  ...I IBRPT="D" D
  1.  ....S IBBN=$P(IBN0,U) S:IBPOL1 IBBN=IBBN_"*"
  1.  ....S Y(Z)=IBBN_U_Y(Z),Y1(Z)=$G(Y1(Z))+1
  1.  ....S ^TMP("IBJDB1",$J,IBDIV,IBTY,Z,$P(IBDFN,U)_"@@"_$P(IBDFN,U,9),Y1(Z))=Y(Z)
  1.  ...E  S IBCT(IBDIV,IBTY,Z)=IBCT(IBDIV,IBTY,Z)+1,IBTL(IBDIV,IBTY,Z)=IBTL(IBDIV,IBTY,Z)+Y(Z)
  1.  ;
  1.  Q
  1.  ;
  1. INIT(X) ; - Initialize summary accumulators/detail division nodes.
  1.  I IBRPT="D" S ^TMP("IBJDB1",$J,X)="" Q
  1.  F Y=1:1:4,9,10,11,"2I","3I","4I" S (IBCT(X,"OP",Y),IBTL(X,"OP",Y))=0
  1.  F Y=5:1:11,"6I","7I","8I" S (IBCT(X,"IN",Y),IBTL(X,"IN",Y))=0
  1.  Q
  1.  ;
  1. AUTH(IBN) ; - Is this an authorized claim?
  1.  ;  Input: IBN=Pointer to the AR in file #430
  1.  ; Output: VAL=1^2^3^4^5, where:
  1.  ;             1=1-Authorized claim
  1.  ;               0-Not an authorized claim
  1.  ;             2=Date AR was authorized
  1.  ;             3=Date AR was activated
  1.  ;             4=AR first payment date
  1.  ;             5=Date AR was closed
  1.  ;
  1.  N IBPAY,IBT,IBT0,IBT1,VAL,X
  1.  S VAL=0 I '$G(IBN) G AUTHQ
  1.  ;
  1.  ; - Get date authorized (required).
  1.  S X=$P($G(^DGCR(399,IBN,"S")),U,10) G:'X AUTHQ S VAL="1^"_X
  1.  ;
  1.  ; - Get date activated, if available.
  1.  S X=$P($G(^PRCA(430,IBN,6)),U,21) I X S $P(VAL,U,3)=X\1 G FP
  1.  S X=$P($G(^PRCA(430,IBN,9)),U,3) I X S $P(VAL,U,3)=X\1 G FP
  1.  S X=$P($G(^PRCA(430,IBN,0)),U,10) I X S $P(VAL,U,3)=X\1
  1.  ;
  1. FP ; - Get first payment date, if available.
  1.  I '$P($G(^PRCA(430,IBN,7)),U,7) G DC ; No payments made.
  1.  S (IBPAY,IBT)=0 F  S IBT=$O(^PRCA(433,"C",IBN,IBT)) Q:'IBT  D  Q:IBPAY
  1.  .S IBT0=$G(^PRCA(433,IBT,0)),IBT1=$G(^(1))
  1.  .I $P(IBT0,U,4)'=2 Q  ;                  Not complete.
  1.  .I $P(IBT1,U,2)'=2,$P(IBT1,U,2)'=34 Q  ; Not a payment.
  1.  .S X=$S(+IBT1:+IBT1,1:$P(IBT1,U,9)\1),$P(VAL,U,4)=X,IBPAY=1
  1.  ;
  1. DC ; - Get date AR closed.
  1.  S X=$$CLO^PRCAFN(IBN) I X>0 S $P(VAL,U,5)=X
  1.  ;
  1.  ; - Is there a payment date AND a closed date for this claim?
  1.  I '$P(VAL,U,4),$P(VAL,U,5) S $P(VAL,U)=0
  1.  ;
  1. AUTHQ Q VAL
  1.  ;
  1. DL(X,X1) ; - Is line item date valid for report?
  1.  ;  Input: X=Line item number (or 0), X1=Line item date
  1.  ; Output: 1=valid, 0=invalid 
  1.  ; *Requires pre-defined variables IBBDT, IBEDT, and IBSEL
  1.  S X2=0 I 'X1 G DLQ
  1.  I 'X S:X1'<IBBDT&(X1'>IBEDT) X2=1 G DLQ
  1.  I IBSEL[(","_X_","),X1'<IBBDT,X1'>IBEDT S X2=1
  1. DLQ Q X2
  1.  ;
  1.  ;
  1. PTF(X) ; - Get most recent PTF transmission date.
  1.  ;    Input: X=IEN of PTF file entry.
  1.  ;   Output: Y=PTF date.
  1.  N I,K,Y
  1.  S Y=0 G:'$O(^DGP(45.83,"C",+X,0)) PTFQ
  1.  S I=0 F  S I=$O(^DGP(45.83,"C",X,I)) Q:'I  D
  1.  .S J=$P($G(^DGP(45.83,I,0)),U,2)\1  Q:J>$P(IBAUTH,U,2)  S:J K(J)=""
  1.  S I=0 F  S I=$O(K(I)) Q:'I  S Y=I
  1.  ;
  1. PTFQ Q Y
  1.  ;
  1. CL(IBN) ; - Get the clinics for bill.
  1.  N I,J K IBCL ; IBCL=Bill clinic array.
  1.  S I=0 F  S I=$O(^DGCR(399,IBN,"CP",I)) Q:I=""  D
  1.  .S J=$P($G(^DGCR(399,IBN,"CP",I,0)),U,7) S:J IBCL(J)=""
  1.  Q