Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: IVMUCHK

IVMUCHK.m

Go to the documentation of this file. 
  1. IVMUCHK ;ALB/MLI - Filter routine to validate MT transmission before filing ; August 31,1994
  1.  ;;Version 2.0 ; INCOME VERIFICATION MATCH ;; 21-OCT-94
  1.  ;;Per VHA Directive 10-93-142, this routine should not be modified.
  1.  ;
  1.  ; This routine will perform edit checks to validate the means test data
  1.  ; before it is uploaded into the MAS Means Test files.  Any errors will
  1.  ; be recorded and will be sent automatically to the IVM Center for
  1.  ; processing.
  1.  ;
  1.  ; called from IVMUM1 before upload routine is invoked
  1.  ;
  1.  ; input:
  1.  ;   HLDA as IEN of the HL7 file entry
  1.  ;   HL* - all other HL7 variables expected
  1.  ;
  1.  ; output:
  1.  ;   IVMMTERR as error condition found (free text)
  1.  ;
  1. EN() ; entry point to create temp array and begin filter checks
  1.  ;
  1.  ;
  1.  ;
  1.  N ARRAY,DEP,ERROR,I,IEN,STRING,TYPE,X
  1.  S ERROR=""
  1.  F IEN=1:0 S IEN=$O(^HL(772,HLDA,"IN",IEN)) Q:'IEN!(ERROR]"")  I $E($G(^(IEN,0)),1,3)="PID" D
  1.  . K ARRAY S (DEP,SPOUSE)=0
  1.  . S ARRAY("PID")=$P($G(^HL(772,HLDA,"IN",IEN,0)),HLFS,2,999) ; pid segment
  1.  . S ARRAY("ZIC")=$$ORDER(HLDA,.IEN),$P(ARRAY("ZIC"),HLFS,21)=$$TOTAL(ARRAY("ZIC"))
  1.  . S ARRAY("ZIR")=$$ORDER(HLDA,.IEN)
  1.  . F IEN=IEN:0 S IEN=$O(^HL(772,HLDA,"IN",IEN)) Q:'IEN!($E($G(^(IEN,0)),1,3)="ZMT")  D
  1.  . . S DEP=DEP+1
  1.  . . S ARRAY(DEP,"ZDP")=$$CLEAR($P($G(^HL(772,HLDA,"IN",IEN,0)),HLFS,2,999))
  1.  . . S ARRAY(DEP,"ZIC")=$$ORDER(HLDA,.IEN)
  1.  . . S ARRAY(DEP,"ZIR")=$$ORDER(HLDA,.IEN)
  1.  . . I $P(ARRAY(DEP,"ZDP"),HLFS,6)=2,$P(ARRAY(DEP,"ZDP"),HLFS,2,4)'="^^" S SPOUSE=DEP
  1.  . . I $P(ARRAY(DEP,"ZDP"),HLFS,6)=2,$P(ARRAY(DEP,"ZDP"),HLFS,2,4)="^^" K ARRAY(DEP) S DEP=DEP-1
  1.  . . I DEP S $P(ARRAY(DEP,"ZIC"),HLFS,21)=$$TOTAL(ARRAY(DEP,"ZIC"),ARRAY(DEP,"ZIR"),ARRAY(DEP,"ZDP"))
  1.  . S ARRAY("ZMT")=$$CLEAR($P($G(^HL(772,HLDA,"IN",IEN,0)),HLFS,2,999))
  1.  . S ERROR=$$CHECK()
  1.  Q ERROR
  1.  ;
  1.  ;
  1. CHECK() ; check validity of transmission data
  1.  ;
  1.  ; Output:  error message (first one found)
  1.  ;
  1.  N ERROR,IEN
  1.  S ERROR=$$ZIC^IVMUCHK2(ARRAY("ZIC"))
  1.  I ERROR']"" S ERROR=$$ZIR^IVMUCHK1(ARRAY("ZIR"))
  1.  I ERROR']"" S ERROR=$$ZMT^IVMUCHK4(ARRAY("ZMT"))
  1.  I ERROR']"" F IEN=0:0 S IEN=$O(ARRAY(IEN)) Q:'IEN  D  I ERROR]"" G CHECKQ ; check dependent segments
  1.  . S ERROR=$$ZDP^IVMUCHK3(ARRAY(IEN,"ZDP"),IEN)
  1.  . I ERROR']"" S ERROR=$$ZIC^IVMUCHK2(ARRAY(IEN,"ZIC"),IEN)
  1.  . I ERROR']"" S ERROR=$$ZIR^IVMUCHK1(ARRAY(IEN,"ZIR"),IEN)
  1. CHECKQ Q $G(ERROR)
  1.  ;
  1.  ;
  1. ORDER(HLDA,IEN) ; get next node
  1.  S IEN=$O(^HL(772,HLDA,"IN",IEN))
  1.  Q $$CLEAR($P($G(^HL(772,HLDA,"IN",IEN,0)),HLFS,2,999))
  1.  ;
  1.  ;
  1. CLEAR(NODE) ; convert HLQ to null
  1.  N I
  1.  F I=1:1:25 I $P(NODE,HLFS,I)=HLQ S $P(NODE,HLFS,I)=""
  1.  Q NODE
  1.  ;
  1.  ;
  1. TOTAL(STRING,INCR,DEP) ; append total on the end
  1.  N I,D,N,INC,DEB,NET S (INC,DEB,NET)=""
  1. INC ; income
  1.  I $D(INCR),$P($G(DEP),HLFS,6)'=2,'$P(INCR,HLFS,9) S INC=0 G DEBT
  1.  F I=3:1:12 S INC=$G(INC)+$P(STRING,HLFS,I)
  1. DEBT ; debts
  1.  F I=13:1:15 S DEB=$G(DEB)+$P(STRING,HLFS,I)
  1. NET ; net worth
  1.  F I=16:1:19 I $P(STRING,HLFS,I)]"" S NET=$G(NET)+$P(STRING,HLFS,I)
  1.  I NET]"" S NET=NET-$P(STRING,HLFS,20)
  1.  Q INC_HLFS_DEB_HLFS_NET