Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: IBY547PO

IBY547PO.m

Go to the documentation of this file. 
  1. IBY547PO ;ALB/GEF - Post install routine for patch 547 ; 7-JUN-15
  1.  ;;2.0;INTEGRATED BILLING;**547**;21-MAR-94;Build 119
  1.  ;;Per VA Directive 6402, this routine should not be modified.
  1.  ;
  1.  ; XPDUTL calls are DBIA#10141
  1.  ;
  1. DOC ;
  1.  ; POINDX^IBY547PO will run post-install to set new CROSS-REFERENCES for
  1.  ; existing fields 3.02 & 3.04 in file 36.
  1.  ;  
  1.  ; NEWRCS^IBY547PO sets the new multi-field in file #350.9 with the default Revenue Code Exclusions on the
  1.  ; Printed Claims Report (FUNC REQ: 2.6.4.8, SDD REQ: 6.2.2.2.4.8)
  1.  ;
  1.  ; RFAI sets the initial values in fields 52.01 (null) & 52.02 (20 days) in file #350.9
  1.  ;
  1. EN ; start post-install activities
  1.  D POINDX
  1.  D NEWRCS
  1.  D AC
  1.  D RFAI
  1.  D RIT
  1.  Q
  1.  ;
  1. POINDX ; POST-INSTALL comes here to set new x-refs
  1.  ; run triggers on new cross-refs for fields 3.02 & 3.04 (AEI & AEP)
  1.  D MES^XPDUTL("Setting new EDI cross-references in INSURANCE COMPANY file ")
  1.  N DIK,FLD
  1.  ; file 36, top level
  1.  S DIK="^DIC(36,"
  1.  F FLD=3.02,3.04 S DIK(1)=FLD D ENALL^DIK
  1.  Q
  1.  ;
  1. NEWRCS ; POST-INSTALL comes here to set new multi=field (#15) in file #350.9 for the default
  1.  ; Revenue Code Exclusions on the Printed Claims Report.
  1.  D MES^XPDUTL("Setting Default Revenue Code Exclusions in IB SITE PARAMETER file ")
  1.  N DIE,DIC,DA,DR,IREVCD,REVCD,FDA,ERRMSG,RETIEN
  1.  F REVCD=270:1:279,290:1:299 D
  1.  . S IREVCD=$$FIND1^DIC(399.2,,"X",REVCD) Q:'IREVCD
  1.  . I $D(^IBE(350.9,1,15,"B",IREVCD)) Q
  1.  . K FDA,ERRMSG,RETIEN
  1.  . S FDA(350.9399,"+1,1,",.01)=IREVCD
  1.  . D UPDATE^DIE("","FDA","RETIEN","ERRMSG")
  1.  D MES^XPDUTL("........Default Revenue Code Exclusions set. ")
  1.  Q
  1.  ;
  1. AC ; set initial values in new multiple (#81) in file #350.9 to the default Administrative Contractors for Medicare.
  1.  D MES^XPDUTL("Setting Default Administrative Contractor in IB SITE PARAMETER file ")
  1.  N FDA,ERRMSG,RETIEN
  1.  ;
  1.  ; lookup or add to the pointed to file (adds the first time, lookups the rest)
  1.  S FDA(355.98,"?+1,",.01)="DME"
  1.  D UPDATE^DIE("E","FDA","RETIEN","ERRMSG")  ; returns RETIEN(1) with the value to add or ERRMSG if not found
  1.  ;
  1.  I $D(ERRMSG) Q  ;if you can't find the entry in the pointed to file, might as well quit
  1.  K ERRMSG,FDA
  1.  ;
  1.  ; lookup or add to the multiple.
  1.  S FDA(350.981,"?+1,1,",.01)=RETIEN(1)
  1.  K RETIEN
  1.  D UPDATE^DIE("","FDA","RETIEN","ERRMSG")
  1.  D MES^XPDUTL("........Default Administrative Contractor 'DME' set. ")
  1.  Q
  1.  ;
  1. RFAI ; set initial values in fields 52.01 & 52.02 in file #350.9
  1.  N DA,DIE,DR,IBNL
  1.  D MES^XPDUTL("Setting Default RFAI Purge Days in IB SITE PARAMETER file ")
  1.  S IBNL="",DA=1,DIE=350.9,DR="52.01///^S X=IBNL" D ^DIE K DR
  1.  D MES^XPDUTL("........Default RFAI Transaction Purge Days (#52.01) set to null for 'no purge'. ")
  1.  S DR="52.02///20" D ^DIE
  1.  D MES^XPDUTL("........Default RFAI Worklist Purge Days (#52.02) set to 20 days. ")
  1.  K DA,DIE,DR
  1.  Q
  1.  ;
  1. RIT ; recompile billing screen templates
  1.  N X,Y,DMAX,IBN
  1.  D MES^XPDUTL("Recompiling Input Templates for Billing Screens ...")
  1.  F IBN=1:1:9,"10","102","10H" D
  1.  .S X="IBXS"_$S(IBN=10:"A",IBN="102":"A2",IBN="10H":"AH",1:IBN),Y=$$FIND1^DIC(.402,,"X","IB SCREEN"_IBN,"B"),DMAX=$$ROUSIZE^DILF
  1.  .I Y D EN^DIEZ
  1.  D MES^XPDUTL(" Done.")
  1.  Q