Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: IBJTED

IBJTED.m

Go to the documentation of this file.
  1. IBJTED ;ALB/CXW - TPJI EDI STATUS SCREEN ;09-APR-1999
  1. ;;2.0;INTEGRATED BILLING;**137**;21-MAR-1994
  1. ;;Per VHA Directive 10-93-142, this routine should not be modified.
  1. ;
  1. EN ; -- main entry point for IBJ TP EDI STATUS
  1. D EN^VALM("IBJT EDI STATUS")
  1. Q
  1. ;
  1. HDR ; -- header code
  1. D HDR^IBJTU1(+IBIFN,+DFN,1)
  1. Q
  1. ;
  1. INIT ; -- init variables and list array
  1. K ^TMP("IBJTED",$J)
  1. I '$G(DFN)!'$G(IBIFN) S VALMQUIT="" G INITQ
  1. D BLD
  1. INITQ Q
  1. ;
  1. HELP ; -- help code
  1. S X="?" D DISP^XQORM1 W !!
  1. Q
  1. ;
  1. EXIT ; -- exit code
  1. K ^TMP("IBJTED",$J)
  1. D CLEAR^VALM1,CLEAN^VALM10
  1. Q
  1. ;
  1. BLD ;display EDI status information
  1. N IBY,IBZ,CNT,COL,WD,IBD,IBX,IBDT,IBCNT,IBCH,IBT,IBCH6,IBMS,IBRD,IBSO,IBY,X,IBGS,IBNDT,IBCN2
  1. S (IBCNT,VALMCNT)=0
  1. ; only display the latest transmit record and status message
  1. S IBY=$O(^IBM(361,"B",IBIFN,""))
  1. S IBZ=$$LAST364^IBCEF4(IBIFN)
  1. I 'IBY,'IBZ D BLDQ Q
  1. D E364(IBZ),E361(IBY)
  1. Q
  1. ;
  1. E361(IBY) ; Bill Status Message
  1. ; IBY = ien of entry in file 361
  1. N IBZ,IBX,IBDT,IBT
  1. K ^TMP($J,"RET-MSG")
  1. S IBCH=0
  1. S IBT="EDI Bill Status Messages"
  1. D SET($J("",(80-$L(IBT))\2)_IBT)
  1. D CNTRL^VALM10(VALMCNT,((80-$L(IBT))\2)+1,$L(IBT),IORVON,IORVOFF)
  1. I IBY S IBCH=1 D ; Find all messages rec'd for the bill
  1. . N IBCH
  1. . S IBDT="",IBCNT=0
  1. . F S IBDT=+$O(^IBM(361,"ADR",IBIFN,IBDT),-1) Q:'IBDT S IBY=0 F S IBY=+$O(^IBM(361,"ADR",IBIFN,IBDT,IBY)) Q:'IBY S IBX=$G(^IBM(361,IBY,0)) I IBX'="" D
  1. .. N IBT1
  1. .. S IBCNT=IBCNT+1
  1. .. I IBCNT>1 D SET(" ")
  1. .. S IBT1="---Message "_IBCNT_"---"
  1. .. S IBT=$J("",32-($L(IBCNT)+1\2))_IBT1
  1. .. S IBD=$$SET1(IBT,"",1,80) D SET(IBD)
  1. .. D CNTRL^VALM10(VALMCNT,(33-(($L(IBCNT)+1)\2)),$L(IBT1),IOINHI,IOINORM)
  1. .. S IBT=$J("",8)_"Date Received: "_$$FMTE^XLFDT(IBDT)
  1. .. S IBD=$$SET1(IBT,"",1,49)
  1. .. S IBT="Batch #: "_$$EXPAND^IBTRE(361,.05,+$P($G(^IBA(364,+$P(IBX,U,11),0)),U,2)),IBD=$$SET1(IBT,IBD,50,27)
  1. .. D SET(IBD)
  1. .. ;S IBT="Msg Generation Source: "_$$EXPAND^IBTRE(361,.04,$P(IBX,U,4))
  1. .. ;S IBD=$$SET1(IBT,"",1,40)
  1. .. S IBT="Return Msg Id: "_$P(IBX,U,6)
  1. .. S IBD=$$SET1(IBT,"",9,40)
  1. .. S IBT="Msg Severity: "_$$EXPAND^IBTRE(361,.03,$P(IBX,U,3))
  1. .. S IBD=$$SET1(IBT,IBD,45,35) D SET(IBD)
  1. .. ;S IBT="Return Msg Id: "_$P(IBX,U,6)
  1. .. ;S IBD=$$SET1(IBT,"",9,40) D SET(IBD)
  1. .. S (IBCH,IBCN)=0
  1. .. F S IBCN=$O(^IBM(361,IBY,1,IBCN)) Q:'IBCN S IBD=$$SET1(^(IBCN,0),"",1,79),IBCH=1 D SET(IBD)
  1. .. I 'IBCH S IBD=$$SET1(" No message text found","",1,25) D SET(IBD)
  1. .. S IBT=$J("",31-($L(IBCNT)+1\2))_"---Msg "_IBCNT_" Review---"
  1. .. S IBD=$$SET1(IBT,"",1,80) D SET(IBD)
  1. .. S IBCN=0 F S IBCN=$O(^IBM(361,IBY,2,IBCN)) Q:'IBCN S IBGS=$G(^(IBCN,0)) D
  1. ... S IBT="Review Date: "_$$DAT1^IBOUTL($P(IBGS,U),1)
  1. ... S IBD=$$SET1(IBT,"",1,40)
  1. ... ;S IBT="Reviewed By: "_$P($G(^VA(200,+$P(IBGS,U,2),0)),U)
  1. ... ;S IBD=$$SET1(IBT,IBD,49,29)
  1. ... D SET(IBD)
  1. ... S IBCH=0
  1. ... S IBCN2=0 F S IBCN2=$O(^IBM(361,IBY,2,IBCN,1,IBCN2)) Q:'IBCN2 S IBD=$$SET1($S('IBCH:"Comments: ",1:"")_$G(^(IBCN2,0)),"",1,$S('IBCH:69,1:79)),IBCH=1 D SET(IBD)
  1. D NONE(IBCH)
  1. K ^TMP($J,"RET-MSG")
  1. Q
  1. ;
  1. E364(IBZ) ; EDI Transmit Bill
  1. ; IBZ = ien of entry in file 364
  1. N IBY,IBT,IBX
  1. S IBX=""
  1. I IBZ S IBX=$G(^IBA(364,IBZ,0))
  1. S IBT="Last EDI Transmission"
  1. D SET($J("",(80-$L(IBT))\2)_IBT)
  1. D CNTRL^VALM10(VALMCNT,(80-$L(IBT)\2)+1,$L(IBT),IORVON,IORVOFF)
  1. S IBT="Transmission Status: "_$$EXPAND^IBTRE(364,.03,$P(IBX,U,3))
  1. S IBD=$$SET1(IBT,"",3,79)
  1. D SET(IBD)
  1. S IBT="Status Date: "_$$FMTE^XLFDT($P(IBX,U,4))
  1. S IBD=$$SET1(IBT,"",11,38)
  1. S IBT="Batch #: "_$$EXPAND^IBTRE(364,.02,+$P(IBX,U,2))
  1. S IBD=$$SET1(IBT,IBD,50,29)
  1. D SET(IBD)
  1. I $P(IBX,U,6) D
  1. . S IBT="Resubmit Batch #: "_$$EXPAND^IBTRE(364,.06,+$P(IBX,U,6))
  1. . S IBD=$$SET1(IBT,"",6,30)
  1. . D SET(IBD)
  1. D SET("")
  1. Q
  1. ;
  1. BLDQ ;
  1. D SET(" ",0),SET("No EDI Status Messages Found For This Bill Entry.",0)
  1. Q
  1. ;
  1. NONE(IBCH) ;
  1. I 'IBCH D
  1. . S IBD=$$SET1(" None","",1,10)
  1. . D SET(IBD)
  1. Q
  1. ;
  1. SET(X,CNT) ;
  1. S VALMCNT=VALMCNT+1
  1. S ^TMP("IBJTED",$J,VALMCNT,0)=X
  1. Q:'$G(CNT)
  1. S ^TMP("IBJTED",$J,"IDX",VALMCNT,CNT)=""
  1. Q
  1. ;
  1. SET1(IBT,IBD,COL,WD) ;
  1. S IBD=$$SETSTR^VALM1(IBT,IBD,COL,WD)
  1. Q IBD
  1. ;