Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: IBJTBA

IBJTBA.m

Go to the documentation of this file. 
  1. IBJTBA ;ALB/ARH - TPI BILL CHARGE INFO SCREEN ;01-MAR-1995
  1.  ;;2.0;INTEGRATED BILLING;**39,80,51,137,135,309,349,389,592**;21-MAR-94;Build 58
  1.  ;;Per VA Directive 6402, this routine should not be modified.
  1.  ;
  1. EN ; -- main entry point for IBJ TP BILL CHARGES
  1.  D EN^VALM("IBJT BILL CHARGES")
  1.  Q
  1.  ;
  1. HDR ; -- header code
  1.  D HDR^IBJTU1(+IBIFN,+DFN,12)
  1.  Q
  1.  ;
  1. INIT ; -- init variables and list array
  1.  N IBOK,IBEOBDET
  1.  K ^TMP("IBJTBA",$J) N IBFT
  1.  I '$G(DFN)!'$G(IBIFN) S VALMQUIT="" G INITQ
  1.  S IBFT=+$P($G(^DGCR(399,+IBIFN,0)),U,19),IBOK=1
  1.  I $D(^IBM(361.1,"B",IBIFN))!$D(^IBM(361.1,"C",IBIFN)) D  G:'IBOK INITQ
  1.  . S DIR("A")="DO YOU WANT ALL EEOB DETAILS?: ",DIR("B")="NO",DIR(0)="YA"
  1.  . D FULL^VALM1 W ! D ^DIR K DIR
  1.  . I $D(DTOUT)!$D(DUOUT) S IBOK=0 Q
  1.  . S IBEOBDET=+Y
  1.  D BLD
  1. INITQ Q
  1.  ;
  1. MRA ; -- mra/eob
  1.  N IBI,Z,IBSTR,IBSHEOB,IBCT
  1.  S IBCT=0
  1.  S IBI=0 F  S IBI=$O(^IBM(361.1,"B",IBIFN,IBI)) Q:'IBI  S Z=+$O(^IBM(361.1,IBI,8,0)) I '$O(^(Z)) S IBCT=IBCT+1,IBSHEOB(IBI)=0  ; Entire EOB belongs to the bill
  1.  S IBI=0 F  S IBI=$O(^IBM(361.1,"C",IBIFN,IBI)) Q:'IBI  S IBCT=IBCT+1,IBSHEOB(IBI)=1 ; EOB has been reapportioned at the site
  1.  I 'IBCT D
  1.  . S IBSTR=$$SETLN("No EEOB/MRA Information","",1,79)
  1.  . S IBLN=$$SET(IBSTR,IBLN)
  1.  I IBCT D
  1.  . S Z=0
  1.  . S IBI=0 F  S IBI=$O(IBSHEOB(IBI)) Q:'IBI  S Z=Z+1 D SHEOB^IBJTBA1(IBI,+IBSHEOB(IBI),Z,IBCT)
  1.  ;
  1.  Q
  1.  ;
  1. HELP ; -- help code
  1.  S X="?" D DISP^XQORM1 W !!
  1.  Q
  1.  ;
  1. EXIT ; -- exit code
  1.  K ^TMP("IBJTBA",$J)
  1.  D CLEAR^VALM1
  1.  Q
  1.  ;
  1. BLD ; charges, as they would display on the bill
  1.  N IBXDATA,IBXSAVE
  1.  ;JWS:IB*2.0*592:Dental form#7 as professional
  1.  ;IA# 3820
  1.  I $P($G(^DGCR(399,+IBIFN,0)),U,19)=2!($P($G(^(0)),U,19)=7) D H1500 Q
  1.  D UB04
  1.  K ^TMP("IBXSAVE",$J)
  1.  Q
  1.  ;
  1. H1500 ; block 24
  1.  N X,IBI,IBJ,IBLN,IBX,IBSTR,IBLKLN,IBPFORM,IBLIN
  1.  K ^TMP("IBXSAVE",$J)
  1.  S IBLIN=$$BOX24D^IBCEF11("",1),IBLKLN=0,IBLN=1
  1.  Q:'$G(IBIFN)  K ^TMP("IBXDISP",$J)
  1.  S IBPFORM=$S($P($G(^IBE(353,2,2)),U,8):$P(^(2),U,8),1:2),IBLN=1
  1.  S IBX=$$BILLN^IBCEFG0(1,"1^99",IBLIN,+IBIFN,IBPFORM)
  1.  S IBI=$O(^TMP("IBXDISP",$J,""),-1)
  1.  S IBJ="" F  S IBJ=$O(^TMP("IBXDISP",$J,IBI,IBJ),-1) Q:$S('IBJ:1,1:$TR($G(^(IBJ))," ")'="")  K ^TMP("IBXDISP",$J,IBI,IBJ)
  1.  I '$O(^TMP("IBXDISP",$J,IBI,0)) S VALMSG="No charges or procedures defined.",VALMQUIT="" G H1500Q
  1.  S IBI="" F  S IBI=$O(^TMP("IBXDISP",$J,IBI)) Q:'IBI  S IBJ=0 F  S IBJ=$O(^TMP("IBXDISP",$J,IBI,IBJ)) Q:'IBJ  D
  1.  . S IBX=$G(^TMP("IBXDISP",$J,IBI,IBJ)),IBLN=$$SET(IBX,IBLN)
  1.  K ^TMP("IBXDISP",$J)
  1.  D COB,MRA
  1.  I $$ISRX^IBCEF1(IBIFN) D RX
  1.  I $$ISPROS^IBCEF1(IBIFN) D PROS
  1.  S VALMCNT=IBLN-1
  1. H1500Q Q
  1.  ;
  1. UB04 ;form locator 42-49,   IBIFN required
  1.  N X,Y,DIR,IBI,IBJ,IBX,IBLN,IBLC,IBLIN,IBPFORM,IBSTATE,IBCBILL,IBINPAT,IBQ,Z,Z0
  1.  K ^TMP("IBXSAVE",$J)
  1.  S IBLIN=$$RCBOX^IBCEF11()
  1.  S IBQ=0,IBLC=9 Q:'$G(IBIFN)  K ^TMP("IBXDISP",$J)
  1.  S IBPFORM=$S($P($G(^IBE(353,3,2)),U,8):$P(^(2),U,8),1:3)
  1.  S IBX=$$BILLN^IBCEFG0(1,"1^99",IBLIN,+IBIFN,IBPFORM)
  1.  I '$O(^TMP("IBXDISP",$J,0)) S VALMSG="No charges defined.",VALMQUIT="" G UB04Q
  1.  S Z="" F  S Z=$O(^TMP("IBXDISP",$J,1,Z),-1) Q:Z=""  S Z0=$G(^(Z)) Q:$TR(Z0," ")'=""  K ^(Z)
  1.  S:Z ^TMP("IBXDISP",$J,1,Z+1)=" "
  1.  S IBINPAT=$$INPAT^IBCEF(IBIFN,1)
  1.  S IBSTATE=$G(^DGCR(399,IBIFN,"U")),IBCBILL=$G(^DGCR(399,IBIFN,0))
  1.  ;
  1.  S (VALMCNT,IBLN)=1,IBLKLN=0
  1.  I +IBINPAT D  S IBLN=$$SET(IBSTR,IBLN)
  1.  . S IBX=$P(IBSTATE,U,15),IBSTR=+IBX_" DAY"_$S(IBX'=1:"S",1:"")_" INPATIENT CARE"
  1.  . S IBX=$$LOS^IBCU64(+IBSTATE,+$P(IBSTATE,U,2),+$P(IBCBILL,U,6)),IBX=IBX-$$LOS1^IBCU64(IBIFN) I IBX>0 S IBSTR=IBSTR_$J("Pass Days: "_IBX,55)
  1.  ;
  1.  S IBI="" F  S IBI=$O(^TMP("IBXDISP",$J,IBI)) Q:'IBI  S IBJ=0 F  S IBJ=$O(^TMP("IBXDISP",$J,IBI,IBJ)) Q:'IBJ  D
  1.  . S IBX=$G(^TMP("IBXDISP",$J,IBI,IBJ)),IBLN=$$SET(IBX,IBLN)
  1.  . I $E(IBX,1,3)="001" D COB
  1.  ;
  1.  K ^TMP("IBXDISP",$J)
  1.  ;
  1.  D MRA
  1.  S VALMCNT=IBLN-1
  1. UB04Q Q
  1.  ;
  1. SETLN(STR,IBX,COL,WD) ;
  1.  S IBX=$$SETSTR^VALM1(STR,IBX,COL,WD)
  1.  Q IBX
  1.  ;
  1. SET(STR,LN) ; set up TMP array with screen data (allows 2 blank lines, if not at end of array)
  1.  N IBX,IBI I STR?80" " S IBLKLN=IBLKLN+1 G SETQ
  1.  F IBI=1:1:IBLKLN D SET^VALM10(LN," ") S LN=LN+1 Q:IBI>1
  1.  D SET^VALM10(LN,STR)
  1.  S LN=LN+1,IBLKLN=0
  1. SETQ Q LN
  1.  ;
  1. COB ; if there is an offset or a secondary/tertiary payer add it to the display, with ins co, and prior bill #
  1.  ; IBIFN and IBLN must exist upon entry, IBLN is updated with new line count
  1.  N IBM,IBM1,IBI,IBJ,IBD,IBSTR,IBCU2,IBCU1 Q:'$G(IBIFN)
  1.  S IBM=$G(^DGCR(399,IBIFN,"M")),IBM1=$G(^DGCR(399,IBIFN,"M1"))
  1.  S IBCU2=$G(^DGCR(399,IBIFN,"U2")),IBCU1=$G(^DGCR(399,IBIFN,"U1"))
  1.  S IBJ=$P($G(^DGCR(399,IBIFN,0)),U,21),IBJ=$S(IBJ="P":3,IBJ="S":3,IBJ="T":3,1:0),IBSTR=""
  1.  I +$P(IBM,U,2)!(+$P(IBM,U,3)) F IBI=1:1:IBJ I +$P(IBM,U,IBI) D  S IBLN=$$SET(IBSTR,IBLN)
  1.  . I IBSTR="" S IBLN=$$SET("",IBLN)
  1.  . S IBD=$S(IBI=1:"Primary",IBI=2:"Secondary",1:"Tertiary")_": " S IBSTR=$$SETLN(IBD,"",5,11)
  1.  . S IBD=$P($G(^DIC(36,+$P(IBM,U,IBI),0)),U,1) S IBSTR=$$SETLN(IBD,IBSTR,17,25)
  1.  . I $P(IBCU2,U,(IBI+3))'="" S IBD=$J(+$P(IBCU2,U,(IBI+3)),9,2) S IBSTR=$$SETLN(IBD,IBSTR,44,11)
  1.  . I $P(IBM1,U,(IBI+4))'="" S IBD=$$BN1^PRCAFN(+$P(IBM1,U,(IBI+4))) S IBSTR=$$SETLN(IBD,IBSTR,60,11)
  1.  I +$P(IBCU1,U,2) D  S IBLN=$$SET(IBSTR,IBLN)
  1.  . I IBSTR="" S IBLN=$$SET("",IBLN)
  1.  . S IBD="Offset: " S IBSTR=$$SETLN(IBD,"",5,11)
  1.  . S IBD=$P(IBCU1,U,3) S IBSTR=$$SETLN(IBD,IBSTR,17,25)
  1.  . S IBD=$J($P(IBCU1,U,2),9,2) S IBSTR=$$SETLN(IBD,IBSTR,44,11)
  1.  . S IBD=$P(IBCU1,U,1)-$P(IBCU1,U,2),IBD="Billed: "_$J(IBD,0,2) S IBSTR=$$SETLN(IBD,IBSTR,60,17)
  1.  Q
  1.  ;
  1. RX ;RX refill info for CMS-1500 TPJI display
  1.  N Z,Z0,Z1,IBSPC,IBD,IBI,IBSTR,IBARRAY,IBRXX
  1.  S IBLN=IBLN+1
  1.  S IBSPC=$J("",5)
  1.  D SET^IBCSC5A(IBIFN,.IBARRAY)
  1.  I $D(IBARRAY) D
  1.  . S (Z,Z0)=0 F  S Z0=$O(IBARRAY(Z0)) Q:Z0=""  S Z1=0 F  S Z1=$O(IBARRAY(Z0,Z1)) Q:'Z1  S Z=Z+1 S IBXDATA(Z)=$$DAT1^IBOUTL(Z1)_U_$G(IBARRAY(Z0,Z1))
  1.  S IBD=$$SET("",IBLN)
  1.  S IBD="PRESCRIPTION REFILLS: (For TPJI display only)"
  1.  S IBSTR=$$SETLN(IBD,"",1,79),IBLN=$$SET(IBSTR,IBLN)
  1.  S IBI=0 F  S IBI=$O(IBXDATA(IBI)) Q:IBI=""  D
  1.  . S IBRXX=$G(IBXDATA(IBI))
  1.  . D ZERO^IBRXUTL($P(IBRXX,U,3))
  1.  . S IBD=$J($P(IBRXX,U,7),9,2)_IBSPC_$P(IBRXX,U)_IBSPC_$G(^TMP($J,"IBDRUG",+$P(IBRXX,U,3),.01))
  1.  . K ^TMP($J,"IBDRUG")
  1.  . S IBSTR=$$SETLN(IBD,"",1,79),IBLN=$$SET(IBSTR,IBLN)
  1.  . S IBD="QTY: "_$P(IBRXX,U,5)_" for "_$P(IBRXX,U,4)_" days supply "_"NDC# "_$P(IBRXX,U,6)
  1.  . S IBSTR=$$SETLN(IBD,"",23,79),IBLN=$$SET(IBSTR,IBLN)
  1.  Q
  1.  ;
  1. PROS ;prosthetic info for CMS-1500 TPJI display
  1.  N Z,Z0,Z1,IBARRAY,IBSPC,IBD,IBI,IBSTR
  1.  S IBSPC=$J("",10),IBLN=IBLN+1
  1.  D SET^IBCSC5B(IBIFN,.IBARRAY)
  1.  I $D(IBARRAY) D
  1.  . S (Z,Z0)=0 F  S Z0=$O(IBARRAY(Z0)) Q:Z0=""  S Z1=0 F  S Z1=$O(IBARRAY(Z0,Z1)) Q:'Z1  S Z=Z+1,IBXDATA(Z)=$$DAT1^IBOUTL(Z0)_U_$E($$PINB^IBCSC5B(+IBARRAY(Z0,Z1)),1,39)
  1.  S IBD=$$SET("",IBLN)
  1.  S IBD="PROSTHETIC REFILLS: (For TPJI display only)"
  1.  S IBSTR=$$SETLN(IBD,"",1,79),IBLN=$$SET(IBSTR,IBLN)
  1.  S IBI=0 F  S IBI=$O(IBXDATA(IBI)) Q:IBI=""  D
  1.  . S IBD=$P(IBXDATA(IBI),U)_IBSPC_$P(IBXDATA(IBI),U,2)
  1.  . S IBSTR=$$SETLN(IBD,"",1,79),IBLN=$$SET(IBSTR,IBLN)
  1.  Q
  1.  ;