IVMZ7CCD ;BAJ,TGH - HL7 Z07 CONSISTENCY CHECKER -- CATASTROPHIC DISABILITY SUBROUTINE ; 11/9/05 9:30am
;;2.0;INCOME VERIFICATION MATCH;**105,132,158**;JUL 8,1996;Build 44
;
; Catastrophic Disability Consistency Checks
; This routine checks the various elements of catastrophic disability information
; prior to building a Z07 record. Any tests which fail consistency check will be
; saved to the ^DGIN(38.6 record for the patient.
;
;
; Must be called from entry point
Q
;
EN(DFN) ; entry point. Patient DFN is sent from calling routine.
; initialize working variables
N RULE,Y,DGCDIS,PASS,FILERR
; patient array DGCDIS can be populated by a call to $$GET^DGENCDA(DFN,.DGCDIS) as follows:
;
; S PASS=$$GET^DGENCDA(DFN,.DGCDIS)
;
; and creates an array similar to this:
; DGCDIS("BY")="DR. JOHN"
; DGCDIS("COND",1)="48"
; DGCDIS("DATE")="3050926"
; DGCDIS("DIAG",1)="8"
; DGCDIS("DTFACIRV")=""
; DGCDIS("DTVETNOT")=""
; DGCDIS("FACDET")="16660"
; DGCDIS("METDET")="3"
; DGCDIS("PERM",1)="1"
; DGCDIS("REVDTE")="3050926"
; DGCDIS("SCORE",1)="6"
; DGCDIS("VCD")="Y"
; DGCDIS("VETREQDT")=""
;
; if the patient has no CD data on file, the API will return the following:
; DGCDIS=""
; DGCDIS("BY")=""
; DGCDIS("DATE")=""
; DGCDIS("DTFACIRV")=""
; DGCDIS("DTVETNOT")=""
; DGCDIS("FACDET")=""
; DGCDIS("METDET")=""
; DGCDIS("REVDTE")=""
; DGCDIS("VCD")=""
; DGCDIS("VETREQDT")=""
;
S PASS=$$GET^DGENCDA(DFN,.DGCDIS)
;
; In cases where patient is not listed as catastrophically disabled, routine should check to see if patient could potentially
; qualify for CD. If patient qualifies and is not listed as CD, an inconsistency should be filed. Otherwise continue.
; If patient is not listed as CD, regardless of potential, further checks are not necessary as the rest depend on CD="YES"
;
I '$$CD(DGCDIS("VCD")="Y") D Q
. I $D(FILERR) D FILE
;
; loop through rules in INCONSISTENT DATA ELEMENTS file.
; execute only the rules where CHECK/DON'T CHECK and INCLUDE IN Z07 CHECKS fields are turned ON.
;
; ***NOTE loop boundary (701-728) must be changed if rule numbers are added ***
F RULE=701:1:728 I $D(^DGIN(38.6,RULE)) D ;IVM*2.0*158
. S Y=^DGIN(38.6,RULE,0)
. I $P(Y,"^",6) D @RULE
I $D(FILERR) D FILE
Q
;
CD(VCD) ; Is Patient Catastrophically disabled? If not, we need to examine patient's record to see if qualified for CD
; Whether qualified or not, if patient is listed as NOT CD, the rest of the rules should not be checked. Therefore,
; if DGCDIS("VCD") does not = "Y" system will exit after this rule without checking any further.
I VCD Q 1
I $$ISCD^DGENCDA1(.DGCDIS) S FILERR(720)=""
Q 0
;
701 ;Catastrophic Disability 'Decided By' Cannot be 'HINQ'
I $G(DGCDIS("BY"))="HINQ" S FILERR(RULE)=""
Q
;
702 ;Catastrophic Disability 'Decided By' not valid
I ($L(DGCDIS("BY"))<3)!($L(DGCDIS("BY"))>35) S FILERR(RULE)=""
Q
703 ;"Catastrophic Disability 'Decided By' required"
I $G(DGCDIS("BY"))="" S FILERR(RULE)=""
Q
;
704 ;"Catastrophic Disability Review Date Required"
I $G(DGCDIS("REVDTE"))="" S FILERR(RULE)=""
Q
;
705 ;"Catastrophic Disability Review Date Invalid"
N RESULT
D CHK^DIE(2,.394,,DGCDIS("REVDTE"),.RESULT)
I RESULT="^" S FILERR(RULE)=""
Q
;
706 ;"CD Condition Score not valid"
N ITEM,ERR
S ITEM="",ERR=0
F S ITEM=$O(DGCDIS("COND",ITEM)) Q:ITEM="" D
. I '$$VALID^DGENA5(DGCDIS("COND",ITEM),$G(DGCDIS("SCORE",ITEM))) S ERR=1
I ERR S FILERR(RULE)=""
Q
;
707 ;"CD Review Date greater than CD Date of Determination"
I $G(DGCDIS("REVDTE"))>$G(DGCDIS("DATE")) S FILERR(RULE)=""
Q
;
708 ;"CD Status Affected Extremity' Invalid"
N ITEM,EIEN,ERR
S ITEM="",ERR=0
F S ITEM=$O(DGCDIS("PROC",ITEM)) Q:ITEM="" D
. S EIEN="" F S EIEN=$O(DGCDIS("EXT",ITEM,EIEN)) Q:EIEN="" D
. . I '$$LIMBOK^DGENA5(DGCDIS("PROC",ITEM),DGCDIS("EXT",ITEM,EIEN)) S ERR=1
I ERR S FILERR(RULE)=""
Q
;
709 ;"CD Status Diagnoses' Not Valid"
; .396 CD STATUS DIAGNOSES field (multiple):
N ITEM,ERR
S ITEM="",ERR=0
F S ITEM=$O(DGCDIS("DIAG",ITEM)) Q:ITEM="" D
. I $$TYPE^DGENA5(DGCDIS("DIAG",ITEM))'="D" S ERR=1
I ERR S FILERR(RULE)=""
Q
;
710 ;"'CD Status Procedure' Not Valid"
; .397 CD STATUS PROCEDURES field (multiple):
N ITEM,ERR
S ITEM="",ERR=0
F S ITEM=$O(DGCDIS("PROC",ITEM)) Q:ITEM="" D
. I $$TYPE^DGENA5(DGCDIS("PROC",ITEM))'="P" S ERR=1
I ERR S FILERR(RULE)=""
Q
;
711 ;"No CD Status Reason is Present"
I '($D(DGCDIS("DIAG"))!$D(DGCDIS("PROC"))!$D(DGCDIS("COND"))!$D(DGCDIS("DESCR"))) S FILERR(RULE)=""
Q
;
712 ;"'Date Of Catastophic Disability Decision' Not Valid"
N RESULT,OK,EXTERNAL
S OK=0
I $G(DGCDIS("DATE"))'="" S OK=1 D
. S EXTERNAL=$$EXTERNAL^DILFD(2,.392,"",DGCDIS("DATE"))
. I EXTERNAL="" S OK=0 Q
. D CHK^DIE(2,.392,,EXTERNAL,.RESULT) I RESULT="^" S OK=0
I 'OK S FILERR(RULE)=""
Q
;
713 ;"'Date Of Catastophic Disability Decision' Required"
I $G(DGCDIS("DATE"))="" S FILERR(RULE)=""
Q
;
714 ;"'Facility Making Catastrophic Disability Determination' Not Valid"
I DGCDIS("VCD")'=""!(DGCDIS("FACDET")'=""),$$EXTERNAL^DILFD(2,.393,"",$G(DGCDIS("FACDET")))="" S FILERR(RULE)=""
Q
;
715 ;"'Method Of Determination' Is A Required Value"
I $G(DGCDIS("METDET"))="" S FILERR(RULE)=""
Q
;
716 ;"'Method Of Determination' Not Valid"
I ".2.3."'[("."_$G(DGCDIS("METDET"))_".") S FILERR(RULE)=""
Q
;
717 ;"Not Enough Diagnoses/Procedures/Conditions To Qualify For CD Status"
I '$$ISCD^DGENCDA1(.DGCDIS) S FILERR(RULE)=""
Q
;
718 ;"Permanent Status Indicator' Not Valid"
N ITEM
S ITEM="" F S ITEM=$O(DGCDIS("COND",ITEM)) Q:ITEM="" D
. I ".1.2.3."'[("."_DGCDIS("PERM",ITEM)_".") S FILERR(RULE)=""
Q
;
719 ;"'Veteran Catastrophically Disabled?' Field Must Have A Response"
; .39 VETERAN CATASTROPHICALLY DISABLED? field.
I DGCDIS("VCD")="" S FILERR(RULE)=""
Q
;
720 ;"Veteran Has Enough Diagnoses/Procedures/Conditions To Qualify For CD Status"
; We check this rule at the beginning of the routine. No need to check it here,
; but we need the label as a place holder.
Q
;
723 ;"Catastrophic Disability Review date must be a precise date"
N RESULT
D CHK^DIE(2,.394,,DGCDIS("REVDTE"),.RESULT)
I RESULT="^" S FILERR(RULE)=""
Q
;
724 ;"Catastrophic Disability Date of Decision must be a precise date"
N RESULT
D CHK^DIE(2,.392,,DGCDIS("DATE"),.RESULT)
I RESULT="^" S FILERR(RULE)=""
Q
;
725 ;"Catastrophic Disability Procedure code must be accompanied with an Affected Extremity field"
; Procedure list = DGCDIS("PROC",ITEM)
; Affected Extremity list = DGCDIS("EXT",ITEM)
; This tag makes sure that there is at least one Affected Extremity for each procedure code.
N ITEM,ERR
S ERR=0,ITEM=""
F S ITEM=$O(DGCDIS("PROC",ITEM)) Q:ITEM="" D
. I '$D(DGCDIS("EXT",ITEM)) S ERR=1 Q
. I $G(DGCDIS("EXT",ITEM))="" S ERR=1
I ERR S FILERR(RULE)=""
Q
;
726 ;"Catastrophic Disablity condition code requires a Score field"
; Condition list = DGCDIS("COND",ITEM)
; Score list = DGCDIS("SCORE",ITEM)
N ITEM,ERR
S ERR=0,ITEM=""
F S ITEM=$O(DGCDIS("COND",ITEM)) Q:ITEM="" D
. I '$D(DGCDIS("SCORE",ITEM)) S ERR=1 Q
. I $G(DGCDIS("SCORE",ITEM))="" S ERR=1
I ERR S FILERR(RULE)=""
Q
;
727 ;"'CD Status Descriptor' Not Valid" - IVM*2.0*158
; .401 CD STATUS DESCRIPTORS field (multiple):
N ITEM,ERR
S ITEM="",ERR=0
F S ITEM=$O(DGCDIS("DESCR",ITEM)) Q:ITEM="" D
. I $$TYPE^DGENA5(DGCDIS("DESCR",ITEM))'="DE" S ERR=1
I ERR S FILERR(RULE)=""
Q
;
728 ;"No 'CD Descriptors' Selected" - IVM*2.0*158
I '($D(DGCDIS("DIAG"))!$D(DGCDIS("PROC"))!$D(DGCDIS("COND"))!$D(DGCDIS("DESCR"))) S FILERR(RULE)=""
Q
;
FILE ;file the inconsistencies in a temp global
M ^TMP($J,DFN)=FILERR
Q
;
--- Routine Detail --- with STRUCTURED ROUTINE LISTING ---[H[J[2J[HIVMZ7CCD 8031 printed Nov 22, 2024@17:13:18 Page 2
IVMZ7CCD ;BAJ,TGH - HL7 Z07 CONSISTENCY CHECKER -- CATASTROPHIC DISABILITY SUBROUTINE ; 11/9/05 9:30am
+1 ;;2.0;INCOME VERIFICATION MATCH;**105,132,158**;JUL 8,1996;Build 44
+2 ;
+3 ; Catastrophic Disability Consistency Checks
+4 ; This routine checks the various elements of catastrophic disability information
+5 ; prior to building a Z07 record. Any tests which fail consistency check will be
+6 ; saved to the ^DGIN(38.6 record for the patient.
+7 ;
+8 ;
+9 ; Must be called from entry point
+10 QUIT
+11 ;
EN(DFN) ; entry point. Patient DFN is sent from calling routine.
+1 ; initialize working variables
+2 NEW RULE,Y,DGCDIS,PASS,FILERR
+3 ; patient array DGCDIS can be populated by a call to $$GET^DGENCDA(DFN,.DGCDIS) as follows:
+4 ;
+5 ; S PASS=$$GET^DGENCDA(DFN,.DGCDIS)
+6 ;
+7 ; and creates an array similar to this:
+8 ; DGCDIS("BY")="DR. JOHN"
+9 ; DGCDIS("COND",1)="48"
+10 ; DGCDIS("DATE")="3050926"
+11 ; DGCDIS("DIAG",1)="8"
+12 ; DGCDIS("DTFACIRV")=""
+13 ; DGCDIS("DTVETNOT")=""
+14 ; DGCDIS("FACDET")="16660"
+15 ; DGCDIS("METDET")="3"
+16 ; DGCDIS("PERM",1)="1"
+17 ; DGCDIS("REVDTE")="3050926"
+18 ; DGCDIS("SCORE",1)="6"
+19 ; DGCDIS("VCD")="Y"
+20 ; DGCDIS("VETREQDT")=""
+21 ;
+22 ; if the patient has no CD data on file, the API will return the following:
+23 ; DGCDIS=""
+24 ; DGCDIS("BY")=""
+25 ; DGCDIS("DATE")=""
+26 ; DGCDIS("DTFACIRV")=""
+27 ; DGCDIS("DTVETNOT")=""
+28 ; DGCDIS("FACDET")=""
+29 ; DGCDIS("METDET")=""
+30 ; DGCDIS("REVDTE")=""
+31 ; DGCDIS("VCD")=""
+32 ; DGCDIS("VETREQDT")=""
+33 ;
+34 SET PASS=$$GET^DGENCDA(DFN,.DGCDIS)
+35 ;
+36 ; In cases where patient is not listed as catastrophically disabled, routine should check to see if patient could potentially
+37 ; qualify for CD. If patient qualifies and is not listed as CD, an inconsistency should be filed. Otherwise continue.
+38 ; If patient is not listed as CD, regardless of potential, further checks are not necessary as the rest depend on CD="YES"
+39 ;
+40 IF '$$CD(DGCDIS("VCD")="Y")
Begin DoDot:1
+41 IF $DATA(FILERR)
DO FILE
End DoDot:1
QUIT
+42 ;
+43 ; loop through rules in INCONSISTENT DATA ELEMENTS file.
+44 ; execute only the rules where CHECK/DON'T CHECK and INCLUDE IN Z07 CHECKS fields are turned ON.
+45 ;
+46 ; ***NOTE loop boundary (701-728) must be changed if rule numbers are added ***
+47 ;IVM*2.0*158
FOR RULE=701:1:728
IF $DATA(^DGIN(38.6,RULE))
Begin DoDot:1
+48 SET Y=^DGIN(38.6,RULE,0)
+49 IF $PIECE(Y,"^",6)
DO @RULE
End DoDot:1
+50 IF $DATA(FILERR)
DO FILE
+51 QUIT
+52 ;
CD(VCD) ; Is Patient Catastrophically disabled? If not, we need to examine patient's record to see if qualified for CD
+1 ; Whether qualified or not, if patient is listed as NOT CD, the rest of the rules should not be checked. Therefore,
+2 ; if DGCDIS("VCD") does not = "Y" system will exit after this rule without checking any further.
+3 IF VCD
QUIT 1
+4 IF $$ISCD^DGENCDA1(.DGCDIS)
SET FILERR(720)=""
+5 QUIT 0
+6 ;
701 ;Catastrophic Disability 'Decided By' Cannot be 'HINQ'
+1 IF $GET(DGCDIS("BY"))="HINQ"
SET FILERR(RULE)=""
+2 QUIT
+3 ;
702 ;Catastrophic Disability 'Decided By' not valid
+1 IF ($LENGTH(DGCDIS("BY"))<3)!($LENGTH(DGCDIS("BY"))>35)
SET FILERR(RULE)=""
+2 QUIT
703 ;"Catastrophic Disability 'Decided By' required"
+1 IF $GET(DGCDIS("BY"))=""
SET FILERR(RULE)=""
+2 QUIT
+3 ;
704 ;"Catastrophic Disability Review Date Required"
+1 IF $GET(DGCDIS("REVDTE"))=""
SET FILERR(RULE)=""
+2 QUIT
+3 ;
705 ;"Catastrophic Disability Review Date Invalid"
+1 NEW RESULT
+2 DO CHK^DIE(2,.394,,DGCDIS("REVDTE"),.RESULT)
+3 IF RESULT="^"
SET FILERR(RULE)=""
+4 QUIT
+5 ;
706 ;"CD Condition Score not valid"
+1 NEW ITEM,ERR
+2 SET ITEM=""
SET ERR=0
+3 FOR
SET ITEM=$ORDER(DGCDIS("COND",ITEM))
if ITEM=""
QUIT
Begin DoDot:1
+4 IF '$$VALID^DGENA5(DGCDIS("COND",ITEM),$GET(DGCDIS("SCORE",ITEM)))
SET ERR=1
End DoDot:1
+5 IF ERR
SET FILERR(RULE)=""
+6 QUIT
+7 ;
707 ;"CD Review Date greater than CD Date of Determination"
+1 IF $GET(DGCDIS("REVDTE"))>$GET(DGCDIS("DATE"))
SET FILERR(RULE)=""
+2 QUIT
+3 ;
708 ;"CD Status Affected Extremity' Invalid"
+1 NEW ITEM,EIEN,ERR
+2 SET ITEM=""
SET ERR=0
+3 FOR
SET ITEM=$ORDER(DGCDIS("PROC",ITEM))
if ITEM=""
QUIT
Begin DoDot:1
+4 SET EIEN=""
FOR
SET EIEN=$ORDER(DGCDIS("EXT",ITEM,EIEN))
if EIEN=""
QUIT
Begin DoDot:2
+5 IF '$$LIMBOK^DGENA5(DGCDIS("PROC",ITEM),DGCDIS("EXT",ITEM,EIEN))
SET ERR=1
End DoDot:2
End DoDot:1
+6 IF ERR
SET FILERR(RULE)=""
+7 QUIT
+8 ;
709 ;"CD Status Diagnoses' Not Valid"
+1 ; .396 CD STATUS DIAGNOSES field (multiple):
+2 NEW ITEM,ERR
+3 SET ITEM=""
SET ERR=0
+4 FOR
SET ITEM=$ORDER(DGCDIS("DIAG",ITEM))
if ITEM=""
QUIT
Begin DoDot:1
+5 IF $$TYPE^DGENA5(DGCDIS("DIAG",ITEM))'="D"
SET ERR=1
End DoDot:1
+6 IF ERR
SET FILERR(RULE)=""
+7 QUIT
+8 ;
710 ;"'CD Status Procedure' Not Valid"
+1 ; .397 CD STATUS PROCEDURES field (multiple):
+2 NEW ITEM,ERR
+3 SET ITEM=""
SET ERR=0
+4 FOR
SET ITEM=$ORDER(DGCDIS("PROC",ITEM))
if ITEM=""
QUIT
Begin DoDot:1
+5 IF $$TYPE^DGENA5(DGCDIS("PROC",ITEM))'="P"
SET ERR=1
End DoDot:1
+6 IF ERR
SET FILERR(RULE)=""
+7 QUIT
+8 ;
711 ;"No CD Status Reason is Present"
+1 IF '($DATA(DGCDIS("DIAG"))!$DATA(DGCDIS("PROC"))!$DATA(DGCDIS("COND"))!$DATA(DGCDIS("DESCR")))
SET FILERR(RULE)=""
+2 QUIT
+3 ;
712 ;"'Date Of Catastophic Disability Decision' Not Valid"
+1 NEW RESULT,OK,EXTERNAL
+2 SET OK=0
+3 IF $GET(DGCDIS("DATE"))'=""
SET OK=1
Begin DoDot:1
+4 SET EXTERNAL=$$EXTERNAL^DILFD(2,.392,"",DGCDIS("DATE"))
+5 IF EXTERNAL=""
SET OK=0
QUIT
+6 DO CHK^DIE(2,.392,,EXTERNAL,.RESULT)
IF RESULT="^"
SET OK=0
End DoDot:1
+7 IF 'OK
SET FILERR(RULE)=""
+8 QUIT
+9 ;
713 ;"'Date Of Catastophic Disability Decision' Required"
+1 IF $GET(DGCDIS("DATE"))=""
SET FILERR(RULE)=""
+2 QUIT
+3 ;
714 ;"'Facility Making Catastrophic Disability Determination' Not Valid"
+1 IF DGCDIS("VCD")'=""!(DGCDIS("FACDET")'="")
IF $$EXTERNAL^DILFD(2,.393,"",$GET(DGCDIS("FACDET")))=""
SET FILERR(RULE)=""
+2 QUIT
+3 ;
715 ;"'Method Of Determination' Is A Required Value"
+1 IF $GET(DGCDIS("METDET"))=""
SET FILERR(RULE)=""
+2 QUIT
+3 ;
716 ;"'Method Of Determination' Not Valid"
+1 IF ".2.3."'[("."_$GET(DGCDIS("METDET"))_".")
SET FILERR(RULE)=""
+2 QUIT
+3 ;
717 ;"Not Enough Diagnoses/Procedures/Conditions To Qualify For CD Status"
+1 IF '$$ISCD^DGENCDA1(.DGCDIS)
SET FILERR(RULE)=""
+2 QUIT
+3 ;
718 ;"Permanent Status Indicator' Not Valid"
+1 NEW ITEM
+2 SET ITEM=""
FOR
SET ITEM=$ORDER(DGCDIS("COND",ITEM))
if ITEM=""
QUIT
Begin DoDot:1
+3 IF ".1.2.3."'[("."_DGCDIS("PERM",ITEM)_".")
SET FILERR(RULE)=""
End DoDot:1
+4 QUIT
+5 ;
719 ;"'Veteran Catastrophically Disabled?' Field Must Have A Response"
+1 ; .39 VETERAN CATASTROPHICALLY DISABLED? field.
+2 IF DGCDIS("VCD")=""
SET FILERR(RULE)=""
+3 QUIT
+4 ;
720 ;"Veteran Has Enough Diagnoses/Procedures/Conditions To Qualify For CD Status"
+1 ; We check this rule at the beginning of the routine. No need to check it here,
+2 ; but we need the label as a place holder.
+3 QUIT
+4 ;
723 ;"Catastrophic Disability Review date must be a precise date"
+1 NEW RESULT
+2 DO CHK^DIE(2,.394,,DGCDIS("REVDTE"),.RESULT)
+3 IF RESULT="^"
SET FILERR(RULE)=""
+4 QUIT
+5 ;
724 ;"Catastrophic Disability Date of Decision must be a precise date"
+1 NEW RESULT
+2 DO CHK^DIE(2,.392,,DGCDIS("DATE"),.RESULT)
+3 IF RESULT="^"
SET FILERR(RULE)=""
+4 QUIT
+5 ;
725 ;"Catastrophic Disability Procedure code must be accompanied with an Affected Extremity field"
+1 ; Procedure list = DGCDIS("PROC",ITEM)
+2 ; Affected Extremity list = DGCDIS("EXT",ITEM)
+3 ; This tag makes sure that there is at least one Affected Extremity for each procedure code.
+4 NEW ITEM,ERR
+5 SET ERR=0
SET ITEM=""
+6 FOR
SET ITEM=$ORDER(DGCDIS("PROC",ITEM))
if ITEM=""
QUIT
Begin DoDot:1
+7 IF '$DATA(DGCDIS("EXT",ITEM))
SET ERR=1
QUIT
+8 IF $GET(DGCDIS("EXT",ITEM))=""
SET ERR=1
End DoDot:1
+9 IF ERR
SET FILERR(RULE)=""
+10 QUIT
+11 ;
726 ;"Catastrophic Disablity condition code requires a Score field"
+1 ; Condition list = DGCDIS("COND",ITEM)
+2 ; Score list = DGCDIS("SCORE",ITEM)
+3 NEW ITEM,ERR
+4 SET ERR=0
SET ITEM=""
+5 FOR
SET ITEM=$ORDER(DGCDIS("COND",ITEM))
if ITEM=""
QUIT
Begin DoDot:1
+6 IF '$DATA(DGCDIS("SCORE",ITEM))
SET ERR=1
QUIT
+7 IF $GET(DGCDIS("SCORE",ITEM))=""
SET ERR=1
End DoDot:1
+8 IF ERR
SET FILERR(RULE)=""
+9 QUIT
+10 ;
727 ;"'CD Status Descriptor' Not Valid" - IVM*2.0*158
+1 ; .401 CD STATUS DESCRIPTORS field (multiple):
+2 NEW ITEM,ERR
+3 SET ITEM=""
SET ERR=0
+4 FOR
SET ITEM=$ORDER(DGCDIS("DESCR",ITEM))
if ITEM=""
QUIT
Begin DoDot:1
+5 IF $$TYPE^DGENA5(DGCDIS("DESCR",ITEM))'="DE"
SET ERR=1
End DoDot:1
+6 IF ERR
SET FILERR(RULE)=""
+7 QUIT
+8 ;
728 ;"No 'CD Descriptors' Selected" - IVM*2.0*158
+1 IF '($DATA(DGCDIS("DIAG"))!$DATA(DGCDIS("PROC"))!$DATA(DGCDIS("COND"))!$DATA(DGCDIS("DESCR")))
SET FILERR(RULE)=""
+2 QUIT
+3 ;
FILE ;file the inconsistencies in a temp global
+1 MERGE ^TMP($JOB,DFN)=FILERR
+2 QUIT
+3 ;
