Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: IVMCMD1

IVMCMD1.m

Go to the documentation of this file. 
  1. IVMCMD1 ;ALB/SEK,KCL - DELETE DCD INCOME TESTS CON'T ; 29-MAY-97
  1.  ;;2.0;INCOME VERIFICATION MATCH;**17**;21-OCT-94
  1.  ;
  1.  ;
  1.  ;
  1. EN ;This entry point is called from the routine (IVMCMD) and
  1.  ;contains calls that are responsible for completing the
  1.  ;deletion of an income test.
  1.  ;
  1.  ; Delete record from Annual Means Test (#408.31) file
  1.  D DEL31(IVMMTIEN)
  1.  S IVMDONE=1
  1.  ;
  1.  ; Open case record in the IVM Patient (#301.5) file
  1.  D OPEN(DFN,IVMDOT)
  1.  ;
  1.  ; Send 'delete' bulletin/notification to local mail group
  1.  D BULL
  1.  ;
  1.  ; Call means test event driver
  1.  D EVNT
  1.  ;
  1.  ; Call DGMTR if deleted means test
  1.  D:IVMTOT=1 EN^DGMTR
  1.  ;
  1.  ; Cleanup variables
  1.  D CLEAN
  1.  ;
  1. ENQ Q
  1.  ;
  1.  ;
  1. DEL31(IVMDIEN) ; Delete record from Annual Means Test (#408.31) file.
  1.  ;
  1.  ;  Input(s): 
  1.  ;    IVMDIEN - as IEN of the Annual Means Test (#408.31) file
  1.  ;
  1.  ; Output(s): None
  1.  ;
  1.  N DA,DIK
  1.  S DA=IVMDIEN,DIK="^DGMT(408.31,"
  1.  D ^DIK
  1.  Q
  1.  ;
  1.  ;
  1. OPEN(IVMDFN,IVMOPNDT) ; Open IVM Patient (#301.5) file case record
  1.  ;
  1.  ; Input(s):
  1.  ;     IVMDFN - as pointer to patient in Patient (#2) file
  1.  ;   IVMOPNDT - as date of income test
  1.  ;
  1.  ; Output(s): None
  1.  ;
  1.  N DA,DR,DIE
  1.  S DA=$O(^IVM(301.5,"APT",+IVMDFN,+$$LYR^DGMTSCU1(IVMOPNDT),0))
  1.  I $G(^IVM(301.5,+DA,0))']"" G OPENQ
  1.  S DR=".04////0",DIE="^IVM(301.5,"
  1.  D ^DIE
  1.  K ^IVM(301.5,+DA,1)
  1. OPENQ Q
  1.  ;
  1.  ;
  1. BULL ; Build/Transmit mail msg to IVM mail group notifying
  1.  ; local site that a Means Test or Copay Test was deleted.
  1.  ;
  1.  ;  Input(s):
  1.  ;        DFN - as pointer to patient in Patient (#2) file
  1.  ;     IVMDOT - as date of test
  1.  ;     IVMTOT - as type of test
  1.  ;
  1.  ; Output(s): None
  1.  ;
  1.  S IVMPAT=$$PT^IVMUFNC4(DFN)
  1.  S XMSUB="DCD - Income Test Deletion for "_$P($P(IVMPAT,"^"),",")_" ("_$P(IVMPAT,"^",3)_")"
  1.  S IVMTEXT(1)="A deletion request has been received from the Health Eligibility Center."
  1.  S IVMTEXT(2)="A "_$P($G(^DG(408.33,+IVMTOT,0)),"^")_" was transmitted in error and has now"
  1.  S IVMTEXT(3)="been deleted for the following patient:"
  1.  S IVMTEXT(4)=" "
  1.  S IVMTEXT(5)="          Patient Name:  "_$P(IVMPAT,"^")
  1.  S IVMTEXT(6)="                    ID:  "_$P(IVMPAT,"^",2)
  1.  S IVMTEXT(7)="          Type of Test:  "_$P($G(^DG(408.33,+IVMTOT,0)),"^")
  1.  S Y=IVMDOT X ^DD("DD")
  1.  S IVMTEXT(8)="          Date of Test:  "_Y
  1.  S IVMTEXT(9)=" "
  1.  ;
  1.  ; notify mail group
  1.  D MAIL^IVMUFNC("DGMT MT/CT UPLOAD ALERTS")
  1.  Q
  1.  ;
  1.  ;
  1. EVNT ; Call means test event driver
  1.  S DGMTYPT=IVMTOT D QUE^DGMTR
  1.  Q
  1.  ;
  1.  ;
  1. CLEAN ; Cleanup variables used for deletion.
  1.  K DA,DFN,DGINC,DGINR,DGMTA,DGMTACT,DGMTI,DGMTP
  1.  K DGMTYPT,DIE,DIK,DR,IVM12,IVM121,IVM13,IVM41,IVM411
  1.  K IVMAR1,IVMDEP,IVMFILE,IVMNOD,IVMOLD
  1.  K IVMPAT,IVMTEXT,IVMVAMCA,XMSUB,Y
  1.  Q