Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: IVMBULK

IVMBULK.m

Go to the documentation of this file. 
  1. IVMBULK ;ALB/KCL - IVM/ENROLLMENT Extract ; 18-AUG-1997
  1.  ;;2.0;INCOME VERIFICATION MATCH;**9**; 21-OCT-94
  1.  ;
  1.  ; * This extract will scan the PATIENT (#2) file for patients that
  1.  ;   meet the following enrollment extract selection criteria:
  1.  ;
  1.  ;     [Patient has a current enrollment]
  1.  ;                AND
  1.  ;     [Enrollment status is 'Pending'
  1.  ;                OR
  1.  ;      Enrollment status is 'Unverified'
  1.  ;                OR
  1.  ;      Enrollment status is 'Verified']
  1.  ;
  1.  ;     OR,
  1.  ;
  1.  ;     [Patient is a Veteran]
  1.  ;                AND
  1.  ;     [Patient is a current inpatient
  1.  ;                OR
  1.  ;      Patient was an inpatient after 1/1/96
  1.  ;                OR
  1.  ;      Patient was an outpatient after 1/1/96]
  1.  ;
  1.  ;
  1.  ; * An HL7 "Full Data Transmission" message (Z07) will be built
  1.  ;   for each patient selected.  HL7 messages will be output to a
  1.  ;   selected host file.
  1.  ;
  1.  ; * A mail message will be generated upon completion of the initial
  1.  ;   data extract.  This mail message will contian the results of
  1.  ;   the extract.
  1.  ;
  1.  ; * This job will be queued.
  1.  ;
  1.  ;
  1. EN(IVMARRY1,IVMCONST) ; --
  1.  ; Description: Entry point responsible for queuing off the enrollment extract job.
  1.  ;
  1.  ;  Input: None
  1.  ;
  1.  ; Output: 
  1.  ;   IVMARRY1 - as array containing required input parameters for enrollment extract job, pass by reference
  1.  ;   IVMCONST - as array containing enrollment extract constants, pass by reference
  1.  ;
  1.  N ZTDESC,ZTIO,ZTRTN,ZTSAVE,QUIT
  1.  ;
  1.  S QUIT=0
  1.  ;
  1.  ; lock IVM Extract Mangement file, otherwise exit
  1.  I '$$LOCK^IVMBULK2(1) D  G ENQ
  1.  .W !,">>> This job has already been queued!"
  1.  ;
  1.  ; if environment check fails, exit
  1.  I '$$ENV() S QUIT=1 G ENQ
  1.  ;
  1.  ; get extract constants
  1.  I $$GETCONST^IVMBULK2(.IVMCONST)
  1.  ;
  1.  ; get IVM Extract Management record
  1.  I '$$GET^IVMBULK2(.IVMARRY1) D
  1.  .;
  1.  .; - if no IVM Extract Mgmt. record, init IVM Extract Mgmt. record
  1.  .I $$INIT^IVMBULK2(.IVMARRY1)
  1.  ;
  1.  ; don't want sites to unknowingly run extract again
  1.  I IVMARRY1("EXTRACT"),'IVMARRY1("LASTPAT") D  G:QUIT ENQ
  1.  .W !,"> > >  W A R N I N G",*7
  1.  .W !,?5,"The enrollment data extract has already run to completion!"
  1.  .W !,?5,"Do NOT run the extract again unless you have first deleted the"
  1.  .W !,?5,"host files that contain the prior extract!",!
  1.  .D INQUIRE^IVMBULK2("^IVM(301.63,",1)
  1.  .N DIR
  1.  .S DIR(0)="Y"
  1.  .S DIR("A")="Do you want to run the enrollment extract again"
  1.  .S DIR("B")="NO"
  1.  .D ^DIR
  1.  .I $D(DIRUT)!(Y'=1) D
  1.  ..S QUIT=1
  1.  .E  D
  1.  ..D CLEAR(.IVMARRY1)
  1.  ;
  1.  ; write user info
  1.  D HDR1
  1.  ;
  1.  ; calculate extract size/time estimates
  1.  S IVMARRY1("PROJECT")=""
  1.  D EST(.IVMARRY1,.IVMCONST)
  1.  ;
  1.  ; if user time-out or abort, exit
  1.  I '$$PAUSE() S QUIT=1 G ENQ
  1.  ;
  1.  ; if directory not specified, exit
  1.  I IVMARRY1("DIR")="",('$$PATH^IVMBULK2(.IVMARRY1)) S QUIT=1 G ENQ
  1.  ;
  1.  ; queue enrollment extract job
  1.  S ZTSAVE("IVMARRY1(")="",ZTSAVE("IVMCONST(")=""
  1.  S ZTDESC="Enrollment Initial Data Extract",ZTRTN="GOGO^IVMBULK1",ZTIO=""
  1.  D ^%ZTLOAD,HOME^%ZIS
  1.  I $D(ZTSK) W !,"This job has been queued.  The task number is "_ZTSK_"."
  1.  I '$D(ZTSK) W !,"Unable to queue this job." S QUIT=1
  1.  ;
  1. ENQ ;
  1.  ; if job is not queued, unlock IVM EXTRACT MANAGEMENT file
  1.  I QUIT D UNLOCK^IVMBULK2(1)
  1.  Q
  1.  ;
  1.  ;
  1. ENV() ; --
  1.  ; Description: This function performs an environment check for the enrollment initial data extract job.
  1.  ;
  1.  ;  Input: None
  1.  ;
  1.  ; Output:
  1.  ;   Function Value - Extract environment check successful?
  1.  ;                    Return 1 if successful, otherwise 0
  1.  ;
  1.  N IVMOK
  1.  S IVMOK=1
  1.  ;
  1.  I '($D(DUZ)#2) W *7,!,"You must have a valid DUZ defined before running this routine!" S IVMOK=0
  1.  ;
  1.  Q IVMOK
  1.  ;
  1.  ;
  1. PAUSE() ; --
  1.  ; Description: End-of-Page, Press return to continue or "^" to exit.
  1.  ;
  1.  ;  Input: None
  1.  ;  
  1.  ; Output: Function value - returns 1 if success, 0 otherwise
  1.  ;
  1.  N DIR,DIRUT,DUOUT,SUCCESS,Y
  1.  S SUCCESS=0
  1.  ;
  1.  S DIR(0)="E"
  1.  D ^DIR
  1.  I $D(DIRUT)!($D(DUOUT)) G PAUSEQ
  1.  ;
  1.  S SUCCESS=1
  1.  ;
  1. PAUSEQ Q SUCCESS
  1.  ;
  1.  ;
  1. EST(IVMARRY1,IVMCONST) ; --
  1.  ; Description: Calculate extract size/time estimates.
  1.  ;
  1.  ;  Input:
  1.  ;   IVMARRY1 - as array containing required input parameters for enrollment extract job, pass by reference
  1.  ;   IVMCONST - as array containing enrollment extract constants, pass by reference
  1.  ;
  1.  ; Output: None
  1.  ;
  1.  N IVMTOTAL,X,X2,X3
  1.  ;
  1.  ; total patients in PATIENT file
  1.  S IVMTOTAL=$$TOTPAT(1)
  1.  ;
  1.  ; if extract complete, exit
  1.  I IVMTOTAL'>$G(IVMARRY1("PROC")) G ESTQ
  1.  ;
  1.  ; write estimate disclaimer
  1.  D HDR2(.IVMCONST)
  1.  ;
  1.  S IVMTOTAL=IVMTOTAL-$G(IVMARRY1("PROC"))
  1.  S X=IVMTOTAL,X2=0,X3=10 D COMMA^%DTC
  1.  W !,?7,"Estimated number of patients to be processed: "_X
  1.  ;W !,?7,"Estimated time of extract: "_$$TIMEST(IVMTOTAL,IVMCONST("PERCNT"),IVMCONST("AVG100"))
  1.  S X=$$TIMEST(IVMTOTAL,IVMCONST("PERCNT"),IVMCONST("AVG100"))
  1.  W !,?7,"Estimated time of extract: "_$P(X,"^",1)_" Hours "_$P(X,"^",2)_" Minutes"
  1.  S IVMARRY1("PROJECT")=$$FMADD^XLFDT($$NOW^XLFDT,0,$P(X,"^",1),$P(X,"^",2),0)
  1.  S X=($$SIZEST(IVMTOTAL,IVMCONST("PERCNT"),IVMCONST("SIZE"))\1),X2=0,X3=20 D COMMA^%DTC
  1.  W !,?7,"Estimated amount of disk space (bytes): "_X
  1.  W !
  1. ESTQ Q
  1.  ;
  1.  ;
  1. TOTPAT(ESTIMATE) ; --
  1.  ; Description: This function counts the number of records in the PATIENT file.
  1.  ;
  1.  ;  Input:
  1.  ;    ESTIMATE - (optional) if not passed, an actual patient count will be returned as the function value.  If ESTIMATE=1, then an estimated number of patients in the Patient (#2) file will be returned as the function value.
  1.  ;
  1.  ; Output: 
  1.  ;   Function Value - If ESTIMATE=1 the actual count of records in the patient file, otherwise the estimated count of records in the patient file.
  1.  ;
  1.  N COUNT,DFN
  1.  S (COUNT,DFN)=0
  1.  ;
  1.  ; if flag, estimated count of records in Patient (#2) file (header node)
  1.  I $G(ESTIMATE) S COUNT=$P($G(^DPT(0)),"^",4)
  1.  ;
  1.  ELSE  D
  1.  .;
  1.  .; - loop through Patient (#2) file for actual count of records
  1.  .F  S DFN=$O(^DPT(DFN)) Q:'DFN  S COUNT=COUNT+1
  1.  ;
  1.  Q COUNT
  1.  ;
  1.  ;
  1. TIMEST(COUNT,PERCN,AVG100) ; --
  1.  ; Description: This function will return a time estimate as to how long the initial data extract will run.
  1.  ;
  1.  ;  Input:
  1.  ;  COUNT - number of patients in the PATIENT file
  1.  ;  PERCN - percentage of total patients that are expected to be extracted
  1.  ;  AVG100 - average time to add 100 patients to the extract in seconds
  1.  ;
  1.  ; Output:
  1.  ;  Function Value - If successful, returns the time estimate in the format HOURS^MINUTES.  If function is not successful, the function returns NULL  
  1.  ;
  1.  N SECONDS,HOURS,MINUTES
  1.  ;
  1.  I ($G(COUNT)'>0)!($G(PERCN)'>0)!($G(AVG100)'>0) Q ""
  1.  S SECONDS=(PERCN*AVG100*COUNT)/10000
  1.  S HOURS=SECONDS\3600
  1.  S SECONDS=SECONDS-(HOURS*3600)
  1.  S MINUTES=SECONDS\60
  1.  ;
  1.  Q HOURS_"^"_MINUTES
  1.  ;
  1.  ;
  1. SIZEST(COUNT,PERCN,SIZE) ;
  1.  ; Description: This function will return a size estimate for the initial data extract.
  1.  ;
  1.  ; Input:
  1.  ;   COUNT - number of patients in the PATIENT file
  1.  ;   PERCN - percentage of total patients that are expected to be extracted
  1.  ;    SIZE - average size of single patient record in the extract in BYTES
  1.  ; Output:
  1.  ;   Function Value - the estimated file size in BYTES
  1.  ;
  1.  I (COUNT'>0)!(PERCN'>0)!(SIZE'>0) Q 0
  1.  Q (PERCN*SIZE*COUNT)/100
  1.  ;
  1.  ;
  1. HDR1 ; --
  1.  ; Description: Write extract user info.
  1.  ;
  1.  ;  Input: None
  1.  ; Output: None
  1.  ;
  1.  W !!,"> > >  E N R O L L M E N T   D A T A   E X T R A C T"
  1.  W !!,?5,"This job will loop through the Patient (#2) file to find patients"
  1.  W !,?5,"that meet the enrollment extract selection criteria.",!
  1.  W !,?5,"Due to the high integration with the Patient (#2) file, please"
  1.  W !,?5,"queue this job to run at non-peak hours.",!
  1.  Q
  1.  ;
  1.  ;
  1. HDR2(IVMCONST) ; --
  1.  ; Description: Write extract estimate disclaimer
  1.  ;
  1.  ;  Input:
  1.  ;    IVMCONST() - an array containing extract constants, pass by reference
  1.  ;    IVMCONST("PERCNT") - % of patients expected to be extracted.
  1.  ;
  1.  ; Output: None
  1.  ;
  1.  W !,?15," * * * * *  P L E A S E   N O T E  * * * * *"
  1.  W !,?5,"The following time and space estimates are based on the approximate"
  1.  W !,?5,"number of patients in your database.  Of those patients, it is assumed"
  1.  W !,?5,"that approximately "_IVMCONST("PERCNT")_"% will meet the requirements to be included in"
  1.  W !,?5,"the extract.  Also, the time estimate provided does not account for"
  1.  W !,?5,"the speed of your system or the load on your system.",!
  1.  Q
  1.  ;
  1. CLEAR(IVMARRAY) ;
  1.  ;Description: If the extract must be run again (the entire extract
  1.  ;created from scratch, as opposed to restarted), the IVM EXTRACT
  1.  ;MANAGMENT record needs to be cleared.  This call will do that.
  1.  ;
  1.  ;Input: none
  1.  ;Output:
  1.  ;  IVMARRAY - optional output variable, pass by reference,
  1.  ;          IVMARRAY() contains the IVM EXTRACT MANAGMENT record after
  1.  ;          being initialized.
  1.  ;
  1.  N IVMCONST
  1.  ;
  1.  I $$GETCONST^IVMBULK2(.IVMCONST),$$INIT^IVMBULK2(.IVMARRAY) D
  1.  .S IVMARRAY("HOST")=IVMCONST("HOST")
  1.  .I $$STORE^IVMBULK2(.IVMARRAY)
  1.  Q