Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: IBNCPDPH

IBNCPDPH.m

Go to the documentation of this file.
  1. IBNCPDPH ;DALOI/SS - ECME REPORT OF ON HOLD CHARGES FOR A PATIENT ;3/6/08 16:19
  1. ;;2.0;INTEGRATED BILLING;**276,347,384**;21-MAR-94;Build 74
  1. ;;Per VHA Directive 2004-038, this routine should not be modified.
  1. Q
  1. ;
  1. ;made after IBOHPT1 to use with ECME User Screen
  1. ;see IA# with ECME
  1. ;
  1. ONHOLD(DFN) ;
  1. N IBQUIT,IBII,DIRUT,DUOUT,DTOUT,ZTIO,Y S IBQUIT=0
  1. N DPTNOFZY S DPTNOFZY=1 ;Suppress PATIENT file fuzzy lookups
  1. ;
  1. S DIR(0)="DA^::EX",DIR("A")="Start with DATE: "
  1. S DIR("?")="Enter the starting date for this report."
  1. D ^DIR K DIR G:$D(DIRUT) EXIT S IBSDT=+Y
  1. S DIR(0)="DA^"_+Y_":NOW:EX",DIR("A")=" Go to DATE: "
  1. S DIR("?")="Enter the ending date for this report."
  1. D ^DIR K DIR G:$D(DIRUT) EXIT S IBEDT=+Y
  1. ;
  1. S DIR(0)="Y",DIR("A")="Include Pharmacy Co-pay charges on this report",DIR("B")="NO"
  1. S DIR("?",1)=" Enter: 'Y' - to include Pharmacy Co-pay charges on this report"
  1. S DIR("?",2)=" 'N' - to exclude Pharmacy Co-pay charges on this report"
  1. S DIR("?")=" '^' - to select a new patient"
  1. D ^DIR K DIR G:$D(DIRUT) EXIT S IBIBRX=Y
  1. ;
  1. QUEUED ; entry point if queued
  1. ;***
  1. K ^TMP($J,"IB")
  1. D:'$G(IBQUIT) DEVICE D:'$G(IBQUIT) CHRGS,REPORT^IBOHPT2
  1. D EXIT
  1. ;***
  1. Q
  1. EXIT ;
  1. K ^TMP($J,"IB")
  1. K DFN,IBEND,IBSDT,IBEDT,IBIBRX,IBCN,IBDT,IBIFN,X
  1. K IBRDT,IBRF,IBRX,IBRXN
  1. I $D(ZTQUEUED) S ZTREQ="@" Q
  1. D ^%ZISC
  1. Q
  1. DEVICE ;
  1. I $D(ZTQUEUED) Q
  1. W !!,*7,"*** Margin width of this output is 132 ***"
  1. W !,"*** This output should be queued ***"
  1. N %ZIS
  1. S %ZIS="QM" D ^%ZIS I POP S IBQUIT=1 Q
  1. N ZTRTN,ZTIO,ZTDES,ZTSAVE
  1. I $D(IO("Q")) S ZTRTN="QUEUED^IBOHPT1",ZTIO=ION,ZTDESC="ON HOLD CHARGE INFO/PT",ZTSAVE("IB*")="",ZTSAVE("DFN")="" D ^%ZTLOAD W !,$S($D(ZTSK):"REQUEST QUEUED TASK="_ZTSK,1:"REQUEST CANCELLED") D HOME^%ZIS K ZTSK S IBQUIT=1 Q
  1. U IO
  1. Q
  1. ; indexes records that should be included in report
  1. ;
  1. CHRGS ; charges on hold
  1. N DATE,IBN,IBND,A,B,C,D,E,IBNX
  1. S IBN=0 F S IBN=$O(^IB("C",DFN,IBN)) Q:'IBN S IBND=$G(^IB(IBN,0)) D:IBND
  1. .I 'IBIBRX,$E($G(^IBE(350.1,+$P(IBND,"^",3),0)),1,3)="PSO" Q
  1. .Q:$P(IBND,"^",8)["ADMISSION"
  1. .Q:'$P($G(^IB(IBN,1)),"^",6)
  1. .Q:'$D(^IB("APDT",IBN))
  1. .S (C,D)="",C=$O(^IB("APDT",IBN,C)),D=$O(^IB("APDT",IBN,C,D))
  1. .S E=$P($G(^IB(D,0)),U,3)
  1. .S A=$P($G(^IBE(350.1,E,0)),U,5)
  1. .S IBNX=$S(A=2:$P($Q(^IB("APDT",IBN,C,D)),")",1),A=3:$P($Q(^IB("APDT",IBN,C,D)),")",1),1:IBN)
  1. .I (A=2)!(A=3) D
  1. ..I IBNX["[""" S IBNX="^"_$P(IBNX,"]",2)
  1. .I $P(IBNX,",",4)>0 S IBNX=$P(IBNX,",",4)
  1. .S DATE=$P($G(^IB(+$P(IBND,"^",1),0)),"^",17)
  1. .S:'DATE DATE=$P($G(^IB(IBNX,1)),"^",5)
  1. .S:'DATE DATE=$P($G(^IB(IBNX,1)),"^",2)\1
  1. .I (DATE>(IBSDT-.0001))&(DATE<(IBEDT+.9999)) S ^TMP($J,"IB",-DATE,IBNX)="" D BILLS
  1. Q
  1. ;
  1. BILLS ; find bills for charges on hold
  1. N IBFR,IBT,IBATYPE,IBTO
  1. S IBATYPE=$S($P($G(^IBE(350.1,+$P(IBND,"^",3),0)),"^")["OPT":"O",$P($G(^IBE(350.1,+IBND,"^",3,0)),"^")["PSO":"RX",1:"I")
  1. S IBFR=$P(IBND,"^",14),IBTO=$P(IBND,"^",15)
  1. I IBATYPE="I" D INP
  1. I IBATYPE="O" D OPT
  1. E D RX
  1. Q
  1. INP ; inpatient bills
  1. N IBEV,IBBILL,IBT,X,X1,X2,IBEND,IBOK
  1. S IBEV=$P(IBND,"^",16) Q:'IBEV ; parent event
  1. S IBEV=($P($G(^IB(IBEV,0)),"^",17)\1) Q:'IBEV ; date of parent event
  1. S X1=IBEV,X2=1 D C^%DTC S IBEND=X
  1. S IBT=(IBEV-.0001) F S IBT=$O(^DGCR(399,"D",IBT)) Q:'IBT!(IBT'<IBEND) S IBBILL=0 F S IBBILL=$O(^DGCR(399,"D",IBT,IBBILL)) Q:IBBILL="" D
  1. .D INPTCK
  1. .I IBOK S ^TMP($J,"IB",-DATE,IBNX,IBBILL)=""
  1. Q
  1. ;
  1. INPTCK ; does bill belong to charge? returns IBOK=0 if no
  1. N IBBILL0,IBBILLU
  1. S IBBILL0=$G(^DGCR(399,IBBILL,0)),IBBILLU=$G(^("U"))
  1. S IBOK=1
  1. CK1 ; for same patient?
  1. I DFN=$P(IBBILL0,"^",2)
  1. S IBOK=$T
  1. Q:'IBOK
  1. CK2 ; same type- inp or opt?
  1. N B S B=$S(+$P(IBBILL0,"^",5)<3:"I",1:"O")
  1. I B=IBATYPE
  1. S IBOK=$T
  1. Q:'IBOK
  1. CK3 ; overlap in date range?
  1. N F,T
  1. S F=+IBBILLU,T=$P(IBBILLU,"^",2)
  1. I (IBTO<F)!(IBFR>T)
  1. S IBOK='$T
  1. Q:'IBOK
  1. CK4 ; insurance bill?
  1. I $P(IBBILL0,"^",11)="i"
  1. S IBOK=$T
  1. Q
  1. OPT ; outpatient bills
  1. N X,IBV,IBBILL,IBOK,IBBILL0
  1. S IBV=(IBFR\1)-.0001 F S IBV=$O(^DGCR(399,"AOPV",DFN,IBV)) Q:'IBV!(IBV>IBTO) S IBBILL=0 D
  1. .F S IBBILL=$O(^DGCR(399,"AOPV",DFN,IBV,IBBILL)) Q:('IBBILL) D
  1. ..Q:$D(^TMP($J,"IB",-DATE,IBNX,IBBILL))
  1. ..S IBBILL0=$G(^DGCR(399,IBBILL,0)) D CK4 Q:'IBOK
  1. ..S ^TMP($J,"IB",-DATE,IBNX,IBBILL)=""
  1. Q
  1. RX ; rx refill bills
  1. Q:'IBIBRX
  1. S (IBRX,IBRXN,IBRF,IBRDT)=0
  1. I $P(IBND,"^",4)'["52:" Q
  1. ;
  1. S IBRXN=$P($P(IBND,"^",4),":",2),IBRX=$P($P(IBND,"^",8),"-"),IBRF=$P($P(IBND,"^",4),":",3)
  1. ;
  1. I +IBRF>0 S IBRDT=$$SUBFILE^IBRXUTL(+IBRXN,IBRF,52,.01)
  1. I +IBRF=0 S IBRDT=$$FILE^IBRXUTL(+IBRXN,22)
  1. ;
  1. Q:(IBRX="")!('IBRDT)
  1. N X,IBBILL,IBBILL0,IBFILL,IBFILL0,IBOK S IBBILL=0
  1. S IBFILL=0 F S IBFILL=$O(^IBA(362.4,"B",IBRX,IBFILL)) Q:IBFILL="" D
  1. .S IBFILL0=$G(^IBA(362.4,IBFILL,0)) I $P(IBFILL0,"^",3)'=IBRDT Q
  1. .S IBBILL=+$P(IBFILL0,"^",2) I 'IBBILL Q
  1. .S IBBILL0=$G(^DGCR(399,IBBILL,0)) D CK4 I 'IBOK Q
  1. .S ^TMP($J,"IB",-DATE,IBNX,IBBILL)=""
  1. Q