Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: IBQLT

IBQLT.m

Go to the documentation of this file. 
  1. IBQLT ;LEB/MRY - TRANSMIT DATA ; 24-APR-95
  1.  ;;1.0;UTILIZATION MGMT ROLLUP LOCAL;**1,2**;Oct 01, 1995
  1.  ;;Per VHA Directive 10-93-142, this routine should not be modified.
  1.  ; 
  1.  I '$D(DT) D DT^DICRW
  1.  ;D PULL^IBQLPL
  1.  W !!,"Transmit Rollup Data",!
  1.  ;W !,"The next National Rollup will be " S Y=IBBDT X ^DD("DD") W Y_" to " S Y=IBEDT X ^DD("DD") W Y
  1.  ;I IBMSG'="" W !!,IBMSG,!,IBMSG1
  1.  ;
  1. DEC95 ;; -- per Directive ....
  1.  ;; -- until 1/1/96, allow sites to transmit previous rollup periods.
  1.  ;I DT<2960101,DT<2951116 D ASK^IBQLT5 G:IBQUIT END
  1.  ;I DT<2960101,DT>2951115 D ASK^IBQLT5A G:IBQUIT END
  1.  ;
  1.  ; - ask user for roll-up period to be transmitted
  1.  D RANGE^IBQLT5 G:IBQUIT END
  1.  ;
  1.  F I="IBBDT","IBEDT" S ZTSAVE(I)=""
  1.  S ZTRTN="START^IBQLT",ZTDESC="IBQ - TRANSMIT ROLLUP DATA",ZTIO=""
  1.  W ! D ^%ZTLOAD G END
  1.  ;
  1. START ;
  1.  S IBDDT=IBBDT-.01,IBCNT=0,IBREC=0
  1.  S IBCNT=1,^TMP("IBQLT",$J,IBCNT,0)="**"_"^"_IBBDT_"^"_IBEDT
  1.  F  S IBDDT=$O(^IBQ(538,"ADIS",IBDDT)) Q:'IBDDT!(IBDDT>IBEDT)  D
  1.  .S IBTRN="" F  S IBTRN=$O(^IBQ(538,"ADIS",IBDDT,IBTRN)) Q:'IBTRN  D DATA
  1.  ;
  1.  ; -- transmit data thru mailman handler
  1.  D TRANSMIT
  1.  ;
  1. END K ^TMP("IBQLT",$J),^TMP("IBQ",$J),IBDDT,IBTRN,INTRND0,IBTRND1,IBTRND2,IBREC,IBCNT,IBBDT1,IBEDT1
  1.  K IBBDT,IBEDT,IBMSG,IBMSG1,IBRDT1,IBQUIT
  1.  Q
  1.  ;
  1.  ;
  1. DATA ; -- build ^tmp($j,cnt,0) and ^tmp("ibql",$j,cnt,0) for mailman handler.
  1.  ; IBTRND0 = entry id^site^ssn^admitting diagnosis^enroll code^
  1.  ;           admitting phy^attending phy^resident phy,^admission^
  1.  ;          discharge^ward^treating specialty^acute adm?^
  1.  ; IBTRND1 = si from adm^is from adm^reasons from adm^
  1.  ;          provider interviewed?^adm influenced?^rollup type^service
  1.  ; IBTRND2 = day^is^si^d/s^interviewed?^reasons^service
  1.  ;
  1.  I '$G(^IBQ(538,IBTRN,0))!($P(^(1),"^",6)="L") Q
  1.  S IBREC=IBREC+1,IBTRND0=^IBQ(538,IBTRN,0),IBTRND1=$G(^(1))
  1.  I '$P(IBTRND0,"^",2) S $P(IBTRND0,"^",2)=$P($$SITE^VASITE,"^")
  1.  ; -- null out unwanted field entries from transmission.
  1.  ; -- admitting phy,attending phy,resident phy,ward
  1.  F I=6,7,8,11 S $P(IBTRND0,"^",I)=""
  1.  S IBCNT=IBCNT+1,^TMP("IBQLT",$J,IBCNT,0)=IBTRND0_"^"_IBTRND1
  1.  ; -- continued stay reviews
  1.  S N=0 F  S N=$O(^IBQ(538,IBTRN,13,N)) Q:'N  D
  1.  .S IBTRND2=^IBQ(538,IBTRN,13,N,0),$P(IBTRND2,"^")=$P(IBTRND0,"^")_"."_$P(IBTRND2,"^")
  1.  .S IBCNT=IBCNT+1,^TMP("IBQLT",$J,IBCNT,0)=IBTRND2
  1.  Q
  1.  ;
  1. TRANSMIT ;  
  1.  ; -- transmit data to National DataBase
  1.  S Y=IBBDT X ^DD("DD") S IBBDT1=Y S Y=IBEDT X ^DD("DD") S IBEDT1=Y
  1.  S XMY("S.IBQN SERVER@ISC-CHICAGO.DOMAIN.EXT")="",XMDUZ="UTILIZATION MANAGEMENT ROLLUP MONITOR"
  1.  S XMTEXT="^TMP(""IBQLT"",$J,",XMSUB="Rollup Extract" D ^XMD
  1.  ; -- transmit local message
  1.  S XMY("G.IBQ ROLLUP")=""
  1.  S XMSUB="Rollup Extract transmitted",XMDUZ="IBQ MONITOR"
  1.  S ^TMP("IBQ",$J,1,0)="Utilization Management Rollup was transmitted.",^TMP("IBQ",$J,2,0)=""
  1.  S ^TMP("IBQ",$J,3,0)="Site: "_$P($$SITE^VASITE,"^"),^TMP("IBQ",$J,5,0)="Number of Records sent: "_IBREC
  1.  S ^TMP("IBQ",$J,6,0)="Period: "_IBBDT1_" - "_IBEDT1
  1.  S XMTEXT="^TMP(""IBQ"",$J," D ^XMD
  1.  Q